The program listed in this content shows how to use U2 BASIC's CallHTTP API to communicate with R/Link's REST API. The focus is on the /List, /FileGet, and /FilePut methods which are available through the API.

When the program is run, three menu options are available to the user:

1. List contents of shared folder U2upload <- this option uses the REST API's **/List** method

2. Display content of file in shared folder <- this option uses the REST API's **/FileGet** method

3. Upload file to shared folder <- this option uses the REST API's **/FilePut** method

**PROGRAM TEST.RLINK**

\* Program to interface with R/Link's REST API.

\* Uses U2's CallHTTP API to communicate with R/Link.

\* Methods /List, /FileGet, and /FilePut are used.

\* Program calls other subroutines to read JSON output in response data.

$INCLUDE INCLUDE UDO.H

EQU TRUE TO 1

EQU FALSE TO 0

PROMPT ''

PROTOCOL = 'https'

PRINT 'Enter user name : ': ; INPUT USERNAME

PRINT 'Enter password : ': ; INPUT PASSWORD

TIMEOUT = 10000

IGNORE = ''

FOLDER.CONTENTS = ''

!

\* Display Menu

DSP.MENU.OPTS = 'List contents of shared folder U2upload'

DSP.MENU.OPTS<-1> = 'Display content of file in shared folder'

DSP.MENU.OPTS<-1> = 'Upload file to shared folder'

LOOP

SILENT.LISTING = FALSE

LOOP

PRINT ; PRINT

FOR DSP = 1 TO DCOUNT(DSP.MENU.OPTS,@AM)

PRINT DSP:". ":DSP.MENU.OPTS<DSP>

NEXT DSP

PRINT

PRINT 'Enter selection or Q to quit: ':

INPUT ITEM.SEL

CONT = FALSE

IF (ITEM.SEL >= 1 AND ITEM.SEL <= DCOUNT(DSP.MENU.OPTS,@AM)) THEN CONT = TRUE

IF OCONV(ITEM.SEL,'MCU') = 'Q' THEN CONT = TRUE

UNTIL CONT DO

REPEAT

UNTIL ITEM.SEL = 'Q' DO

ON ITEM.SEL GOSUB LIST.FOLDER, DOWNLOAD.FILE, UPLOAD.FILE

REPEAT

RETURN

!

LIST.FOLDER:

\* List content of folder...

IF NOT(SILENT.LISTING) THEN PRINT ; PRINT 'Listing content of U2upload folder...'

HOST = 'myshare.rocketsoftware.com/myshare/api/List/My Shares/share/U2upload'

URL=PROTOCOL:'://':HOST:'?list\_contents=true&user\_id=':USERNAME:'&password=':PASSWORD

!

STATUS = setHTTPDefault('VERSION', '1.1')

\*

\* use either SSLV3 OR TLSV1 security protocol

STATUS = createsecuritycontext(sec\_context,"tlsv1")

STATUS = createSecureRequest(URL, 'GET', restGET,sec\_context)

STATUS = submitRequest(restGET, TIMEOUT, IGNORE, Header, restData, httpStatus)

restData=CHANGE(restData, '{', '{':CHAR(10))

restData=CHANGE(restData, ',', ',':CHAR(10))

restData=CHANGE(restData, '}', '}':CHAR(10))

IF NOT(SILENT.LISTING) THEN

PRINT ; PRINT 'URL:':URL

PRINT ; PRINT 'Response status: ':httpStatus

PRINT 'Response headers:':Header

PRINT; PRINT 'Response data:':CHAR(10):restData

END

GOSUB PROCESS.LISTING

RETURN

!

DOWNLOAD.FILE:

FOLDER.CONTENTS = ''

SILENT.LISTING = TRUE

GOSUB LIST.FOLDER

IF FOLDER.CONTENTS = '' THEN

PRINT 'No items to display in folder'

RETURN

END

LOOP

LOOP

PRINT ; PRINT

FOR FDSP = 1 TO DCOUNT(FOLDER.CONTENTS<1>,@VM)

PRINT FDSP:". ":FOLDER.CONTENTS<1,FDSP>

NEXT FDSP

PRINT

PRINT 'Enter number for the corresponding file to view or <Enter> to return: ':

INPUT FILE.SEL

CONT = FALSE

IF FILE.SEL = '' THEN RETURN

IF (FILE.SEL >= 1 AND FILE.SEL <= DCOUNT(FOLDER.CONTENTS<1>,@VM)) THEN CONT = TRUE

UNTIL CONT DO

REPEAT

UNTIL FILE.SEL = '' DO

