**Лабораторна робота №6**

**«Ієрархічна модель даних в СКБД Caché. Зберігання даних у вигляді глобалів»**

**Прямий доступ до даних**

Змінні як локальні, так і глобальні можуть існувати у вигляді простих або індексованих структур. Глобальні змінні або глобали, будучи даними, що зберігаються, створюють основу так званого прямого доступу. Багатомірність даних реалізована через індекси, тому говорять про індексовані змінні. Таблиця демонструє відмінності між змінними:

|  |  |  |
| --- | --- | --- |
| **Тип змінної** | **Локальна** | **Глобальна** |
| Скалярна | Name=Іванов | ^Name=Іванов |
| Багатомірна | Book(Nomer)=Солярис|Лемм С. | ^Book(Nomer)=Солярис|Лемм С. |

Змінна Name – скалярна, вона не зберігається в базі даних. Змінна ^Name – глобальна, вона зберігається в базі даних.

Змінні Book і ^Book – це індексовані змінні, на відміну від змінних Name і ^Name. Змінна ^Book є глобальною, тобто зберігається в базі даних.

Глобали - це структури даних, як правило, багатомірні, які зберігаються в базі даних і можуть оброблятися в розрахованому на багато користувачів середовищі різними процесами. Обробка глобалів в Caché достатньо проста: за допомогою команди Set глобалу привласнюється значення, яке може бути або простим або представляти собою список значень. В останньому випадку слід скористатись функцією створення списку $listbuild().

Створимо глобал відповідно до описаної вище структури шляхом написання підпрограми CreateUniversityGlobal у термінальній програмі University.Global. Дана підпрограма вхідних параметрів не має, її назва вказується за допомогою мітки, що описується починаючи з першого символу рядка. Нагадаємо, що для написання програмного коду в термінальних програмах рядок повинен починатись з проміжку, окрім того рядка, в якому описується мітка.

CreateUniversityGlobal  
 set ^Univer = "Чорноморський державний університет імені Петра Могили"  
 set ^Univer("Факультет комп'ютерних наук") = $listbuild("Мусієнко М.П.","76-55-74")  
 set ^Univer("Факультет економічних наук") = $listbuild("Іщенко Н.М.","46-41-26")  
 set ^Univer("Факультет політичних наук") = $listbuild("Шевчук О.В.","76-55-53")  
 set ^Univer("Інститут філології") = $listbuild("Пронкевич О.В.","76-92-60")   
 set ^Univer("Юридичний факультет") = $listbuild("Січко Д.С.","76-55-65")   
 set ^Univer("Факультет соціології") = $listbuild("Ляпіна Л.А.","76-55-52")  
 set ^Univer("Медичний інститут") = $listbuild("Лебідь С.М.","76-55-54")  
   
 set ^Univer("Факультет комп'ютерних наук",101) = "Бурлаченко І.С."  
 set ^Univer("Факультет комп'ютерних наук",102) = "Давиденко Є.О."  
 set ^Univer("Факультет комп'ютерних наук",103) = "Нездолій Ю.О."  
 set ^Univer("Факультет комп'ютерних наук",105) = "Крайник Я.М."  
 set ^Univer("Факультет комп'ютерних наук",106) = "Корецька О.С."  
 set ^Univer("Факультет комп'ютерних наук",107) = "Кулаковська І.В."  
 set ^Univer("Факультет комп'ютерних наук",201) = "Боровльова С.Ю."  
 set ^Univer("Факультет комп'ютерних наук",202) = "Швед А.В."  
 set ^Univer("Факультет комп'ютерних наук",203) = "Солобуто Л.В."  
 set ^Univer("Факультет комп'ютерних наук",205) = "Салтовський Б.Г."  
 set ^Univer("Факультет комп'ютерних наук",206) = "Горбань Г.В."  
   
 set ^Univer("Факультет комп'ютерних наук",101,1510101) = "Антонюк В.А."  
 set ^Univer("Факультет комп'ютерних наук",101,1510102) = "Бондаренко У.А."  
 set ^Univer("Факультет комп'ютерних наук",101,1510103) = "Головатий В.Р."  
 set ^Univer("Факультет комп'ютерних наук",101,1510104) = "Доробанський М.Ю."  
 set ^Univer("Факультет комп'ютерних наук",101,1510105) = "Задорожна О.А."  
 set ^Univer("Факультет комп'ютерних наук",101,1510106) = "Іващенко С.В."  
 set ^Univer("Факультет комп'ютерних наук",101,1510107) = "Каланжова А.С."  
 set ^Univer("Факультет комп'ютерних наук",101,1510108) = "Кліменко Д.О."  
 set ^Univer("Факультет комп'ютерних наук",101,1510109) = "Корбут В.В."  
 set ^Univer("Факультет комп'ютерних наук",101,1510110) = "Лепетинський Е.Р."  
 set ^Univer("Факультет комп'ютерних наук",101,1510111) = "Місюк Т.О."  
 set ^Univer("Факультет комп'ютерних наук",101,1510112) = "Олейніченко Є.Є."  
 set ^Univer("Факультет комп'ютерних наук",101,1510113) = "Осадчий А.О."


