Merge branch 'master' of github.com:perl6/perl6-examples

categories/euler/prob065-andreoss.pl

@@ -0,0 +1,69 @@
+#!/usr/bin/env perl6
+use v6;
+
+=begin pod
+
+=TITLE Convergents of e
+
+=AUTHOR Andrei Osipov
+
+L<https://projecteuler.net/problem=65>
+
+
+
+The square root of 2 can be written as an infinite continued fraction.
+
+√2 = 1 +  1
+        ______
+	2 +  1
+           ______
+  	   2 + 	1
+  	      ______
+	      2 +  1
+  	  	 ______
+	         2 + ...
+
+The infinite continued fraction can be written, √2 = [1;(2)], (2) indicates that
+2 repeats ad infinitum. In a similar way, √23 = [4;(1,3,1,8)].
+
+It turns out that the sequence of partial values of continued fractions for square
+roots provide the best rational approximations. Let us consider the convergents for √2.
+	 
+1 + 1
+   ___              = 3/2
+    2 
+
+1 +    1
+    _________       = 7/5
+    2 +  1 / 2
+           
+....
+
+Hence the sequence of the first ten convergents for √2 are:
+1, 3/2, 7/5, 17/12, 41/29, 99/70, 239/169, 577/408, 1393/985, 3363/2378, ...
+
+What is most surprising is that the important mathematical constant,
+e = [2; 1,2,1, 1,4,1, 1,6,1 , ... , 1,2k,1, ...].
+
+The first ten terms in the sequence of convergents for e are:
+2, 3, 8/3, 11/4, 19/7, 87/32, 106/39, 193/71, 1264/465, 1457/536, ...
+
+The sum of digits in the numerator of the 10th convergent is 1+4+5+7=17.
+
+Find the sum of digits in the numerator of the 100th convergent of the continued fraction for e.
+
+
+Expected result:  272
+
+=end pod		      
+
+sub continued-fraction(@sequence, :$depth)  {
+    my $x = @sequence.shift;
+    return 1 if $depth == 1;
+    $x + 1.FatRat /
+	continued-fraction :depth($depth - 1), @sequence
+}
+
+my @e := gather { take 2;  take (1; $_; 1) for 2,4 ... * };
+
+say [+] continued-fraction(@e, depth => 100).numerator.comb;

categories/euler/prob066-andreoss.pl

@@ -0,0 +1,83 @@
+#!/usr/bin/perl6
+use v6;
+
+=begin pod
+
+=TITLE Diophantine equation
+
+=AUTHOR Andrei Osipov
+
+L<https://projecteuler.net/problem=66> 
+
+Consider quadratic Diophantine equations of the form:
+
+x² – D×y² = 1
+
+For example, when D=13, the minimal solution in x is 649² – 13×180² = 1.
+
+It can be assumed that there are no solutions in positive integers when D is square.
+
+By finding minimal solutions in x for D = {2, 3, 5, 6, 7}, we obtain the following:
+
+3²– 2×2²= 1
+2²– 3×1²= 1
+9²– 5×4²= 1
+5²– 6×2²= 1
+8²– 7×3²= 1
+
+Hence, by considering minimal solutions in x for D ≤ 7, the largest x is obtained when D=5.
+
+Find the value of D ≤ 1000 in minimal solutions of x for which the largest value of x is obtained.
+
+
+Expected result:  661
+
+The following algoritm was used for the solution:
+L<https://en.wikipedia.org/wiki/Chakravala_method>
+
+=end pod
+
+subset NonSquarable where *.sqrt !%% 1; 
+
+sub next-triplet([\a,\b,\k], \N) {
+
+    # finding minimal l
+    1 .. N.sqrt.floor
+	==> grep  -> \l { (a + b * l) %% k } \
+	==> sort  -> \l { abs(l ** 2 - N)  } \
+	==> my @r;
+
+    my \l = @r.shift;
+
+      (a * l + N * b) / abs(k)
+    , (a + b * l)     / abs(k)
+    , (l ** 2 - N )   / k
+}
+
+sub simple-solution(NonSquarable \N) {
+
+    my $a = N.sqrt.floor;
+    my $b = 1;
+    my $k = $a ** 2 - N;
+
+    $a, $b, $k;
+}
+
+sub chakravala(NonSquarable \N) {
+    # Start with a solution for a² - N b² = k 
+
+    my ($a, $b, $k) = simple-solution N;
+
+    ($a,$b,$k) = next-triplet [$a,$b,$k], N
+	while $k != 1;
+
+    $a, $b, $k;
+}
+
+
+1 .. 1000
+    ==> grep NonSquarable                \
+    ==> map -> \D { [D, chakravala D] }  \
+    ==> sort *[2] ==> my @x;
+
+say @x.pop[0];