DL.FILE = FOLDER.CONTENTS<1,FILE.SEL>

GOSUB GET.FILE

REPEAT

RETURN

!

GET.FILE:

PRINT ; PRINT

\* Use FileGet method of R/Link's REST API

PATH.OF.FILE = 'myshare.rocketsoftware.com/myshare/api/FileGet':DL.FILE

PRINT 'Show content of ':DL.FILE:' using FileGet method...'

HOST = PATH.OF.FILE

\*

URL=PROTOCOL:'://':HOST:'?user\_id=':USERNAME:'&password=':PASSWORD

STATUS = setHTTPDefault('VERSION', '1.1')

\*

\* use either SSLV3 OR TLSV1 security protocol

STATUS = createsecuritycontext(sec\_context,"tlsv1")

STATUS = createSecureRequest(URL, 'GET', restGET,sec\_context)

STATUS = submitRequest(restGET, TIMEOUT, IGNORE, Header, restData, httpStatus)

restData=CHANGE(restData, '{', '{':CHAR(10))

restData=CHANGE(restData, ',', ',':CHAR(10))

restData=CHANGE(restData, '}', '}':CHAR(10))

PRINT ; PRINT 'URL:':URL

PRINT ; PRINT 'Response status: ':httpStatus

PRINT 'Response headers:':Header

PRINT; PRINT 'Response data:':CHAR(10):restData

RETURN

!

PROCESS.LISTING:

restData = CHANGE(restData,':false',':0')

restData = CHANGE(restData,':true',':1')

inputString = restData

outputString = "" ; udoHandle = ''

STATUS = UDORead(inputString, UDOFORMAT\_JSON, udoHandle)

IF STATUS = UDO\_SUCCESS THEN PRINT "OK" ELSE STOP "NOT OK"

myStatus = UDOGetType( udoHandle, THETYPE )

BEGIN CASE

CASE THETYPE = UDO\_OBJECT

CALL jsonObjectSub( udoHandle, FOLDER.CONTENTS )

CASE THETYPE = UDO\_ARRAY

CALL jsonArraySub(udoHandle, FOLDER.CONTENTS)

CASE 1

NULL

END CASE

FOR FLDR = DCOUNT(FOLDER.CONTENTS<1>,@VM) TO 1 STEP -1

IF FOLDER.CONTENTS<2,FLDR> = 1 THEN

FOLDER.CONTENTS = DELETE(FOLDER.CONTENTS,1,FLDR)

FOLDER.CONTENTS = DELETE(FOLDER.CONTENTS,2,FLDR)

END

NEXT FLDR

RETURN

!

UPLOAD.FILE:

PRINT; PRINT 'Specify database file: ':

INPUT DB.FILE

OPEN '',DB.FILE TO DB.FILE ELSE

PRINT 'Cannot open database file'

RETURN

END

PRINT 'Specify the record containing the data: ':

INPUT DB.REC

READ ITEM FROM DB.FILE, DB.REC ELSE ITEM = ''

IF ITEM = '' THEN

PRINT 'Either the record does not exist or there is no content'

RETURN

END

HOST = 'myshare.rocketsoftware.com/myshare/api/FilePut/My Shares/share/U2upload'

URL=PROTOCOL:'://':HOST:'/':DB.REC:'?user\_id=':USERNAME:'&password=':PASSWORD:'&overwrite=false'

STATUS = setHTTPDefault('VERSION', '1.1')

STATUS = createsecuritycontext(sec\_context,"tlsv1")

STATUS = createSecureRequest(URL, 'POST:application/octet-stream', restPUT,sec\_context)

IF STATUS # 0 THEN ABORT 'createRequest has failed, code: ':STATUS

STATUS = addRequestParameter(restPUT, 'uploadedfile', ITEM, 'Content-Disposition: form-data; filename="':DB.REC:'"')

IF STATUS # 0 THEN ABORT 'addRequestParameter has failed, code: ':STATUS

STATUS = submitRequest(restPUT, TIMEOUT, IGNORE, Header, restData, httpStatus)

IF STATUS = 2 AND httpStatus<1,1> = 200 THEN STATUS = 0 ; \* ignore

IF STATUS # 0 THEN ABORT 'submitRequest failed with code: ':STATUS

restData=CHANGE(restData, '{', '{':CHAR(10))

restData=CHANGE(restData, ',', ',':CHAR(10))

restData=CHANGE(restData, '}', '}':CHAR(10))

PRINT ; PRINT 'URL:':URL

PRINT ; PRINT 'Response status: ':httpStatus

PRINT 'Response headers:':Header

PRINT; PRINT 'Response data:':CHAR(10):restData