Для того, щоб виконати дану підпрограму потрібно у Терміналі написати наступну команду:

do CreateUniversityGlobal^University.Global,


де CreateUniversityGlobal – назва підпрограми, University.Global – назва загальної програми, у якій дана підпрограма описана та реалізована.

**Перегляд даних глобалів**


Подібно до перегляду реляційного представлення даних у Порталі управління системою можливий перегляд даних, що зберігаються у глобалах. Для цього потрібно скористатись шляхом **System Explorer -> Глобали**.



При переході за даним пунктом меню буде відображений список збережений у відповідній області даних (нагадаємо, що у кожного студента вона своя). Тут ми побачимо і створений глобал ^Univer. Його вміст можна переглянути, здійснивши перехід за відповідним посиланням **VIEW** для нього.



Після цього будуть відображені дані глобалу ^Univer, що був створений шляхом виконання описаної вище підпрограми CreateUniversityGlobal.



**Обробка даних глобалів**

Мова Caché Object Script має достатньо гнучкий засіб обробки даних глобалів за допомогою вбудованих функцій $data, $get, $order та $query (див. лекцію №8). Наведемо деякі приклади роботи з даними глобалів.


У вже створеній термінальній програмі University.Global.mac створимо іншу підпрограму під назвою GetStudents, призначення якої полягає у отриманні списку студентів, що належать до певної групи. Оскільки номер групи є індексом глобалу другого рівня, а індексом першого рівня є назва факультету, задамо для даної підпрограми відповідні аргументи: faculty та group. Програмний код підпрограми GetStudents наведений нижче.

GetStudents(faculty,group)  
 set x = ""  
 for   
 {  
  set x=$order(^Univer(faculty,group,x))  
  quit:x=""  
  write x //виведення на екран номеру залікової книжки студента у якості індексу 3 рівня глобалу  
  write " ",^Univer(faculty,group,x),! //виведення на екран значення глобалу, яке зберігає у собі прізвище студента   
 }

У коді підпрограми використовується вбудована функція $order, що дозволяє отримати дані глобалу певного рівня за кожним з його індексів. У даному випадку перші два індекси глобалу ^Univer мають фіксовані значення, що відповідно вказані в аргументах faculty та group. Третім індексом глобалу ^Univer є номер залікової книжки студента, а його значеннями на третьому рівні будуть прізвище та ініціали відповідного студента.

Почергово у циклі for (який до того ж оголошений як нескінченний) у змінну x будуть витягнуті всі індекси третього рівня, а саме номера залікових книжок студентів, після чого на екран буде виведене відповідне значення глобалу за отриманою сукупністю індексів.

Викликавши підпрограму GetStudents у Терміналі з параметрами «Факультет комп’ютерних наук» та 101 група у якості її аргументів, отримаємо наступний результат.




Якщо глобал на певному рівні має більш ніж одне значення, воно представляється у вигляді списків. Для отримання таких значень треба скористатись вбудованими функціями роботи зі списками (див. лекцію №6).

