Permalink
Find file
Fetching contributors…
Cannot retrieve contributors at this time
168 lines (139 sloc) 4.36 KB
buildscript {
repositories {
jcenter()
mavenCentral()
maven { url = "http://files.minecraftforge.net/maven" }
maven { url = "https://oss.sonatype.org/content/repositories/snapshots/" }
}
dependencies { classpath 'net.minecraftforge.gradle:ForgeGradle:2.2-SNAPSHOT' }
}
plugins {
id "com.matthewprenger.cursegradle" version "1.0.7"
}
apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'maven-publish'
ext.buildnumber = 0
if (System.getenv('BUILD_NUMBER') != null)
project.buildnumber = System.getenv('BUILD_NUMBER')
else
logger.lifecycle "No build number detected, setting to 0"
group = "com.enderio.enderzoo"
archivesBaseName = "EnderZoo"
version = "${minecraft_version}-${mod_version}.${buildnumber}"
boolean dev = System.getenv("RELEASE") == null || System.getenv("RELEASE").equalsIgnoreCase("false")
def type = 'release'
if (project.hasProperty('mod_appendix')) {
version += "-${project.mod_appendix}"
type = project.mod_appendix
}
minecraft {
mappings = "snapshot_20160518"
version = "${minecraft_version}-${forge_version}"
runDir = 'run'
replace "@VERSION@", project.version
replaceIn "EnderZoo.java"
}
configurations {
compile.extendsFrom exportedCompile
}
repositories {
mavenCentral()
maven { url "http://mobiusstrip.eu/maven" }
}
dependencies {
compile "mcp.mobius.waila:Waila:${waila_version}"
}
sourceSets {
main {
java {
srcDir 'src/main/java'
}
resources {
srcDir 'resources'
}
}
}
processResources {
inputs.property "version", project.version
inputs.property "mcversion", project.minecraft.version
from(sourceSets.main.resources.srcDirs) {
include '**/*.info'
include '**/*.properties'
expand 'version': project.version, 'mcversion': project.minecraft.version
}
from(sourceSets.main.resources.srcDirs) {
exclude '**/*.info'
exclude '**/*.properties'
}
}
jar {
from { configurations.exportedCompile.collect { it.isDirectory() ? it : zipTree(it) } }
}
if (JavaVersion.current().isJava8Compatible()) {
allprojects {
tasks.withType(Javadoc) {
options.addStringOption('Xdoclint:none', '-quiet')
}
}
}
build.dependsOn sourceJar
publishing {
tasks.publish.dependsOn 'build'
publications {
mavenJava(MavenPublication) {
from components.java
artifact sourceJar
}
}
repositories {
if (project.hasProperty('mavendir')) {
maven { url mavendir }
} else {
mavenLocal()
}
}
}
task checkTranslations << {
Map<String, String> mapen = new HashMap<String, String>()
(new File('resources/assets/enderio/lang/en_US.lang')).eachLine {
def (value1, value2) = it.tokenize( '=' )
if (value1 == null || value2 == null) {return}
mapen.put(value1, value2)
}
new File('resources/assets/enderio/lang/').eachFileMatch( ~".*\\.lang\$" ) { langfile ->
if (!langfile.getName().contains("en_US")) {
Map<String, String> map = new HashMap<String, String>()
File outfile = new File("${langfile}.txt")
Writer outwriter = outfile.newWriter("UTF8")
outwriter.write("\n// Additional translations:\n")
outwriter << langfile.filterLine {
def (value1, value2) = it.tokenize( '=' )
if (value1 == null || value2 == null) {return false}
map.put(value1, value2)
return !mapen.containsKey(value1)
}
outwriter.append("\n// Missing translations:\n")
for (e in mapen) {
if (!map.containsKey(e.key)) {
outwriter.append(e.key + "=" + e.value + "\n")
}
}
println "Created translation report ${outfile}"
}
}
}
tasks.curseforge.enabled = !dev && project.hasProperty('curseforge_key')
curseforge {
if (project.hasProperty('curseforge_key')) {
apiKey = project.curseforge_key
}
project {
id = project.projectId
changelog = System.getenv('CHANGELOG') == null || System.getenv('CHANGELOG').equals('none') ? "NA" : System.getenv('CHANGELOG')
changelogType = 'html'
releaseType = type
mainArtifact(jar) {
displayName = "${archivesBaseName} - ${version}"
}
}
}