|  |
| --- |
| Licence 3 informatique |
| Compte Rendu AMPL |
| DM Répartition de marché |
|  |
| **Thibault Montois Alex Dalencourt** |
| **10/11/2015** |

|  |
| --- |
| Groupe 1 |

Le programme AMPL utilise le fichier repartition\_marche.data. Par ailleurs le fichier contient trois objectifs dont deux commentés. Chacun des objectifs permettent de répondre à une des trois questions du devoir. Un commentaire permet d’identifier la question associée à chaque objectif. Ainsi les questions 1, 2.1 et 2.2 ont été réalisées.

Résultats obtenus par question :

Question 1)

Question 2.1)

Question 2.2)

Développement du programme :

La première difficulté rencontrée au cours du programme a été la reformulation du programme afin de pouvoir séparer objectif paramètres variable et contraintes. Ainsi l’écriture de l’objectif fut la principale épreuve puisqu’il doit tenir compte des différentes contraintes mais aussi d’un pourcentage de marge d’erreurs. Ces contraintes nous on fait réfléchir sur le problème d’avoir un seul et unique objectif. La seconde difficulté a été de tenir compte des marges d’erreur afin de les minimiser.

Ainsi pour le premier pour la première question, qui ne doit pas optimiser la marge d’erreur, nous avons choisi d’utiliser un objectif dit « constant » : « maximize inutile : 1 ». Ainsi l’objectif n’est pas pris en compte. En revanche les toutes les contraintes de l’objectif seront maximisées.

Pour la question 2.1 l’objectif choisi est : « minimize somme\_varition\_vabs : somme\_bornes ». Cet objectif nécessite le calcul de plusieurs variables en plus des contraintes de répartitions et de bornage. On doit, pour commencer, minimiser la variable somme\_bornes qui contient la somme de toutes les bornes supérieures des contraintes des problèmes. Pour minimiser ces bornes les contraintes bornes\_sup\_1 à 4 permettent de minimiser les variables bornes\_nb\_pts\_vente, borne\_spiritueux, borne\_huile et borne detaillants.

Enfin pour le troisième problème, l’objectif est : « minimize variation\_max\_vabs : borne sup ». Cette fois plutôt que de minimiser la somme de toutes les bornes maximales, on va minimiser la borne maximale de parmi toutes les contraintes, d’où l’utilisation de la variable borne\_sup.

Enfin les variables de type rapport\_\* permettent de calculer le pourcentage de présence des détaillants dans la division 1 pour chaque contrainte associée.

**Annexe code AMPL**

/\*Réinitialisation\*/

reset;

/\*Choix du Solver\*/

option solver gurobi;

## Déclaration des ensembles

set DETAILLANTS;

set REGIONS;

set CATEGORIES;

## Déclaration des paramètres

/\*Paramètres initiaux\*/

param region{DETAILLANTS} symbolic in REGIONS;

param huile{DETAILLANTS} >= 0;

param nb\_pts\_vente{DETAILLANTS} >= 0;

param spiritueux{DETAILLANTS} >= 0;

param categorie{DETAILLANTS} symbolic in CATEGORIES;

/\*Paramètres calculés\*/

param nb\_pts\_vente\_total = sum{d in DETAILLANTS} nb\_pts\_vente[d];

param spiritueux\_total = sum{d in DETAILLANTS} spiritueux[d];

param huile\_total{r in REGIONS} = sum{d in DETAILLANTS : region[d] = r} huile[d];

param detaillants\_total{c in CATEGORIES} = sum{d in DETAILLANTS : categorie[d] = c} 1;

## Déclaration des variables

/\*Variables initiales\*/

var appartient\_a\_D1{DETAILLANTS} binary;

var borne\_nb\_pts\_vente >= 0, <= 0.05;

var borne\_spiritueux >= 0, <= 0.05;

var borne\_huile{REGIONS} >= 0, <= 0.05;

var borne\_detaillants{CATEGORIES} >= 0, <= 0.05;

var borne\_sup >=0, <= 0.05;

/\*Variables calculées\*/

var nb\_pts\_vente\_D1 = sum{d in DETAILLANTS} appartient\_a\_D1[d] \* nb\_pts\_vente[d];

var spiritueux\_D1 = sum{d in DETAILLANTS} appartient\_a\_D1[d] \* spiritueux[d];

var huile\_D1{r in REGIONS} = sum{d in DETAILLANTS : region[d] = r} appartient\_a\_D1[d] \* huile[d];

var detaillants\_D1{c in CATEGORIES} = sum{d in DETAILLANTS : categorie[d] = c} appartient\_a\_D1[d];

var rapport\_nb\_pts\_vente\_D1 = nb\_pts\_vente\_D1 / nb\_pts\_vente\_total;

var rapport\_spiritueux\_D1 = spiritueux\_D1 / spiritueux\_total;

var rapport\_huile\_D1{r in REGIONS} = huile\_D1[r] / huile\_total[r];

var rapport\_detaillants\_D1{c in CATEGORIES} = detaillants\_D1[c] / detaillants\_total[c];

var somme\_bornes = borne\_nb\_pts\_vente + borne\_spiritueux + sum{r in REGIONS} borne\_huile[r] + sum{c in CATEGORIES} borne\_detaillants[c];

## Objectif

/\*Objectif de la question 1\*/

#maximize inutile :

# 1;

/\*Objectif de la question 2.1\*/

minimize somme\_variation\_vabs :

somme\_bornes;

/\*Objectif de la question 2.2\*/

#minimize variation\_max\_vabs :

# borne\_sup;

## Contraintes

/\*Contraintes liées au nombre de points de vente de la division D1\*/

subject to nb\_pts\_vente\_min :

rapport\_nb\_pts\_vente\_D1 >= 0.40 - borne\_nb\_pts\_vente;

subject to nb\_pts\_vente\_max :

rapport\_nb\_pts\_vente\_D1 <= 0.40 + borne\_nb\_pts\_vente;

/\*Contraintes liées au marché des spiritueux de la division D1\*/

subject to spiritueux\_min :

rapport\_spiritueux\_D1 >= 0.40 - borne\_spiritueux;

subject to spiritueux\_max :

rapport\_spiritueux\_D1 <= 0.40 + borne\_spiritueux;

/\*Contraintes liées au marché de l'huile par région de la division D1\*/

subject to huile\_\_par\_region\_min{r in REGIONS} :

rapport\_huile\_D1[r] >= 0.40 - borne\_huile[r];

subject to huile\_par\_region\_max{r in REGIONS} :

rapport\_huile\_D1[r] <= 0.40 + borne\_huile[r];

/\*Contraintes liées au nombre de détaillants par catégorie de la division D1\*/

subject to detaillants\_par\_categorie\_min{c in CATEGORIES} :

rapport\_detaillants\_D1[c] >= 0.40 - borne\_detaillants[c];

subject to detaillants\_par\_categorie\_max{c in CATEGORIES} :

rapport\_detaillants\_D1[c] <= 0.40 + borne\_detaillants[c];

/\*Contraintes liées à la borne supérieure\*/

subject to borne\_sup\_1 :

borne\_sup >= borne\_nb\_pts\_vente;

subject to borne\_sup\_2 :

borne\_sup >= borne\_spiritueux;

subject to borne\_sup\_3{r in REGIONS} :

borne\_sup >= borne\_huile[r];

subject to borne\_sup\_4{c in CATEGORIES} :

borne\_sup >= borne\_detaillants[c];