У якості прикладу напишемо підпрограму з назвою GetFacultiesInformation, яка виводить на екран інформацію про факультет: прізвище та ініціали його декана та телефон деканату. Нагадаємо, що дана інформація зберігається у глобалі ^Univer на першому рівні вкладеності. Індексом першого рівня вкладеності є назва факультету, а значення складається зі списку, першим елементом якого є прізвище та ініціали декана, а другим – телефон деканату. При витягненні цих значень використовується вбудована функція $list.

Нижче наведений програмний код відповідної підпрограми.

GetFacultiesInformation  
 write "Факультет",?30,"Декан",?45,"Телефон",!  
 set x = ""  
 for  
 {  
 set x = $order(^Univer(x))  
  quit:x=""  
  set inf = ^Univer(x)  
  set dean = $listget(inf,1) //витяг ПІБ декана факультету  
  set phone = $listget(inf,2) //витяг телефону деканату факультету  
  write x //виведення на екран назви факультету у якості індексу 1 рівня глобалу  
  write ?30,dean,?45,phone,! //виведення інформації на екран  
 }

При виконанні даної підпрограми у Терміналі буде отриманий наступний результат.




**Збереження даних класів Caché у вигляді глобалів**

Кожний збережений клас, може зберігати свої екземпляри усередині бази даних, використовуючи один або кілька вузлів багатомірних даних (глобалів). При створенні класу компілятором класу автоматично створюються визначення двох глобалів: глобали даних та індексні глобали. При цьому справедливо наступне:

* Дані зберігаються в глобалі, ім'я якого починається з повного імені класу, тобто пакет.клас, при цьому праворуч до імені глобала даних додається буква “D”, до імені глобала індексу додається буква “I”;
* Дані кожного екземпляра зберігаються усередині єдиного вузла глобала даних, при цьому значення властивостей розміщаються в спискових структурах;
* Кожний вузол глобала даних має об'єктний ідентифікатор ID. За замовчуванням, значення ID це цілі числа, значення яких забезпечуються викликом функції $Increment;


При цьому для роботи з об'єктами можна використовувати або об'єктний доступ, або надзвичайно ефективний прямий доступ за допомогою глобалів.

Дані глобалів, що відповідають збереженим класам, також відображуютья у вкладці **«Глобали»** у порталі управління системою. Розглянемо, наприклад, глобал класу University.Department, який представляє дані про кафедри університету.



Якщо деякий збережений клас унаслідується від іншого збереженого класу, який не є абстрактим взагалі, або є абстрактним, але тип класу вказаний як Persistent, то глобал даних та індексний глобал для класу-нащадка не створюється. Відповідні класи будуть створені тільки для батьківського класу.

Нижче представлені дані глобалу класу University.Person. Нагадаємо, що даний клас є абстрактним, але типом класу є persistent, тобто у реляційному відображенні буде створена його таблиця. При цьому власних екземплярів даний клас не має, а у відповідній таблиці будуть відображені його нащадки: екземпляри класу University.Student та University.Teacher.



Розглянемо детально дані глобалу ^University.PersonD. У його корені зберігається ID останнього об’єкта, що був збережений у базі даних. При цьому нумерація ID є наскрізною і не залежить від того, до якого з нащадків класу Person відноситься той чи інший його об’єкт. При виклику методів класу %DeleteExtent або %KillExtent у випадку повного знищення всього екстенту класу також будуть знищені його глобали: D та I.

Індексом глобалу на першому рівні є ID відповідного об’єкту, а його значенням – список значень відповідних властивостей, описаних у **базовому класі**. При цьому першим елементом цього списку буде повне ім’я класу-нащадка, до якого належить даний об’єкт. Всі інші елементи списку представляють собою значення простих властивостей. Якщо серед властивостей класу є вбудований клас, то у глобалі певним елементом списку значень буде вкладений список зі значеннями вбудованого об’єкту.

На другому рівні глобалу також у списку зберігаються дані властивостей, що були описані у класі-нащадку (наприклад, вчене звання для класу Teacher та номер залікової книжки для класу Student), а індексом глобалу на цьому рівні є назва класу-нащадка, до якого відноситься відповідний об’єкт. При цьому буде вказане не повне, а скорочене ім’я, тобто без назви схеми даних (пакету).

