Skip to content

Prosopography and linked person data

Gabriel Bodard edited this page Nov 21, 2017 · 20 revisions

Thursday November 16, 2017, 16h00-17h15 Greenwich Mean Time

Session 9: Prosopography and linked person-data

Convenors: Gabriel Bodard (University of London), Rada Varga (Cluj Napoca)

YouTube link: https://youtu.be/lRRfkWoOZG4

Slides: tba

Outline

This session will introduce students to the digital structuring of person-data for the attested historical (ancient, but not exclusively) population. We will opt for a practical, hands-on approach, indicating the tools and resources which allow us to query data on ancient people, disambiguate characters and reconstruct biographical and prosopographical information.

  1. Prosopographical sources
  2. Prosopographical data formats
  3. Demonstration of Romans1by1 and Trismegistos People
  4. Demonstration of SNAP:DRGN using Sparql (and exercise)

Seminar reading

Other resources

Essay title

Compare traditional print prosopographical and onomastic corpora (such as PIR, PCBE, PLRE) and person databases (such as Trismegistos or Lexicon of Greek Personal Names). What research questions one can ask, comparatively? How do the approaches to research on ancient persons differ in each case?

Exercise

Building on your practice with Nomisma SPARQL queries three weeks ago, and on the sample queries below, try to extract meaningful information from the SNAP:DRGN triplestore, using the SPARQL interface.

Example Sparql queries

(1) Give me all triples where SNAP person 1 (PIR² P 156) is the subject node:

PREFIX prov: <http://www.w3.org/ns/prov#>
SELECT ?orig ?p ?o
WHERE {
 <http://data.snapdrgn.net/person/1> prov:wasDerivedFrom ?orig .
 ?orig ?p ?o
}

Repeat for person 10925 (= TM 380005) and 367918 (= LGPN V4-32697, Vol IV Παρμενέα 1), to get a good sample of SNAP RDF content.

(2) Give me a list of the first 1000 SNAP ids that are a merge of two deprecated ids (and what their originating ids are):

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dc: <http://purl.org/dc/terms/>
PREFIX prov: <http://www.w3.org/ns/prov#>
SELECT ?new ?old1 ?old2 ?origin1 ?origin2 WHERE {
 ?new dc:replaces ?old1 .
 ?new dc:replaces ?old2 .
FILTER (?old1 != ?old2) .
 ?old1 prov:wasDerivedFrom ?origin1 .
 ?old2 prov:wasDerivedFrom ?origin2 
} LIMIT 1000

(3) Give me a list of SNAP ids that are a merge of two deprecated ids, and the names of the old ids:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dc: <http://purl.org/dc/terms/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?new ?origin1 ?origin2 ?name1 ?name2 WHERE {
 ?new dc:replaces ?old1 .
 ?new dc:replaces ?old2 .
FILTER (?old1 != ?old2) .
 ?old1 prov:wasDerivedFrom ?origin1 .
 ?origin1 foaf:name ?name1 .
 ?old2 prov:wasDerivedFrom ?origin2 .
 ?origin2 foaf:name ?name2
} LIMIT 1000

(4) Written in class…

PREFIX dc: <http://purl.org/dc/terms/>
PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX snap: <http://onto.snapdrgn.net/snap#>
SELECT ?new ?dataset1 ?name1 ?date1 ?dataset2 ?name2 ?date2 WHERE {
 ?new dc:replaces ?old1 .
 ?new dc:replaces ?old2 .
FILTER (?old1 != ?old2) .
 ?old1 prov:wasDerivedFrom ?origin1 .
 ?origin1 snap:associatedDate ?date1 ;
  foaf:name ?name1 ;
  dc:isPartOf ?dataset1 .
 ?old2 prov:wasDerivedFrom ?origin2 .
 ?origin2 snap:associatedDate ?date2 ;
   foaf:name ?name2 ;
   dc:isPartOf ?dataset2 
} LIMIT 1000
You can’t perform that action at this time.