categories/euler/prob080-andreoss.pl

@@ -0,0 +1,62 @@
+use v6;
+
+=begin pod
+
+=TITLE Square root digital expansion
+
+=AUTHOR Andrei Osipov
+
+L<https://projecteuler.net/problem=80> 
+
+It is well known that if the square root of a natural number is not an integer, then it is irrational.
+The decimal expansion of such square roots is infinite without any repeating pattern at all.
+The square root of two is 1.41421356237309504880..., and the digital sum of the first one
+hundred decimal digits is 475.
+
+For the first one hundred natural numbers, find the total of the digital sums of the first
+one hundred decimal digits for all the irrational square roots.
+
+The following algoritm was used for the solution:
+L<http://www.afjarvis.staff.shef.ac.uk/maths/jarvisspec02.pdf>
+
+Expected result:  40886
+ 
+=end pod
+
+use v6;
+
+my constant $limit = 100;
+
+sub sqrt-subtraction($n) {
+    my Int $a = $n * 5 ;
+    my Int $b = 5;
+    while $b < 10 * 10 ** $limit {
+	given $a <=> $b {
+	    when More | Same {
+		# replace a with a − b, and add 10 to b.
+		$a -=  $b;
+		$b += 10;
+	    }
+	    when Less {
+		# add two zeros to a
+		$a *= 100; 
+		# add a zero to b just before the final digit (which will always be ‘5’).
+		$b = ($b - (my $x = $b % 10)) * 10 + $x;
+	    }
+	}
+    }
+    $b;
+}
+
+sub MAIN(Bool :$verbose = False) {
+    say [+] do for 1 ... 100 -> $n {
+	next if $n.sqrt.floor ** 2 == $n; 
+	my $x = [+] $n.&sqrt-subtraction.comb[^$limit];
+	say "$n $x"  if $verbose;
+	$x;
+    }
+    say "Done in {now - INIT now}" if $verbose;
+}
+
+
+

t/categories/euler.t

@@ -396,7 +396,24 @@ subtest {
 
     check-example-solutions($problem, $expected-output, @authors)
 }, "prob063";
+subtest {
+    plan 1;
+
+    my $problem = "prob065";
+    my @authors = <andreoss>;
+    my $expected-output = 272;
+
+    check-example-solutions($problem, $expected-output, @authors)
+}, "prob065";
+subtest {
+    plan 1;
+
+    my $problem = "prob066";
+    my @authors = <andreoss>;
+    my $expected-output = 661;
 
+    check-example-solutions($problem, $expected-output, @authors)
+}, "prob066";
 subtest {
     plan 1;
 
@@ -406,7 +423,14 @@ subtest {
 
     check-example-solutions($problem, $expected-output, @authors)
 }, "prob067";
+subtest {
+    plan  1;
+    my $problem = "prob080";
+    my @authors = <andreoss>;
+    my $expected-output = 40886;
 
+    check-example-solutions($problem, $expected-output, @authors)
+}, "prob080";
 subtest {
     plan 1;