diff --git a/.mega-linter.yaml b/.mega-linter.yaml
index 8557dfecf79b..e76d9a9a79a5 100644
--- a/.mega-linter.yaml
+++ b/.mega-linter.yaml
@@ -47,3 +47,4 @@ DISABLE_ERRORS_LINTERS:
   - PHP_PHPCSFIXER
 PHP_PHPCS_ARGUMENTS:
   - --standard=PSR12
+RAKU_RAKU_ARGUMENTS: -I ./grammars/raku/lib/
diff --git a/CHANGELOG.md b/CHANGELOG.md
index a039aa61bee7..e1e87600c4f9 100644
--- a/CHANGELOG.md
+++ b/CHANGELOG.md
@@ -14,6 +14,8 @@
 
 **Integrations**:
 
+- Add grammar file for Raku. (@vanillajonathan, #5576)
+
 **Internal changes**:
 
 **New Contributors**:
diff --git a/grammars/README.md b/grammars/README.md
index b3b5c2962ed2..bea84245ef68 100644
--- a/grammars/README.md
+++ b/grammars/README.md
@@ -70,6 +70,9 @@ an index.
   ([prql.py](https://github.com/pygments/pygments/blob/master/pygments/lexers/prql.py)).
   See the [demo](https://pygments.org/demo/).
 
+- [Raku](https://raku.org/) — Grammar can be found at
+  [`grammars/raku/`](https://github.com/PRQL/prql/tree/main/grammars/raku/).
+
 - [TEA](https://github.com/psemiletov/tea-qt/) — supported. The grammar is
   [upstream](https://github.com/psemiletov/tea-qt/blob/master/hls/prql.xml).
 
diff --git a/grammars/raku/META6.json b/grammars/raku/META6.json
new file mode 100644
index 000000000000..339a651b5866
--- /dev/null
+++ b/grammars/raku/META6.json
@@ -0,0 +1,20 @@
+{
+  "name": "PRQL",
+  "version": "0.0.1",
+  "description": "Grammar for PRQL",
+  "tags": ["data", "grammar", "pipeline", "sql"],
+  "source-url": "https://github.com/PRQL/prql/",
+  "support": {
+    "source": "https://github.com/PRQL/prql/",
+    "bugtracker": "https://github.com/PRQL/prql/issues"
+  },
+  "api": "1.0",
+  "production": false,
+  "auth": "github:PRQL",
+  "license": "Artistic-2.0",
+  "provides": {
+    "prql": "lib/prql.rakumod"
+  },
+  "raku": "6.*",
+  "meta-version": "1"
+}
diff --git a/grammars/raku/README.md b/grammars/raku/README.md
new file mode 100644
index 000000000000..8a742d58d067
--- /dev/null
+++ b/grammars/raku/README.md
@@ -0,0 +1,36 @@
+# Raku grammar
+
+PRQL grammar for Raku.
+
+## Instructions
+
+```raku
+use lib '.';
+use prql;
+
+say PRQL.parse('from employees');
+say PRQL.parsefile('employees.prql');
+```
+
+## Installation
+
+To install from source run:
+
+    zef install .
+
+## Tests
+
+Tests can be run individually by specifying the test filename on the command
+line:
+
+    raku t/arithmetics.rakutest
+
+To run all tests in the directory you have to install `prove6` using `zef`:
+
+    zef install App::Prove6
+    prove6 --lib t/
+
+## Documentation
+
+- https://docs.raku.org/language/grammar_tutorial
+- https://docs.raku.org/language/grammars
diff --git a/grammars/raku/lib/prql.rakumod b/grammars/raku/lib/prql.rakumod
new file mode 100644
index 000000000000..849342d0b2c4
--- /dev/null
+++ b/grammars/raku/lib/prql.rakumod
@@ -0,0 +1,319 @@
+=begin pod
+
+=head1 NAME
+
+prql.rakumod - Grammar for PRQL.
+
+=head1 SYNOPSIS
+
+    use PRQL;
+
+    # Parse a simple PRQL query
+    say PRQL.parse('from employees');
+
+    # Parse a PRQL file
+    say PRQL.parsefile('employees.prql');
+
+=head1 DESCRIPTION
+
+PRQL grammar for Raku.
+
+PRQL is a modern language for transforming data — a simple, powerful, pipelined SQL replacement.
+
+=head1 SEE ALSO
+
+L<https://prql-lang.org/> and L<https://github.com/PRQL/prql/>.
+
+=end pod
+
+grammar PRQL {
+    token TOP {
+        <statement>*
+    }
+
+    rule statement {
+        | <doc-block>
+        | <comment>
+        | <query-definition>
+        | <module>
+        | <annotation>
+        | <variable-declaration>
+        | <pipeline-statement> <comment>?
+    }
+
+    rule query-definition {
+        'prql' <named-arg>+
+    }
+
+    rule module {
+        'module' <identifier> '{' <statement>* '}'
+    }
+
+    rule pipeline-statement {
+        <pipeline>
+    }
+
+    rule pipeline {
+        | <call-expression>+ % '|'
+        | <expression> '|' <identifier>
+    }
+
+    rule tuple-expression {
+        '{'
+        (
+        | <declaration-tuple>
+        | <call-expression>
+        | <expression>
+        | <case-branch>
+        )* %% ','
+        '}'
+    }
+
+    rule annotation {
+        '@{'
+        <declaration>? % ','
+        '}'
+    }
+
+    rule call-expression {
+        <identifier>
+        (
+        | <named-arg>
+        | <declaration>
+        | <test>
+        )+
+    }
+
+    rule named-arg {
+        <identifier> ':' <expression>
+    }
+
+    rule declaration {
+        <identifier> '=' <expression>
+    }
+
+    rule declaration-tuple {
+        <identifier> '=' <expression>
+    }
+
+    rule case-branch {
+        <expression> '=>' <expression>
+    }
+
+    rule case-expression {
+        'case' <tuple-expression>
+    }
+
+    rule nested-pipeline {
+        '(' <pipeline> ')'
+    }
+
+    # The name "test" here means equality testing. It is the name used in the Python grammar.
+    rule test {
+        <test-inner>
+    }
+
+    rule test-inner {
+        | <binary-test>
+        | '!' <test-inner>
+        | <expression>
+    }
+
+    rule binary-test {
+        | <expression> <logic-op> <expression>
+        | <expression> <compare-op> <expression>
+        | <expression> <arith-op> <expression>
+    }
+
+    token expression {
+        | 'this'
+        | 'that'
+        | 'null'
+        | <binary-expression>
+        | <unary-expression>
+        | <array-expression>
+        | <tuple-expression>
+        | <nested-pipeline>
+        | <case-expression>
+        | <date-time>
+        | <parameter>
+        | <parenthesized-expression>
+        | <range-expression>
+        | <identifier>
+        | <boolean>
+        | <time-unit>
+        | <number>
+        | <string>
+        | <f-string>
+        | <r-string>
+        | <s-string>
+    }
+
+    token boolean {
+        | 'true'
+        | 'false'
+    }
+
+    token variable-name {
+        <.ident>
+    }
+
+    token identifier {
+        <.ident>
+        ['.' [<.ident> | '*']]*
+    }
+
+    rule array-expression {
+        '['
+        (<test> | '*' <expression>)+ %% ','
+        ']'
+    }
+
+    rule binary-expression {
+        <identifier> <arith-op> <expression>
+    }
+
+    rule parenthesized-expression {
+        '(' <expression> ')'
+    }
+
+    rule unary-expression {
+        | ('+' | '-') <expression>
+        | '==' <identifier>
+    }
+
+    token number {
+        | <float>
+        | <integer>
+    }
+
+    rule variable-declaration {
+        'let' <variable-name> '=' (<nested-pipeline> | <lambda>)
+    }
+
+    rule lambda {
+        <lambda-param>* '->' <expression>
+    }
+
+    rule type-definition {
+        '<' <type-name> ('|' <type-name>)* '>'
+    }
+
+    rule type-name {
+        <identifier> <type-definition>?
+    }
+
+    rule lambda-param {
+        <identifier> <type-definition>? (':' <expression>)?
+    }
+
+    token integer {
+        | <.digit> [<.digit> | '_']* ['e' ['+' | '-']? <integer>]?
+        | '0x' [<.xdigit> | '_']+
+        | '0b' <[01_]>+
+        | '0o' <[0..7_]>+
+    }
+
+    token float {
+        \d [\d | '_']* '.' \d [\d | '_']* ['e' <integer>]?
+    }
+
+    token date {
+        \d+ '-' \d+ '-' \d+
+    }
+
+    token time {
+        \d+ ':' \d+
+        [':' \d+ ['.' \d+]?]?
+    }
+
+    token date-time {
+        '@'
+        (
+        | <date> 'T' <time> ['Z' | ['-' | '+'] \d+ ':' \d+]?
+        | <date>
+        | <time>
+        )
+    }
+
+    token time-unit {
+        $<number>=\d+
+        <dimension>
+    }
+
+    token escape {
+        '\\'
+        (
+        | 'x' <xdigit> <xdigit>
+        | 'u' '{' <xdigit>+ '}'
+        | <[bfnrt]>
+        )
+    }
+
+    token parameter {
+        '$'
+        \w+
+    }
+
+    token doc-block {
+        '#!' .+? $$
+    }
+
+    token comment {
+        '#' .+? $$
+    }
+
+    token range-expression {
+        (<.digit>+)
+        '..'
+        (<.digit>+)
+    }
+
+    token dimension {
+        [
+        | microseconds
+        | milliseconds
+        | seconds
+        | minutes
+        | hours
+        | days
+        | weeks
+        | months
+        | years
+        ] <!ww>
+    }
+
+    token arith-op {
+        '+' | '-' | '*' | '/' | '%' | '//' | '**'
+    }
+
+    token compare-op {
+        '==' | '!=' | '~=' | '>=' | '<=' | '>' | '<' | 'in'
+    }
+
+    token logic-op {
+        '&&' | '||' | '??'
+    }
+
+    token f-string {
+        | 'f"' (<-[\"]> | <escape>)* '"'
+        | 'f\'' (<-[\']> | <escape>)* '\''
+    }
+
+    token r-string {
+        | 'r"' <-[\"]>* '"'
+        | 'r\'' <-[\']>* '\''
+    }
+
+    token s-string {
+        | 's"' (<-[\"]> | <escape>)* '"'
+        | 's\'' (<-[\']> | <escape>)* '\''
+    }
+
+    token string {
+        | '"""' (<-[\"]> | <escape>)* '"""'
+        | '"' (<-[\"]> | <escape>)* '"'
+        | '\'' (<-[\']> | <escape>)* '\''
+        | '\'\'\'' (<-[\']> | <escape>)* '\'\'\''
+    }
+}
diff --git a/grammars/raku/t/arithmetics.rakutest b/grammars/raku/t/arithmetics.rakutest
new file mode 100644
index 000000000000..69eacfb55591
--- /dev/null
+++ b/grammars/raku/t/arithmetics.rakutest
@@ -0,0 +1,28 @@
+use Test;
+use prql;
+
+plan 6;
+
+# Plus
+ok PRQL.parse('filter 10 + 10.5');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(integer,arith-op,float)))))
+
+# Minus
+ok PRQL.parse('filter 10 - 10');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(integer,arith-op,integer)))))
+
+# Multiply
+ok PRQL.parse('filter 10 * 10');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(integer,arith-op,integer)))))
+
+# Divide
+ok PRQL.parse('filter 10 / 10');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(integer,arith-op,integer)))))
+
+# Exponentiation
+ok PRQL.parse('filter 10 ** 10');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(integer,arith-op,integer)))))
+
+# Multiple ops
+ok PRQL.parse('filter 10 + 10 + 10');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(binary-expression(integer,arith-op,integer),arith-op,integer)))))
diff --git a/grammars/raku/t/arrays.rakutest b/grammars/raku/t/arrays.rakutest
new file mode 100644
index 000000000000..9843da9dcac6
--- /dev/null
+++ b/grammars/raku/t/arrays.rakutest
@@ -0,0 +1,44 @@
+use Test;
+use prql;
+
+plan 6;
+
+# Array on one line
+ok PRQL.parse('filter [foo, bar, baz]');
+#query(pipeline(call-expression(identifier,arg-list(array-expression(identifier,identifier,identifier)))))
+
+# Array on multiple lines
+ok PRQL.parse(q:to/END/);
+filter [
+  foo,
+  bar,
+  baz
+]
+END
+#query(pipeline(call-expression(identifier,arg-list(array-expression(identifier,identifier,identifier)))))
+
+# Array on multiple lines with blank lines
+ok PRQL.parse(q:to/END/);
+filter [
+
+  foo,
+
+  bar,
+
+  baz
+
+]
+END
+#query(pipeline(call-expression(identifier,arg-list(array-expression(identifier,identifier,identifier)))))
+
+# Array of integers
+ok PRQL.parse('filter [1, 2, 3]');
+#query(pipeline(call-expression(identifier,arg-list(array-expression(integer,integer,integer)))))
+
+# Array of floats
+ok PRQL.parse('filter [1.1, 2.2, 3.3]');
+#query(pipeline(call-expression(identifier,arg-list(array-expression(float,float,float)))))
+
+# Array of strings
+ok PRQL.parse('filter ["string", f"format", r"raw", s"server"]');
+#query(pipeline(call-expression(identifier,arg-list(array-expression(string,f-string,r-string,s-string)))))
diff --git a/grammars/raku/t/datetime.rakutest b/grammars/raku/t/datetime.rakutest
new file mode 100644
index 000000000000..ff6f6331a1e8
--- /dev/null
+++ b/grammars/raku/t/datetime.rakutest
@@ -0,0 +1,32 @@
+use Test;
+use prql;
+
+plan 7;
+
+# Date YYYY-MM-DD
+ok PRQL.parse('filter @1970-01-01');
+#query(pipeline(call-expression(identifier,arg-list(date-time))))
+
+# Time HH:MM
+ok PRQL.parse('filter @08:30');
+#query(pipeline(call-expression(identifier,arg-list(date-time))))
+
+# Time HH:MM:SS
+ok PRQL.parse('filter @12:00:00');
+#query(pipeline(call-expression(identifier,arg-list(date-time))))
+
+# Time HH:MM:SS.xxx
+ok PRQL.parse('filter @12:00:00.500');
+#query(pipeline(call-expression(identifier,arg-list(date-time))))
+
+# Date and time
+ok PRQL.parse('filter @1970-01-01T12:00:00');
+#query(pipeline(call-expression(identifier,arg-list(date-time))))
+
+# Date and time with timezone
+ok PRQL.parse('filter @1970-01-01T12:00:00+01:00');
+#query(pipeline(call-expression(identifier,arg-list(date-time))))
+
+# Date and time in UTC
+ok PRQL.parse('filter @1970-01-01T12:00:00Z');
+#query(pipeline(call-expression(identifier,arg-list(date-time))))
diff --git a/grammars/raku/t/full_queries.rakutest b/grammars/raku/t/full_queries.rakutest
new file mode 100644
index 000000000000..751624fb205f
--- /dev/null
+++ b/grammars/raku/t/full_queries.rakutest
@@ -0,0 +1,29 @@
+use Test;
+use prql;
+
+plan 1;
+
+ok PRQL.parse(q:to/END/);
+# Website showcasing example
+from invoices
+filter invoice_date >= @1970-01-16
+derive {
+  transaction_fees = 0.8,
+  income = total - transaction_fees
+}
+filter income > 1
+group customer_id (
+  aggregate {
+    average total
+  }
+)
+sort {-sum_income}
+take 10
+join c=customers (==customer_id)
+derive name = f"{c.last_name}, {c.first_name}"
+select {
+  c.customer_id, name, sum_income
+}
+derive db_version = s"version()"
+END
+#query(pipeline(call-expression(identifier,arg-list(identifier)),call-expression(identifier,arg-list(binary-expression(identifier,compare-op,date-time))),call-expression(identifier,arg-list(tuple-expression(declaration-tuple(declaration-item,equals,float),declaration-tuple(declaration-item,equals,binary-expression(identifier,arith-op,identifier))))),call-expression(identifier,arg-list(binary-expression(identifier,compare-op,integer))),call-expression(identifier,arg-list(identifier,nested-pipeline(pipeline(call-expression(identifier,arg-list(tuple-expression(call-expression(identifier,arg-list(identifier))))))))),call-expression(identifier,arg-list(tuple-expression(unary-expression(arith-op,identifier)))),call-expression(identifier,arg-list(integer)),call-expression(identifier,arg-list(declaration(declaration-item,equals,identifier),parenthesized-expression(unary-Expression(compare-op,identifier)))),call-expression(identifier,arg-list(declaration(declaration-item,equals,f-string))),call-expression(identifier,arg-list(tuple-expression(identifier,identifier,identifier))),call-expression(identifier,arg-list(declaration(declaration-item,equals,s-string)))))
diff --git a/grammars/raku/t/identifiers.rakutest b/grammars/raku/t/identifiers.rakutest
new file mode 100644
index 000000000000..3279a8e4478f
--- /dev/null
+++ b/grammars/raku/t/identifiers.rakutest
@@ -0,0 +1,16 @@
+use Test;
+use prql;
+
+plan 3;
+
+# Basic identifier
+ok PRQL.parse('filter foo');
+#query(pipeline(call-expression(identifier,arg-list(identifier))))
+
+# Identifier with underscore and digit
+ok PRQL.parse('filter foo_123');
+#query(pipeline(call-expression(identifier,arg-list(identifier))))
+
+# Unicode identifier
+ok PRQL.parse('filter räksmörgås');
+#query(pipeline(call-expression(identifier,arg-list(identifier))))
diff --git a/grammars/raku/t/misc.rakutest b/grammars/raku/t/misc.rakutest
new file mode 100644
index 000000000000..4c992f1d7140
--- /dev/null
+++ b/grammars/raku/t/misc.rakutest
@@ -0,0 +1,128 @@
+use Test;
+use prql;
+
+plan 23;
+
+# Boolean: true
+ok PRQL.parse('filter true');
+#query(pipeline(call-expression(identifier,arg-list(boolean))))
+
+# Boolean: false
+ok PRQL.parse('filter false');
+#query(pipeline(call-expression(identifier,arg-list(boolean))))
+
+# Null
+ok PRQL.parse('filter null');
+#query(pipeline(call-expression(identifier,arg-list(null))))
+
+# Keyword: this
+ok PRQL.parse('filter this');
+#query(pipeline(call-expression(identifier,arg-list(this))))
+
+# Keyword: that
+ok PRQL.parse('filter that');
+#query(pipeline(call-expression(identifier,arg-list(that))))
+
+# Annotation
+ok PRQL.parse(q:to/END/);
+@{binding_strength=1}
+let x = y -> z
+END
+#query(annotation(declaration(declaration-item,equals,integer)),variable-declaration(let,variable-name,equals,lambda(lambda-param,identifier)))
+
+# Range: 10..20
+ok PRQL.parse('filter 10..20');
+#query(pipeline(call-expression(identifier,arg-list(range-expression))))
+
+# Comment
+ok PRQL.parse('filter 1 # Hello');
+#query(pipeline(call-expression(identifier,arg-list(integer))),comment)
+
+# Two comments
+ok PRQL.parse(q:to/END/);
+# Hello
+# Bar
+END
+#query(comment,comment)
+
+# Comment between pipes
+ok PRQL.parse(q:to/END/);
+from foo
+# filter...
+select bar
+END
+#query(pipeline(call-expression(identifier,arg-list(identifier)),comment,call-expression(identifier,arg-list(identifier))))
+
+# Docblock
+ok PRQL.parse(q:to/END/);
+#! Hello
+filter 1
+END
+#query(docblock,pipeline(call-expression(identifier,arg-list(integer))))
+
+# Variable declaration
+ok PRQL.parse('let foo = (from foo)');
+#query(variable-declaration(let,variable-name,equals,nested-pipeline(pipeline(call-expression(identifier,arg-list(identifier))))))
+
+# Function declaration
+ok PRQL.parse('let my_func = arg1 -> arg1');
+#query(variable-declaration(let,variable-name,equals,lambda(lambda-param,identifier)))
+
+# Function declaration with two args
+ok PRQL.parse('let my_func = arg1 arg2 -> arg1 + arg2');
+#query(variable-declaration(let,variable-name,equals,lambda(lambda-param,lambda-param,binary-expression(identifier,arith-op,identifier))))
+
+# Function declaration with type annotation
+ok PRQL.parse('let my_func = arg1<int32> -> arg1');
+#query(variable-declaration(let,variable-name,equals,lambda(lambda-param(type-definition(type-name)),identifier)))
+
+# Parameter
+ok PRQL.parse('filter id == $1');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,compare-op,parameter)))))
+
+# Parenthesized expression
+ok PRQL.parse('filter (1)');
+#query(pipeline(call-expression(identifier,arg-list(parenthesized-expression(integer)))))
+
+# Simple pipeline
+ok PRQL.parse('from foo | select bar');
+#query(pipeline(call-expression(identifier,arg-list(identifier)),call-expression(identifier,arg-list(identifier))))
+
+# Derive
+ok PRQL.parse(q:to/END/);
+derive {
+  transaction_fees = 0.8,
+  income = total - transaction_fees
+}
+END
+#query(pipeline(call-expression(identifier,arg-list(tuple-expression(declaration-tuple(declaration-item,equals,float),declaration-tuple(declaration-item,equals,binary-expression(identifier,arith-op,identifier)))))))
+
+# Nested pipeline
+ok PRQL.parse(q:to/END/);
+group customer_id (
+  aggregate {
+    average total
+  }
+)
+END
+#query(pipeline(call-expression(identifier,arg-list(identifier,nested-pipeline(pipeline(call-expression(identifier,arg-list(tuple-expression(call-expression(identifier,arg-list(identifier)))))))))))
+
+# Tabs as spaces
+ok PRQL.parse('let		foo		=		(foo 1)');
+#query(variable-declaration(let,variable-name,equals,nested-pipeline(pipeline(call-expression(identifier,arg-list(integer))))))
+
+# Module
+ok PRQL.parse(q:to/END/);
+module foo {
+  let x = -> s"foo()"
+}
+END
+#query(module(module,identifier,variable-declaration(let,variable-name,equals,lambda(s-string))))
+
+# Pipeline within tuple
+ok PRQL.parse(q:to/END/);
+derive {
+  a = (b | math.abs)
+}
+END
+#query(pipeline(call-expression(identifier,arg-list(tuple-expression(declaration-tuple(declaration-item,equals,nested-pipeline(pipeline(identifier,identifier))))))))
diff --git a/grammars/raku/t/numbers.rakutest b/grammars/raku/t/numbers.rakutest
new file mode 100644
index 000000000000..da22ae7cbbf8
--- /dev/null
+++ b/grammars/raku/t/numbers.rakutest
@@ -0,0 +1,40 @@
+use Test;
+use prql;
+
+plan 9;
+
+# Integer
+ok PRQL.parse('filter 123');
+#query(pipeline(call-expression(identifier,arg-list(integer))))
+
+# Integer with underscore
+ok PRQL.parse('filter 123_456');
+#query(pipeline(call-expression(identifier,arg-list(integer))))
+
+# Integer with underscores
+ok PRQL.parse('filter 123_456_789');
+#query(pipeline(call-expression(identifier,arg-list(integer))))
+
+# Decimal
+ok PRQL.parse('filter 123.45');
+#query(pipeline(call-expression(identifier,arg-list(float))))
+
+# Scientific notation
+ok PRQL.parse('filter 123e10');
+#query(pipeline(call-expression(identifier,arg-list(integer))))
+
+# Number with time unit
+ok PRQL.parse('filter 5years');
+#query(pipeline(call-expression(identifier,arg-list(time-unit))))
+
+# Binary notation
+ok PRQL.parse('filter 0b1111');
+#query(pipeline(call-expression(identifier,arg-list(integer))))
+
+# Hex notation
+ok PRQL.parse('filter 0xff');
+#query(pipeline(call-expression(identifier,arg-list(integer))))
+
+# Octal notation
+ok PRQL.parse('filter 0o777');
+#query(pipeline(call-expression(identifier,arg-list(integer))))
diff --git a/grammars/raku/t/operators.rakutest b/grammars/raku/t/operators.rakutest
new file mode 100644
index 000000000000..e7d54e64b038
--- /dev/null
+++ b/grammars/raku/t/operators.rakutest
@@ -0,0 +1,44 @@
+use Test;
+use prql;
+
+plan 10;
+
+# == Equals
+ok PRQL.parse('filter foo == bar');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,compare-op,identifier)))))
+
+# != Not equals
+ok PRQL.parse('filter foo != bar');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,compare-op,identifier)))))
+
+# >= Greater than
+ok PRQL.parse('filter foo >= bar');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,compare-op,identifier)))))
+
+# <= Less than
+ok PRQL.parse('filter foo <= bar');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,compare-op,identifier)))))
+
+# ~= Regex match
+ok PRQL.parse('filter foo ~= bar');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,compare-op,identifier)))))
+
+# && And
+ok PRQL.parse('filter foo && bar');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,logic-op,identifier)))))
+
+# || Or
+ok PRQL.parse('filter foo || bar');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,logic-op,identifier)))))
+
+# ?? Coalesce
+ok PRQL.parse('filter foo ?? bar');
+#query(pipeline(call-expression(identifier,arg-list(binary-expression(identifier,logic-op,identifier)))))
+
+# Unary operator -
+ok PRQL.parse('sort { -name }');
+#query(pipeline(call-expression(identifier,arg-list(tuple-expression(unary-expression(arith-op,identifier))))))
+
+# Unary operator ==
+ok PRQL.parse('join customers (==customer_id)');
+#query(pipeline(call-expression(identifier,arg-list(identifier,parenthesized-expression(unary-expression(compare-op,identifier))))))
diff --git a/grammars/raku/t/strings.rakutest b/grammars/raku/t/strings.rakutest
new file mode 100644
index 000000000000..86b06121bb66
--- /dev/null
+++ b/grammars/raku/t/strings.rakutest
@@ -0,0 +1,48 @@
+use Test;
+use prql;
+
+plan 11;
+
+# Single-quoted string
+ok PRQL.parse("filter 'Hello'");
+#query(pipeline(call-expression(identifier,arg-list(string))))
+
+# Double-quoted string
+ok PRQL.parse('filter "Hello"');
+#query(pipeline(call-expression(identifier,arg-list(string))))
+
+# Single-quoted f-string
+ok PRQL.parse("filter f'Hello \{name\}!'");
+#query(pipeline(call-expression(identifier,arg-list(f-string))))
+
+# Double-quoted f-string
+ok PRQL.parse('filter f"Hello {name}!"');
+#query(pipeline(call-expression(identifier,arg-list(f-string))))
+
+# Single-quoted r-string
+ok PRQL.parse("filter r'version()'");
+#query(pipeline(call-expression(identifier,arg-list(r-string))))
+
+# Double-quoted r-string
+ok PRQL.parse('filter r"version()"');
+#query(pipeline(call-expression(identifier,arg-list(r-string))))
+
+# Single-quoted s-string
+ok PRQL.parse("filter s'version()'");
+#query(pipeline(call-expression(identifier,arg-list(s-string))))
+
+# Double-quoted s-string
+ok PRQL.parse('filter s"version()"');
+#query(pipeline(call-expression(identifier,arg-list(s-string))))
+
+# Triple-quoted single-quoted string
+ok PRQL.parse("filter '''Hello world!'''");
+#query(pipeline(call-expression(identifier,arg-list(string))))
+
+# Triple-quoted double-quoted string
+ok PRQL.parse('filter """Hello world!"""');
+#query(pipeline(call-expression(identifier,arg-list(string))))
+
+# Escape sequence
+ok PRQL.parse('filter "\xff"');
+#query(pipeline(call-expression(identifier,arg-list(string(escape)))))
diff --git a/grammars/raku/t/tuples.rakutest b/grammars/raku/t/tuples.rakutest
new file mode 100644
index 000000000000..bf38478ab569
--- /dev/null
+++ b/grammars/raku/t/tuples.rakutest
@@ -0,0 +1,44 @@
+use Test;
+use prql;
+
+plan 5;
+
+# Tuple on one line
+ok PRQL.parse('test {foo, bar, baz}');
+#query(pipeline(call-expression(identifier,arg-list(tuple-expression(identifier,identifier,identifier)))))
+
+# Tuple on multiple lines
+ok PRQL.parse(q:to/END/);
+test {
+  foo,
+  bar,
+  baz
+}
+END
+#query(pipeline(call-expression(identifier,arg-list(tuple-expression(identifier,identifier,identifier)))))
+
+# Tuple on multiple lines with blank lines
+ok PRQL.parse(q:to/END/);
+test {
+
+  foo,
+
+  bar,
+
+  baz
+
+}
+END
+#query(pipeline(call-expression(identifier,arg-list(tuple-expression(identifier,identifier,identifier)))))
+
+# Tuple with key and value
+ok PRQL.parse('test {foo=bar}');
+#query(pipeline(call-expression(identifier,arg-list(tuple-expression(declaration-tuple(declaration-item,equals,identifier))))))
+
+# Tuple with keys and values
+ok PRQL.parse(q:to/END/);
+test {identifier=identifier,int  =3, float=  3.14 ,
+string    =    "string"
+}
+END
+#query(pipeline(call-expression(identifier,arg-list(tuple-expression(declaration-tuple(declaration-item,equals,identifier),declaration-tuple(declaration-item,equals,integer),declaration-tuple(declaration-item,equals,float),declaration-tuple(declaration-item,equals,string))))))