RETURN

!

END

Subroutines called by TEST.RLINK evaluate items in the response data when the /List method is called. The response data returns a JSON Object.

These subroutines are named jsonArraySub and jsonObjectSub.

**SUBROUTINE jsonArraySub(udoHandle, FOLDER.CONTENTS)**

\*

$INCLUDE INCLUDE UDO.H

\*

cnt = 0

LOOP

STAT = UDOArrayGetNextItem(udoHandle, VAL\_OUT, TYPE\_OUT)

UNTIL STAT NE UDO\_SUCCESS DO

cnt += 1

BEGIN CASE

CASE TYPE\_OUT = UDO\_FALSE

TYPE\_NAME = "False"

CASE TYPE\_OUT = UDO\_TRUE

TYPE\_NAME = "True"

CASE TYPE\_OUT = UDO\_NULL

TYPE\_NAME = "Null"

CASE TYPE\_OUT = UDO\_NUMBER

TYPE\_NAME = "Number"

CASE TYPE\_OUT = UDO\_STRING

TYPE\_NAME = "String"

CASE TYPE\_OUT = UDO\_ARRAY

TYPE\_NAME = "Array"

CALL jsonArraySub( VAL\_OUT, FOLDER.CONTENTS )

CASE TYPE\_OUT = UDO\_OBJECT

TYPE\_NAME = "Object"

CALL jsonObjectSub(VAL\_OUT, FOLDER.CONTENTS)

END CASE

REPEAT

STAT = UDOFree(udoHandle)

RETURN

END

**SUBROUTINE jsonObjectSub(udoHandle, FOLDER.CONTENTS)**

\*

$INCLUDE INCLUDE UDO.H

\*

LOOP

STAT = UDOGetNextProperty(udoHandle, NAME, VAL\_OUT, TYPE\_OUT)

UNTIL STAT # UDO\_SUCCESS DO

BEGIN CASE

CASE TYPE\_OUT = UDO\_ARRAY

TYPE\_NAME = "Array"

CALL jsonArraySub( VAL\_OUT, FOLDER.CONTENTS )

CASE TYPE\_OUT = UDO\_OBJECT

TYPE\_NAME = "Object"

CALL jsonObjectSub( VAL\_OUT, FOLDER.CONTENTS )

CASE 1

BEGIN CASE

CASE TYPE\_OUT = UDO\_FALSE

TYPE\_NAME = "False"

CASE TYPE\_OUT = UDO\_TRUE

TYPE\_NAME = "True"

CASE TYPE\_OUT = UDO\_NULL

TYPE\_NAME = "Null"

CASE TYPE\_OUT = UDO\_NUMBER

TYPE\_NAME = "Number"

CASE TYPE\_OUT = UDO\_STRING

TYPE\_NAME = "String"

END CASE

IF NAME = "path" THEN FOLDER.CONTENTS<1,-1> = VAL\_OUT

IF NAME = "is\_container" THEN FOLDER.CONTENTS<2,-1> = VAL\_OUT

END CASE

REPEAT

STAT = UDOFree(udoHandle)

RETURN

END

Output of running the program Below. Options 1 through 3 are selected.

>RUN BP TEST.RLINK

Enter user name : MYUSERID

Enter password : MYPASSWORD

1. List contents of shared folder U2upload

2. Display content of file in shared folder

3. Upload file to shared folder

**Enter selection or Q to quit:** **1**

Listing content of U2upload folder...

URL:https://myshare.rocketsoftware.com/myshare/api/List/My Shares/share/U2upload?list\_contents=true&user\_id=MYUSERID&password=MYPASSWORD

Response status: 200]OK

Response headers:Server]Apache-Coyote/1.1

Cache-Control]private~Expires]Wed, 31 Dec 1969 16:00:00 PST

Set-Cookie]JSESSIONID=290E201936E42F93B078BF219F2C9220; Path=/myshare/; Secure~Content-Type]application/json~Date]Mon, 10 Nov 2014 05:01:50 GMT

Response data:

