新建列：

Day of Week = WEEKDAY(AW\_Calendar\_Lookup[Date],2)

Short Day = UPPER(LEFT(AW\_Calendar\_Lookup[Day Name],3))

Short Month = UPPER(LEFT(AW\_Calendar\_Lookup[Month Name],3))

Weekend = IF(AW\_Calendar\_Lookup[Day of Week]=6 || AW\_Calendar\_Lookup[Day of Week]=7,"Weekend","Weekday")

BirthYear\_CC = AW\_Customer\_Lookup[BirthDate].[Year]

Current Age = DATEDIFF(AW\_Customer\_Lookup[BirthDate],TODAY(),YEAR)

Customer Priority = IF(AW\_Customer\_Lookup[Current Age]<50 && AW\_Customer\_Lookup[AnnualIncome]>100000,"Priority","Standard")

FullName\_CC = AW\_Customer\_Lookup[Prefix] & " " & AW\_Customer\_Lookup[FirstName] & " " & AW\_Customer\_Lookup[LastName]

Parent = IF(AW\_Customer\_Lookup[TotalChildren]>0,"Yes","No")

Price Point = IF(AW\_Product\_Lookup[ProductPrice]>500,"High",IF(AW\_Product\_Lookup[ProductPrice]>100,"Mid-Range","Low"))

SKU Category = LEFT(AW\_Product\_Lookup[ProductSKU],SEARCH("-",AW\_Product\_Lookup[ProductSKU])-1)

QuantityType = IF(AW\_Sales[OrderQuantity]>1,"Multiple Items","Single Item")

新建度量值：

Adjusted Price = [Avg Retail Price] \* (1 + 'Price Adjustment (%)'[Price Adjustment (%) Value])

Avg Retail Price = AVERAGE(AW\_Product\_Lookup[ProductPrice])

Overall Avg Price = CALCULATE([Avg Retail Price],ALL(AW\_Product\_Lookup))

Product Models = DISTINCTCOUNT(AW\_Product\_Lookup[ModelName])

% of All Returns = [Total Returns] / [ALL Returns]

ALL Returns = CALCULATE([Total Returns], ALL(AW\_Returns))

Bike Returns = CALCULATE([Total Returns], AW\_Product\_Category\_Lookup[CategoryName] = "Bikes")

Prev Month Returns = CALCULATE([Total Returns], DATEADD(AW\_Calendar\_Lookup[Date],-1,MONTH))

Quantity Returned = SUM(AW\_Returns[ReturnQuantity])

Return Rate = DIVIDE([Quantity Returned],[Quantity Sold],"No Sales")

Total Returns = COUNTA(AW\_Returns[ReturnQuantity])

% of All Orders = [Total Orders] / [ALL Orders]

10-day Rolling Revenue = CALCULATE([Total Revenue], DATESINPERIOD(AW\_Calendar\_Lookup[Date], MAX(AW\_Calendar\_Lookup[Date]),-10,DAY))

90-day Rolling Profit = CALCULATE([Total Profit], DATESINPERIOD(AW\_Calendar\_Lookup[Date],MAX(AW\_Calendar\_Lookup[Date]),-90,DAY))

Adjusted Profit = [Adjusted Revenue] - [Total Cost]

Adjusted Revenue = SUMX(AW\_Sales, AW\_Sales[OrderQuantity] \* [Adjusted Price])

ALL Orders = CALCULATE([Total Orders],ALL(AW\_Sales))

Bulk Orders = CALCULATE([Total Orders],AW\_Sales[OrderQuantity] > 1)

High Ticket Orders = CALCULATE([Total Orders], FILTER(AW\_Product\_Lookup,AW\_Product\_Lookup[ProductPrice] > [Overall Avg Price]))

Order Target = [Prev Month Orders] \* 1.1

Prev Month Orders = CALCULATE([Total Orders], DATEADD(AW\_Calendar\_Lookup[Date],-1,MONTH))

Prev Month Revenue = CALCULATE([Total Revenue], DATEADD(AW\_Calendar\_Lookup[Date],-1,MONTH))

Quantity Sold = SUM(AW\_Sales[OrderQuantity])

Revenue Target = [Prev Month Revenue] \* 1.1

Total Cost = SUMX(AW\_Sales, AW\_Sales[OrderQuantity] \* RELATED(AW\_Product\_Lookup[ProductCost]))

Total Orders = DISTINCTCOUNT(AW\_Sales[OrderNumber])

Total Profit = [Total Revenue] - [Total Cost]

Total Revenue = SUMX(AW\_Sales, AW\_Sales[OrderQuantity] \* RELATED(AW\_Product\_Lookup[ProductPrice]))

Weekend Orders = CALCULATE([Total Orders],AW\_Calendar\_Lookup[Weekend] = "Weekend")

YTD Revenue = CALCULATE([Total Revenue], DATESYTD(AW\_Calendar\_Lookup[Date]))

Modeling-new table：Price Adjustment (%) = GENERATESERIES(-1, 1, 0.1)

If we wanted to generate a table of values from -1 to 1,increments of 0.1

New measure：Price Adjustment (%) Value = SELECTEDVALUE('Price Adjustment (%)'[Price Adjustment (%)], 0)