[euler] solution for problem 66

categories/euler/prob065-andreoss.pl

@@ -3,7 +3,7 @@
 
 =begin pod
 
-=TITLE Square root digital expansion
+=TITLE Convergents of e
 
 =AUTHOR Andrei Osipov
 

categories/euler/prob066-andreoss.pl

@@ -0,0 +1,83 @@
+#!/usr/bin/perl6
+use v6;
+
+=begin pod
+
+=TITLE Diophantine equation
+
+=AUTHOR Andrei Osipov
+
+L<https://projecteuler.net/problem=66> 
+
+Consider quadratic Diophantine equations of the form:
+
+x² – D×y² = 1
+
+For example, when D=13, the minimal solution in x is 649² – 13×180² = 1.
+
+It can be assumed that there are no solutions in positive integers when D is square.
+
+By finding minimal solutions in x for D = {2, 3, 5, 6, 7}, we obtain the following:
+
+3²– 2×2²= 1
+2²– 3×1²= 1
+9²– 5×4²= 1
+5²– 6×2²= 1
+8²– 7×3²= 1
+
+Hence, by considering minimal solutions in x for D ≤ 7, the largest x is obtained when D=5.
+
+Find the value of D ≤ 1000 in minimal solutions of x for which the largest value of x is obtained.
+
+
+Expected result:  661
+
+The following algoritm was used for the solution:
+L<https://en.wikipedia.org/wiki/Chakravala_method>
+
+=end pod
+
+subset NonSquarable where *.sqrt !%% 1; 
+
+sub next-triplet([\a,\b,\k], \N) {
+
+    # finding minimal l
+    1 .. N.sqrt.floor
+	==> grep  -> \l { (a + b * l) %% k } \
+	==> sort  -> \l { abs(l ** 2 - N)  } \
+	==> my @r;
+
+    my \l = @r.shift;
+
+      (a * l + N * b) / abs(k)
+    , (a + b * l)     / abs(k)
+    , (l ** 2 - N )   / k
+}
+
+sub simple-solution(NonSquarable \N) {
+
+    my $a = N.sqrt.floor;
+    my $b = 1;
+    my $k = $a ** 2 - N;
+
+    $a, $b, $k;
+}
+
+sub chakravala(NonSquarable \N) {
+    # Start with a solution for a² - N b² = k 
+
+    my ($a, $b, $k) = simple-solution N;
+
+    ($a,$b,$k) = next-triplet [$a,$b,$k], N
+	while $k != 1;
+
+    $a, $b, $k;
+}
+
+
+1 .. 1000
+    ==> grep NonSquarable                \
+    ==> map -> \D { [D, chakravala D] }  \
+    ==> sort *[2] ==> my @x;
+
+say @x.pop[0];

categories/euler/prob080-andreoss.pl

@@ -16,7 +16,7 @@
 For the first one hundred natural numbers, find the total of the digital sums of the first
 one hundred decimal digits for all the irrational square roots.
 
-The following algoritms was used for the solution:
+The following algoritm was used for the solution:
 L<http://www.afjarvis.staff.shef.ac.uk/maths/jarvisspec02.pdf>
 
 Expected result:  40886

t/categories/euler.t

@@ -408,6 +408,15 @@ subtest {
 subtest {
     plan 1;
 
+    my $problem = "prob066";
+    my @authors = <andreoss>;
+    my $expected-output = 661;
+
+    check-example-solutions($problem, $expected-output, @authors)
+}, "prob066";
+subtest {
+    plan 1;
+
     my $problem = "prob067";
     my @authors = <felher>;
     my $expected-output = 7273;