{

"items":[{

"path":"/My Shares/share/U2upload/getting started.pdf",

"size":"92.88 KB",

"bytes":95111,

"is\_container":false,

"hash":"z1iiQVOzSmrxZRpjxo5q-T8e-VahXk2HLskZqYrAado",

"icon\_exists":false,

"icon":"PDF",

"date\_modified":"Mon,

29 Sep 2014 19:19:53 -0700",

"shared\_by":"",

"root":"/My Shares"}

,

{

"path":"/My Shares/share/U2upload/TestDownload.txt",

"size":"25 Bytes",

"bytes":25,

"is\_container":false,

"hash":"xCk-d1XGSyBJAWmAz0hRTyAd6n53ndfM-wkrXAV23l8",

"icon\_exists":false,

"icon":"TXT",

"date\_modified":"Tue,

30 Sep 2014 21:10:41 -0700",

"shared\_by":"",

"root":"/My Shares"}

],

"path":"/My Shares/share/U2upload",

"size":"0 Bytes",

"bytes":-1,

"is\_container":true,

"hash":"xyG2oj69KOYjN24Z0suTk3f0PcqJgvS71P9\_klrRNp4",

"icon\_exists":false,

"icon":"FOLDER",

"date\_modified":"Sun,

09 Nov 2014 20:59:53 -0800",

"shared\_by":"",

"root":"/My Shares",

"ok":true}

1. List contents of shared folder U2upload

2. Display content of file in shared folder

3. Upload file to shared folder

**Enter selection or Q to quit: 2**

1. /My Shares/share/U2upload/getting started.pdf

2. /My Shares/share/U2upload/TestDownload.txt

Enter number for the corresponding file to view or <Enter> to return: 2

Show content of /My Shares/share/U2upload/TestDownload.txt using FileGet method...

URL:https://myshare.rocketsoftware.com/myshare/api/FileGet/My Shares/share/U2upload/TestDownload.txt?user\_id=MYUSERID&password=MYPASSWORD

Response status: 200]OK

Response headers:Server]Apache-Coyote/1.1

Cache-Control]private

Expires]Wed, 31 Dec 1969 16:00:00 PST

Set-Cookie]JSESSIONID=E438BBDA80C11D8348D483889BD40CE5; Path=/myshare/; Secure~Content-Type]text/plain~Date]Mon, 10 Nov 2014 05:02:02 GMT

Response data:

**Test Download from R/Link**

1. /My Shares/share/U2upload/getting started.pdf

2. /My Shares/share/U2upload/TestDownload.txt

Enter number for the corresponding file to view or <Enter> to return:

1. List contents of shared folder U2upload

2. Display content of file in shared folder

3. Upload file to shared folder

**Enter selection or Q to quit: 3**

Specify database file: &UFD&

Specify the record containing the data: TestUpload.txt

URL:https://myshare.rocketsoftware.com/myshare/api/FilePut/My Shares/share/U2upload/TestUpload.txt?user\_id=MYUSERID&password=MYPASSWORD&overwrite=false

Response status: 200]OK

Response headers:Server]Apache-Coyote/1.1

Set-Cookie]JSESSIONID=175B3C72F336FFF0EB8CC0157403462D; Path=/myshare/; Secure~Content-Type]text/html~Date]Mon, 10 Nov 2014 05:02:22 GMT

Response data:

{

"path":"My Shares/share/U2upload/TestUpload.txt",

"size":"61 Bytes",

"bytes":61,

"is\_container":false,

"icon\_exists":false,

"icon":"TXT",

"date\_modified":"Sun,

09 Nov 2014 21:02:22 -0800",

"shared\_by":"",

"root":"/My Shares",

"ok":true}

1. List contents of shared folder U2upload

2. Display content of file in shared folder

3. Upload file to shared folder

**Enter selection or Q to quit: 2**

1. /My Shares/share/U2upload/getting started.pdf

2. /My Shares/share/U2upload/TestDownload.txt

3. /My Shares/share/U2upload/TestUpload.txt

Enter number for the corresponding file to view or <Enter> to return: 3

Show content of /My Shares/share/U2upload/TestUpload.txt using FileGet method...

URL:https://myshare.rocketsoftware.com/myshare/api/FileGet/My Shares/share/U2upload/TestUpload.txt?user\_id=MYUSERID&password=MYPASSWORD

Response status: 200]OK

Response headers:Server]Apache-Coyote/1.1~Cache-Control]private~Expires]Wed, 31 Dec 1969 16:00:00 PST~Set-Cookie]JSESSIONID=8FF71C9A94CBEE40433C63418665C86F; Path=/myshare/; Secure~Content-Type]text/plain~Date]Mon, 10 Nov 2014 05:15:37 GMT

Response data:

uploadedfile=These are the latest changes in this document...

1. /My Shares/share/U2upload/getting started.pdf

2. /My Shares/share/U2upload/TestDownload.txt

3. /My Shares/share/U2upload/TestUpload.txt

Enter number for the corresponding file to view or <Enter> to return:

1. List contents of shared folder U2upload

2. Display content of file in shared folder

3. Upload file to shared folder

Enter selection or Q to quit: Q

>