**Пошук даних без використання SQL-запитів**

Використання глобалів робить можливим пошук даних у класах, не використовуючи запити мовою SQL. Для цього потрібно здійснити проходження за всім екстентом класу. Для цього потрібно знати ID останнього збереженого об’єкта. Відповідно, він буде зберігатись у корені глобалу даних відповідного класу. У свою чергу, існування об’єктів у екстенті класу взагалі можна визначити, використавши вбудовану функцію $Data.

Далі намагаємось відкрити по черзі об’єкти з ID, що приймає значення від 1 до значення, що збережене у корені глобалу даних класу. При цьому потрібно перевірити, чи існує об’єкт з поточним ID взагалі. Якщо об’єкт з відповідним ID існує (посилання до нього не NULL), можна здійснювати перевірку цього об’єкту за критеріями, вказаними у запиті.

Якщо здійснюється пошук у класі який є нащадком іншого класу, потрібно використати глобал даних базового класу і при проходженні всіх об’єктів ще перевіряти ім’я класу, до якого відноситься поточний об’єкт.


Нижче наведені приклади методів пошуку викладачів, що займають певну посаду та студентів, що відносяться до певної групи. Дані методи є членами класів Teacher та Student відповідно.

**Пошук викладачів**

ClassMethod FindTeacher() As %Status  
{  
 read !,"Введіть посаду викладача: ",academstat  
 write "...пошук...",!  
 if ($Data(^University.PersonD)) //якщо існують дані у глобалі класу Person  
 {  
 set total = ^University.PersonD //у корні глобалу класу Person зберігається ID об'єкта, що був збережений у БД останнім  
 for i=1:1:total  //цикл за екстентом класу Person  
 {  
 set p = ##class(University.Person).%OpenId(i)  
 if (p'="") //якщо об'єкт з даним ID існує і не був видалений раніше, тобто посилання не порожнє  
 {  
 set classname = p.%ClassName() //знаходимо ім'я класу відкритого об'єкту (ним є один з класів-нащадків: Student або Teacher)  
 if (classname="Teacher") //якщо об'єкт належить до класу Teacher  
 {  
 if (p.Stat.NameStat=academstat) write p.Surname,?15,p.Name,?25,p.Midname,?37,p.Depart.NameDepart,! }  
 }

}  
 }  
}


Виклик методу:



**Пошук студентів**

ClassMethod FindStudent() As %Status  
{  
 read !,"Введіть номер групи студента: ",groupnum  
 write "...пошук...",!  
 if ($Data(^University.PersonD)) //якщо існують дані у глобалі класу Person  
 {  
 set total = ^University.PersonD //у корні глобалу класу Person зберігається ID об'єкта, що був збережений у БД останнім  
 for i=1:1:total  //цикл за екстентом класу Person  
 {  
 set p = ##class(University.Person).%OpenId(i)  
 if (p'="") //якщо об'єкт з даним ID існує і не був видалений раніше, тобто посилання не порожнє  
 {  
 set classname = p.%ClassName() //знаходимо ім'я класу відкритого об'єкту (ним є один з класів-нащадків: Student або Teacher)  
 if (classname="Student") //якщо об'єкт належить до класу Student  
 {  
 if (p.Group.GroupNumber=groupnum) write p.Surname,?15,p.Name,?25,p.Midname,?37,p.Group.GroupNumber,!  
 }  
 }  
 }  
 }  
}

Виклик методу:



**Завдання**

1. Відповідно до предметної області спроектувати та створити власний глобал більш ніж з одним рівнем, обґрунтувати кількість рівнів у ньому. Здійнити пошук даних у створеному глобалі.
2. Здійснити запит з лабораторної роботи №5 без використання SQL.

**Контрольні питання**

1. В чому полягає ієрархічна модель даних в СКБД Caché?
2. Що таке глобал?
3. Як зберігається глобал у базі даних?
4. Які дії виконують функції $Data та $Get?
5. Які дії виконують функції $Order та $Query?
6. Як скопіювати багатомірну змінну?
7. Як представляються класи, їх підкласи та індекси у вигляді глобалів?
8. Як здійснити пошук об’єктів за критерієм без використання запитів SQL?