DATE: 4/23/2020 EZ AUTO SALES PAGE 1

TIME: 9:50 PM CUSTOMER SALES SUBTOTAL REPORT

TYLER SATHER

MAKE --> Chevrolet

CUSTOMER PURCHASE PURCHASE SATIS.

NUMBER CUSTOMER NAME STREET ADDRESS DATE PRICE RATING

-------- -------------------- -------------------- ---------- --------- --------

1003 Robert Andrews 10202 WEST 73RD 8/26/2001 $ 7,000.00 DISSAT.

1008 Rafelino Anzio 3495 WELMONT ROAD 9/01/2001 $ 4,560.50 DISSAT.

1041 Bonnie Blondell 1011 BELVIEW DR. 9/04/2001 $ 3,560.50 UNDECIDED

1067 Wayne R. Claflin 4575 HIGHLAND PKWY. 9/01/2001 $ 4,560.50 SATISFIED

2002 Sarah D. Corey 1756 CONKEY ROAD 8/27/2001 $ 6,500.50 DISSAT.

2004 Goodman Cracklin 876 JOE MARTIN RD. 9/01/2001 $14,560.50 DISSAT.

2043 Ralph O. Davies 9809 MORRIS DR. 8/26/2001 $ 3,330.00 DISSAT.

2048 Donna Dennick 5505 GREENE ST. 9/01/2001 $ 6,560.25 DISSAT.

3011 Ester B. Eaton 5520 E. PAYTON ST. 9/01/2001 $13,560.50 DISSAT.

3047 James Flannery 50 W. EAST STREET 9/01/2001 $ 4,500.50 DISSAT.

3062 Tony S. Gennerro 98 W. LINCOLN HWY. 8/30/2001 $ 3,200.50 DISSAT.

3066 Nancy K. Goebel 444 KENNEDY AVE. 9/02/2001 $ 6,430.50 DISSAT.

3098 Roberto Hartnett 56 E. 89TH AVE. 9/05/2001 $ 3,260.40 DISSAT.

4024 Jack Johnson 7645 HOWARD AVE. 9/03/2001 $ 2,560.50 DISSAT.

4046 Charles S. Norris 2529 W. 86TH AVE. 9/05/2001 $ 8,440.00 DISSAT.

4066 Robert B. Reed 455 ENTERPRISE WAY 8/27/2001 $ 7,400.50 DISSAT.

4094 Jack Warner 11223 SUNSET DRIVE 9/04/2001 $ 8,560.50 DISSAT.

----------

\* TOTAL OF 17 CARS OF MAKE Chevrolet SOLD FOR $108,546.65

MAKE --> Dodge Bros.

CUSTOMER PURCHASE PURCHASE SATIS.

NUMBER CUSTOMER NAME STREET ADDRESS DATE PRICE RATING

-------- -------------------- -------------------- ---------- --------- --------

1063 Martha S. Chelsea 1823 N. ADAMS 8/30/2001 $ 3,500.00 DISSAT.

3043 Wesley Farnsworth 840 DIRT ROAD 9/05/2001 $11,500.00 DISSAT.

4038 Jill Levandowski 52123 ROOSEVELT RD. 8/28/2001 $ 4,300.00 UNDECIDED

4047 Alfred Nowakowski 1991 KING BLVD. 9/01/2001 $ 6,560.50 UNDECIDED

4067 Alonzo Rodriguez 91 W. 114TH NORTH 9/05/2001 $10,500.50 DISSAT.

----------

\* TOTAL OF 5 CARS OF MAKE Dodge Bros. SOLD FOR $ 36,361.00

MAKE --> Ford

CUSTOMER PURCHASE PURCHASE SATIS.

NUMBER CUSTOMER NAME STREET ADDRESS DATE PRICE RATING

-------- -------------------- -------------------- ---------- --------- --------

1001 Carl T. Albert 123 EAST STREET 8/25/2001 $ 2,550.00 SATISFIED

1031 Jennifer Bezzmek 239 COLORADO ST. 8/27/2001 $ 4,550.00 SATISFIED

1033 Donald Blake 925 LINCOLN HIGHWAY 8/29/2001 $ 7,220.50 UNDECIDED

1056 Fredrick Bymann 349 W. 73RD AVE. 8/29/2001 $ 3,300.00 UNDECIDED

1061 Ronald Calbert 2021 CRESTWOOD DR. 9/05/2001 $ 3,550.00 SATISFIED

1080 Johnathan Cooper 7021 CONGRESS PKWY. 9/05/2001 $12,560.00 SATISFIED

2031 David P. Dalton 6621 183RD AVE. 8/25/2001 $ 2,340.00 SATISFIED

2091 Rita Dunlop 8008 W. 93RD AVE. 8/25/2001 $14,500.45 SATISFIED

3003 Cynthia Dykes 9420 STATE RD. 49 8/26/2001 $ 4,100.50 UNDECIDED DATE: 4/23/2020 EZ AUTO SALES PAGE 2

TIME: 9:50 PM CUSTOMER SALES SUBTOTAL REPORT

TYLER SATHER

MAKE --> Ford

CUSTOMER PURCHASE PURCHASE SATIS.

NUMBER CUSTOMER NAME STREET ADDRESS DATE PRICE RATING

-------- -------------------- -------------------- ---------- --------- --------

3026 David Eppley 659 WISCONSIN ST. 8/28/2001 $ 4,140.00 UNDECIDED

3031 Rosa Erkle 2850 ROSEMONT ROAD 9/03/2001 $ 3,550.20 SATISFIED

3061 Clarence Gallagher 4521 MANARD ROAD 9/04/2001 $10,060.00 SATISFIED

4021 Raymond Idzior 109 WASHINGTON ST. 9/01/2001 $14,600.00 SATISFIED

4022 William Jennings 774 N. JEFFERSON 8/26/2001 $ 6,120.40 UNDECIDED

4044 Arnold E. Metz 1414 VIRGINIA ST. 9/01/2001 $13,230.00 SATISFIED

4061 Shamus Perry 515 BEVERLY STREET 9/05/2001 $ 8,950.00 SATISFIED

4084 Martin Torrez 391 MONROE, APT. 12 8/27/2001 $ 5,650.00 SATISFIED

4090 Mark Tuttle 905 APPLE ORCHARD 8/29/2001 $ 7,100.50 UNDECIDED

----------

\* TOTAL OF 18 CARS OF MAKE Ford SOLD FOR $128,072.55

MAKE --> Hudson

CUSTOMER PURCHASE PURCHASE SATIS.

NUMBER CUSTOMER NAME STREET ADDRESS DATE PRICE RATING

-------- -------------------- -------------------- ---------- --------- --------

1025 Alfred A. Avery 45 W. GRAND BLVD. 8/29/2001 $ 2,300.00 UNDECIDED

1076 Richard L. Colwell 542 OAKLAND CIRCLE 8/29/2001 $ 4,300.00 UNDECIDED

2024 Izore M. Cyborg 456 LAKESHORE DR. 9/05/2001 $ 1,300.00 UNDECIDED

2085 Radar O. Doppler 1212 BUCKLEY ROAD 8/30/2001 $ 3,110.00 UNDECIDED

3056 David Furnace 404 EASY STREET 8/29/2001 $ 5,300.00 UNDECIDED

3094 Jonathon Hancock 3101 CHECKER ST. 9/03/2001 $ 3,300.00 UNDECIDED

4012 Janet F. Hyatt 98 BAKER STREET 8/30/2001 $ 1,550.00 UNDECIDED

4059 Lenni R. Patterson 1020 BUTTERFIELD RD. 8/29/2001 $ 2,500.00 UNDECIDED

----------

\* TOTAL OF 8 CARS OF MAKE Hudson SOLD FOR $ 23,660.00

MAKE --> Pierce-Arrow

CUSTOMER PURCHASE PURCHASE SATIS.

NUMBER CUSTOMER NAME STREET ADDRESS DATE PRICE RATING

-------- -------------------- -------------------- ---------- --------- --------

1010 William B. Ashley 4502 ASHLEY DRIVE 9/02/2001 $12,400.00 SATISFIED

1045 James Bonadio 23W. 123 NORTH 9/03/2001 $11,500.00 SATISFIED

1070 Charles C. Cole 879 MISSISSIPPI ST. 9/02/2001 $10,500.00 SATISFIED

2011 Timothy Crawford 2122 HOWARD ST. 9/01/2001 $10,400.00 SATISFIED

2050 Deanna Derbin 401 TAFT ST. 9/02/2001 $16,400.25 SATISFIED

3015 Baily Effley 2200 BEATTY ST. 9/02/2001 $14,460.45 SATISFIED

3050 Otto J. Foreman 999 RIGHTWAY ROAD 9/02/2001 $ 9,400.00 SATISFIED

3072 Frederick Gunther 707 JOLIET ROAD 9/03/2001 $12,600.00 SATISFIED

4005 Sonia Henning 606 MONUMENT CIRCLE 9/05/2001 $13,050.00 SATISFIED

4032 Robert C. Kulka 8811 CLOVERLEAF 9/04/2001 $ 9,700.00 SATISFIED

4053 Niel O'boyle 4002 WHEELING ROAD 9/03/2001 $15,500.00 SATISFIED

4073 Henry Sanchez 8181 CHESTNUT LANE 9/01/2001 $ 8,300.00 SATISFIED

4115 Yourto Yackley 1185 PINTO STREET 9/04/2001 $10,000.00 SATISFIED

----------

\* TOTAL OF 13 CARS OF MAKE Pierce-Arrow SOLD FOR $154,210.70

MAKE --> Studebaker

CUSTOMER PURCHASE PURCHASE SATIS.

NUMBER CUSTOMER NAME STREET ADDRESS DATE PRICE RATING

-------- -------------------- -------------------- ---------- --------- --------

1015 Mark Atkinson 123 NORTH 109TH ST 8/27/2001 $ 500.00 UNDECIDED DATE: 4/23/2020 EZ AUTO SALES PAGE 3

TIME: 9:50 PM CUSTOMER SALES SUBTOTAL REPORT

TYLER SATHER

MAKE --> Studebaker

CUSTOMER PURCHASE PURCHASE SATIS.

NUMBER CUSTOMER NAME STREET ADDRESS DATE PRICE RATING

-------- -------------------- -------------------- ---------- --------- --------

1055 Onieda Bucko 4705 AINSWORTH RD. 8/28/2001 $ 2,450.00 UNDECIDED

1075 Thomas Coleman 1903 THOMAS DR. 8/27/2001 $ 1,670.50 UNDECIDED

2012 Raymond Currie 45 N. ASHLAND AVE. 8/28/2001 $ 1,500.25 UNDECIDED

2065 Phillip Donnehue 725 HARRISON AVE. 9/04/2001 $ 540.00 UNDECIDED

3025 Amanda Eggerton 12123 HIGHWAY 6 8/29/2001 $ 3,350.00 UNDECIDED

3055 Kathleen Fowler 7808 STURDY ROAD 8/27/2001 $ 2,670.50 UNDECIDED

3080 Marshall Haines 1912 MADISON AVE. 8/29/2001 $ 2,500.25 UNDECIDED

4009 Rogers Hornsby 1792 WHITLEY AVE. 8/25/2001 $ 1,675.00 UNDECIDED

4035 Donald Kurtz 505 HICKEY STREET 8/30/2001 $ 3,450.00 UNDECIDED

4056 Patrick O'brian 4013 CHESTERFIELD 8/30/2001 $ 3,470.50 UNDECIDED

4081 Hector Swartz 20021 MARTIN ROAD 8/28/2001 $ 750.25 UNDECIDED

----------

\* TOTAL OF 12 CARS OF MAKE Studebaker SOLD FOR $ 24,527.25

TOTAL CARS SOLD = 73

TOTAL PURCHASES = $475,378.15

END OF REPORT

IDENTIFICATION DIVISION.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

PROGRAM-ID. VSEX8-3.

AUTHOR. TYLER SATHER.

INSTALLATION. M STATE.

DATE-WRITTEN. ARP, 22 2020

DATE-COMPILED.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* PROGRAM NARRATIVE \*

\* \*

\* THIS PROGRAM PRODUCES THE CUSTOMER SALES SUBTOTAL REPORT \*

\* LISTING ALL SALES BY AUTO MAKE AND PROVIDING SUMMARY \*

\* INFORMATION FOR EACH MAKE OF AUTO. THE CUSTOMER SALES FILE \*

\* IS SORTED BY AUTOMAKE PRIOR TO PRODUCING THE REPORT. \*

\* TWO TABLES ARE UTILIZED, ONE FOR CUSTOMER ADDRESSES AND ONE \*

\* SATISFACTION RATING DESCRIPTION \*

\* \*

\* INPUT: CUSTSALE.DAT - CUSTOMER SALES FILE \*

\* CUSTADDR.DAT - CUSTOMER ADDRESS FILE \*

\* OUTPUT: EX8-3.RPT - CUSTOMER SALES SUBTOTAL REPORT\*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

/

ENVIRONMENT DIVISION.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

INPUT-OUTPUT SECTION.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

FILE-CONTROL.

SELECT CUSTOMER-SALES-FILE

ASSIGN TO "C:\Users\sathe\Desktop\Mstate\COBOL\Data\CUSTSALE.DAT"

ORGANIZATION IS LINE SEQUENTIAL.

SELECT SORT-FILE

ASSIGN TO "SORTWORK".

SELECT SORTED-SALES-FILE

ASSIGN TO "C:\Users\sathe\Desktop\Mstate\COBOL\Ch8\SORTCUST.DAT"

ORGANIZATION IS LINE SEQUENTIAL.

SELECT CUSTOMER-ADDRESS-FILE

ASSIGN TO "C:\Users\sathe\Desktop\Mstate\COBOL\Data\CUSTADDR.DAT"

ORGANIZATION IS LINE SEQUENTIAL.

SELECT SALES-SUBTOTAL-REPORT

ASSIGN TO "C:\Users\sathe\Desktop\Mstate\COBOL\Ch8\EX8-3.RPT".

/

DATA DIVISION.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

FILE SECTION.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* INPUT FILE - CUSTOMER SALES FILE \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

FD CUSTOMER-SALES-FILE.

01 CUSTOMER-SALES-REC PIC X(76).

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* SORT FILE - SORT SALES FILE BY AUTO MAKE \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

SD SORT-FILE.

01 SORT-RECORD.

02 PIC X(41).

02 SR-AUTO-MAKE PIC X(20).

02 PIC X(15).

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* SORTED FILE - SORTED SALES FILE \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

FD SORTED-SALES-FILE.

01 SORTED-SALES-REC PIC X(76).

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* ADDRESS FILE - CUSTOMER ADDRESS FILE FOR NON EMBEDDED TABLE \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

FD CUSTOMER-ADDRESS-FILE.

01 CUSTOMER-ADDRESS-RECORD.

02 CAR-NUMBER PIC X(4).

02 CAR-ADDRESS PIC X(20).

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* REPORT FILE - CUSTOMER SALES SUBTOTAL REPORT \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

FD SALES-SUBTOTAL-REPORT.

01 SALES-LINE-OUT PIC X(100).

/

WORKING-STORAGE SECTION.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* SWITCHES \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

01 SWITCHES.

02 SW-END-OF-FILE PIC X.

88 END-OF-FILE VALUE "Y".

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* ACCUMULATORS \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

01 ACCUMULATORS.

02 AC-LINE-COUNT PIC 999.

02 AC-PAGE-COUNT PIC 999.

02 AC-RECORD-COUNT PIC 999.

02 AC-AUTO-COUNT PIC 999.

02 AC-TOTAL-SALES PIC 9(6)V99.

02 AC-AUTO-SALES PIC 9(6)V99.

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* WORK AREA \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

01 WORK-AREA.

02 WA-TODAYS-DATE-TIME.

03 WA-TODAYS-DATE.

04 WA-TODAYS-YEAR PIC 9(4).

04 WA-TODAYS-MONTH PIC 99.

04 WA-TODAYS-DAY PIC 99.

03 WA-TODAYS-TIME.

04 WA-TODAYS-HOUR PIC 99.

04 WA-TODAYS-MINUTES PIC 99.

03 PIC X(9).

02 WA-DATE.

03 WA-MONTH PIC 99.

03 WA-DAY PIC 99.

03 WA-YEAR PIC 9(4).

02 WA-RUN-DATE REDEFINES

WA-DATE PIC 9(8).

02 WA-HOLD-AUTO PIC X(20).

02 WA-DEL-1 PIC X.

02 WA-AUTO-FIELDS.

03 WA-AUTO-NAME-1.

04 PIC X.

04 WA-AUTO-REST-1 PIC X(14).

03 WA-AUTO-NAME-2.

04 PIC X.

04 WA-AUTO-REST-2 PIC X(14).

02 WA-CUSTOMER-NAME-FIELDS.

03 WA-NAME-1.

04 PIC X.

04 WA-REST-1 PIC X(14).

03 WA-NAME-2.

04 PIC X.

04 WA-REST-2 PIC X(14).

03 WA-NAME-3.

04 PIC X.

04 WA-REST-3 PIC X(14).

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* EMBEDDED SATISFACTION CODE TABLE \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

01 SATISFACTION-DATA.

02 PIC X(10) VALUE "0DISSAT.".

02 PIC X(10) VALUE "1UNDECIDED".

02 PIC X(10) VALUE "2SATISFIED".

01 SATISFACTION-TABLE REDEFINES SATISFACTION-DATA.

02 ST-ENTRY OCCURS 3 TIMES

INDEXED BY ST-INDEX.

03 ST-CODE PIC X.

03 ST-RATING PIC X(9).

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* NON-EMBEDDED CUSTOMER ADDRESS TABLE \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

01 CUSTOMER-ADDRESS-TABLE.

02 CAT-ENTRY OCCURS 73 TIMES

INDEXED BY ADDR-INDEX.

03 CAT-NUMBER PIC X(4).

03 CAT-ADDRESS PIC X(20).

COPY"C:\Users\sathe\Desktop\Mstate\COBOL\Data\SALESREC.CBL".

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* REPORT HEADINGS FOR CUSTOMER SALES SUBTOTAL REPORT \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

01 REPORT-HEADINGS.

02 RH-LINE-1.

03 PIC X(6) VALUE "DATE: ".

03 RH-DATE PIC Z9/99/9999.

03 PIC X(25) VALUE SPACES.

03 PIC X(13) VALUE "EZ AUTO SALES".

03 PIC X(27) VALUE SPACES.

03 PIC X(5) VALUE "PAGE ".

03 RH-PAGE-COUNT PIC Z9.

02 RH-LINE-2.

03 PIC X(6) VALUE "TIME: ".

03 RH-HOUR PIC Z9.

03 PIC X VALUE ":".

03 RH-MINUTES PIC 99.

03 PIC X VALUE SPACE.

03 RH-AM-PM PIC XX.

03 PIC X(18) VALUE SPACES.

03 PIC X(30) VALUE "CUSTOMER SALES SUBTOTAL REPORT".

02 RH-LINE-2A.

03 PIC X(12) VALUE "TYLER SATHER".

02 RH-LINE-3.

03 PIC X(9) VALUE "MAKE -->".

03 RH-AUTO-MAKE PIC X(20).

02 RH-LINE-4.

03 PIC X(8) VALUE "CUSTOMER".

03 PIC X(46) VALUE SPACES.

03 PIC X(8) VALUE "PURCHASE".

03 PIC X(4) VALUE SPACES.

03 PIC X(8) VALUE "PURCHASE".

03 PIC X(4) VALUE SPACES.

03 PIC X(6) VALUE "SATIS.".

02 RH-LINE-5.

03 PIC X(6) VALUE "NUMBER".

03 PIC XXX VALUE SPACES.

03 PIC X(13) VALUE "CUSTOMER NAME".

03 PIC X(9) VALUE SPACES.

03 PIC X(14) VALUE "STREET ADDRESS".

03 PIC X(9) VALUE SPACES.

03 PIC X(4) VALUE "DATE".

03 PIC X(8) VALUE SPACES.

03 PIC X(5) VALUE "PRICE".

03 PIC X(7) VALUE SPACES.

03 PIC X(6) VALUE "RATING".

02 RH-LINE-6.

03 PIC X(8) VALUE ALL "-".

03 PIC X VALUE SPACE.

03 PIC X(20) VALUE ALL "-".

03 PIC XX VALUE SPACES.

03 PIC X(20) VALUE ALL "-".

03 PIC XXX VALUE SPACES.

03 PIC X(10) VALUE ALL "-".

03 PIC XX VALUE SPACES.

03 PIC X(9) VALUE ALL "-".

03 PIC XXX VALUE SPACES.

03 PIC X(8) VALUE ALL "-".

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* DETAIL LINE FOR CUSTOMER SALES SUBTOTAL REPORT \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

01 DETAIL-LINE.

02 PIC XX VALUE SPACES.

02 DL-CUSTOMER-NUMBER PIC X(4).

02 PIC XXX VALUE SPACES.

02 DL-CUSTOMER-NAME PIC X(20).

02 PIC XX VALUE SPACES.

02 DL-CUSTOMER-ADDRESS PIC X(20).

02 PIC XXX VALUE SPACES.

02 DL-PURCHASE-DATE PIC Z9/99/9999.

02 PIC XX VALUE SPACES.

02 DL-PURCHASE-PRICE PIC $ZZ,ZZZ.99.

02 PIC XX VALUE SPACES.

02 DL-SATISFACTION-RATING PIC X(9).

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* SUMMARY LINES FOR CUSTOMER SALES SUBTOTAL REPORT \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

01 SUMMARY-LINES.

02 SL-LINE-1.

03 PIC X(66) VALUE SPACES.

03 PIC X(10) VALUE ALL "-".

02 SL-LINE-2.

03 PIC X(12) VALUE "\* TOTAL OF ".

03 SL-MAKE-COUNT PIC ZZ9.

03 PIC X(14) VALUE " CARS OF MAKE ".

03 SL-AUTO-MAKE PIC X(21).

03 PIC X(15) VALUE " SOLD FOR ".

03 SL-AUTO-TOTAL PIC $ZZZ,ZZZ.99.

02 SL-LINE-3.

03 PIC X(24) VALUE SPACES.

03 PIC X(18) VALUE "TOTAL CARS SOLD = ".

03 SL-TOTAL-SOLD PIC ZZ9.

02 SL-LINE-4.

03 PIC X(24) VALUE SPACES.

03 PIC X(18) VALUE "TOTAL PURCHASES = ".

03 SL-TOTAL-SALES PIC $ZZZ,ZZZ.99.

02 SL-LINE-5.

03 PIC X(30) VALUE SPACES.

03 PIC X(13) VALUE "END OF REPORT".

/

PROCEDURE DIVISION.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* MAIN-PROGRAM. THIS IS THE MAIN PARAGRAPH OF THIS PROGRAM \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

MAIN-PROGRAM.

PERFORM A-100-INITIALIZATION.

PERFORM B-100-LOAD-ADDRESS-TABLE.

PERFORM C-100-PROCESS-FILE.

PERFORM D-100-WRAP-UP.

STOP RUN.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* THE INITIALIZATION PARAGRAPH FOLLOWS \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

A-100-INITIALIZATION.

INITIALIZE ACCUMULATORS.

MOVE FUNCTION CURRENT-DATE TO WA-TODAYS-DATE-TIME.

MOVE WA-TODAYS-MONTH TO WA-MONTH.

MOVE WA-TODAYS-DAY TO WA-DAY.

MOVE WA-TODAYS-YEAR TO WA-YEAR.

MOVE WA-RUN-DATE TO RH-DATE.

EVALUATE TRUE

WHEN WA-TODAYS-HOUR = 00

MOVE "AM" TO RH-AM-PM

MOVE 12 TO WA-TODAYS-HOUR

WHEN WA-TODAYS-HOUR < 12

MOVE "AM" TO RH-AM-PM

WHEN WA-TODAYS-HOUR = 12

MOVE "PM" TO RH-AM-PM

WHEN WA-TODAYS-HOUR > 12

MOVE "PM" TO RH-AM-PM

SUBTRACT 12 FROM WA-TODAYS-HOUR.

MOVE WA-TODAYS-HOUR TO RH-HOUR.

MOVE WA-TODAYS-MINUTES TO RH-MINUTES.

SORT SORT-FILE

ON ASCENDING KEY SR-AUTO-MAKE

USING CUSTOMER-SALES-FILE

GIVING SORTED-SALES-FILE.

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* LOAD CUSTOMER ADDRESS TABLE PARAGRAPH \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

B-100-LOAD-ADDRESS-TABLE.

OPEN INPUT CUSTOMER-ADDRESS-FILE.

MOVE "N" TO SW-END-OF-FILE.

READ CUSTOMER-ADDRESS-FILE

AT END

MOVE "Y" TO SW-END-OF-FILE.

PERFORM B-200-LOAD

VARYING ADDR-INDEX FROM 1 BY 1

UNTIL END-OF-FILE OR ADDR-INDEX > 73.

CLOSE CUSTOMER-ADDRESS-FILE.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* MOVE CUSTOMER ADDRESS FILE DATA TO ADDRESS TABLE \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

B-200-LOAD.

MOVE CAR-NUMBER TO CAT-NUMBER(ADDR-INDEX).

MOVE CAR-ADDRESS TO CAT-ADDRESS(ADDR-INDEX).

READ CUSTOMER-ADDRESS-FILE

AT END

MOVE "Y" TO SW-END-OF-FILE.

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* REPORT PROCESSING PARAGRAPH \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

C-100-PROCESS-FILE.

OPEN INPUT SORTED-SALES-FILE

OUTPUT SALES-SUBTOTAL-REPORT.

MOVE "N" TO SW-END-OF-FILE.

READ SORTED-SALES-FILE INTO CUSTOMER-SALES-RECORD

AT END

MOVE "Y" TO SW-END-OF-FILE.

MOVE CSR-AUTO-MAKE TO WA-HOLD-AUTO.

PERFORM C-300-PRINT-HEADINGS.

PERFORM C-310-AUTO-HEADINGS.

PERFORM C-200-PROCESS-RECORDS

UNTIL END-OF-FILE.

PERFORM C-320-AUTO-BREAK.

MOVE AC-TOTAL-SALES TO SL-TOTAL-SALES.

MOVE AC-RECORD-COUNT TO SL-TOTAL-SOLD.

WRITE SALES-LINE-OUT FROM SL-LINE-3

AFTER ADVANCING 3 LINES.

WRITE SALES-LINE-OUT FROM SL-LINE-4

AFTER ADVANCING 1 LINE.

WRITE SALES-LINE-OUT FROM SL-LINE-5

AFTER ADVANCING 2 LINES.

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* RECORD PROCESSING PARAGRAPH \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

C-200-PROCESS-RECORDS.

IF CSR-AUTO-MAKE NOT = WA-HOLD-AUTO

PERFORM C-320-AUTO-BREAK

PERFORM C-310-AUTO-HEADINGS.

MOVE CSR-CUSTOMER-NUMBER TO DL-CUSTOMER-NUMBER.

PERFORM C-330-CUSTOMER-NAME.

SET ADDR-INDEX TO 1.

SEARCH CAT-ENTRY

AT END

MOVE "NOT FOUND" TO DL-CUSTOMER-ADDRESS

WHEN CAT-NUMBER(ADDR-INDEX) = CSR-CUSTOMER-NUMBER

MOVE CAT-ADDRESS(ADDR-INDEX) TO DL-CUSTOMER-ADDRESS.

MOVE CSR-PURCHASE-DATE TO DL-PURCHASE-DATE.

MOVE CSR-PURCHASE-PRICE TO DL-PURCHASE-PRICE.

SET ST-INDEX TO 1.

SEARCH ST-ENTRY

AT END

MOVE "NOT FOUND" TO DL-SATISFACTION-RATING

WHEN ST-CODE (ST-INDEX) = CSR-SATISFACTION-CODE

MOVE ST-RATING (ST-INDEX) TO DL-SATISFACTION-RATING.

WRITE SALES-LINE-OUT FROM DETAIL-LINE

AFTER ADVANCING 1 LINE.

ADD 1 TO AC-LINE-COUNT.

ADD 1 TO AC-AUTO-COUNT.

ADD CSR-PURCHASE-PRICE TO AC-AUTO-SALES.

IF AC-LINE-COUNT > 55

MOVE ZERO TO AC-LINE-COUNT

PERFORM C-300-PRINT-HEADINGS

PERFORM C-310-AUTO-HEADINGS.

READ SORTED-SALES-FILE INTO CUSTOMER-SALES-RECORD

AT END

MOVE "Y" TO SW-END-OF-FILE.

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* PAGE HEADING PARAGRAPH \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

C-300-PRINT-HEADINGS.

ADD 1 TO AC-PAGE-COUNT.

MOVE AC-PAGE-COUNT TO RH-PAGE-COUNT.

WRITE SALES-LINE-OUT FROM RH-LINE-1

AFTER ADVANCING PAGE.

WRITE SALES-LINE-OUT FROM RH-LINE-2

AFTER ADVANCING 1 LINE.

WRITE SALES-LINE-OUT FROM RH-LINE-2A

AFTER ADVANCING 1 LINE.

MOVE 3 TO AC-LINE-COUNT.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* AUTO HEADING PARAGRAPH \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

C-310-AUTO-HEADINGS.

MOVE SPACES TO WA-AUTO-FIELDS.

UNSTRING CSR-AUTO-MAKE DELIMITED BY "-" OR ALL SPACES

INTO WA-AUTO-NAME-1 DELIMITER IN WA-DEL-1

WA-AUTO-NAME-2.

MOVE FUNCTION LOWER-CASE (WA-AUTO-REST-1) TO WA-AUTO-REST-1.

MOVE FUNCTION LOWER-CASE (WA-AUTO-REST-2) TO WA-AUTO-REST-2.

MOVE SPACES TO RH-AUTO-MAKE.

STRING WA-AUTO-NAME-1 DELIMITED BY SPACES

WA-DEL-1 DELIMITED BY SIZE

WA-AUTO-NAME-2 DELIMITED BY SPACES

INTO RH-AUTO-MAKE.

WRITE SALES-LINE-OUT FROM RH-LINE-3

AFTER ADVANCING 2 LINES.

WRITE SALES-LINE-OUT FROM RH-LINE-4

AFTER ADVANCING 2 LINES.

WRITE SALES-LINE-OUT FROM RH-LINE-5

AFTER ADVANCING 1 LINE.

WRITE SALES-LINE-OUT FROM RH-LINE-6

AFTER ADVANCING 1 LINE.

MOVE SPACES TO SALES-LINE-OUT.

WRITE SALES-LINE-OUT

AFTER ADVANCING 1 LINE.

ADD 6 TO AC-LINE-COUNT.

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* WRITE AUT CONTROL BREAK TOTAL \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

C-320-AUTO-BREAK.

MOVE AC-AUTO-COUNT TO SL-MAKE-COUNT.

MOVE RH-AUTO-MAKE TO SL-AUTO-MAKE.

MOVE AC-AUTO-SALES TO SL-AUTO-TOTAL.

WRITE SALES-LINE-OUT FROM SL-LINE-1

AFTER ADVANCING 1 LINE.

WRITE SALES-LINE-OUT FROM SL-LINE-2

AFTER ADVANCING 1 LINE.

ADD AC-AUTO-COUNT TO AC-RECORD-COUNT.

ADD AC-AUTO-SALES TO AC-TOTAL-SALES.

ADD 2 TO AC-LINE-COUNT.

MOVE CSR-AUTO-MAKE TO WA-HOLD-AUTO.

MOVE ZERO TO AC-AUTO-COUNT

AC-AUTO-SALES.

/

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* CALCULATE VENDOR CODE PARAGRAPH \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

C-330-CUSTOMER-NAME.

MOVE SPACES TO WA-CUSTOMER-NAME-FIELDS.

UNSTRING CSR-CUSTOMER-NAME DELIMITED BY "-" OR ALL SPACES

INTO WA-NAME-1

WA-NAME-2

WA-NAME-3.

MOVE FUNCTION LOWER-CASE (WA-REST-1) TO WA-REST-1.

MOVE FUNCTION LOWER-CASE (WA-REST-2) TO WA-REST-2.

MOVE FUNCTION LOWER-CASE (WA-REST-3) TO WA-REST-3.

MOVE SPACES TO DL-CUSTOMER-NAME.

IF WA-NAME-3 = SPACES

STRING WA-NAME-2 DELIMITED BY SPACES

" " DELIMITED BY SIZE

WA-NAME-1 DELIMITED BY ","

INTO DL-CUSTOMER-NAME

ELSE

STRING WA-NAME-2 DELIMITED BY SPACES

" " DELIMITED BY SIZE

WA-NAME-3 DELIMITED BY SPACES

" " DELIMITED BY SIZE

WA-NAME-1 DELIMITED BY ","

INTO DL-CUSTOMER-NAME.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* \*

\* END OF JOB PARAGRAPH \*

\* \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

D-100-WRAP-UP.

CLOSE SORTED-SALES-FILE

SALES-SUBTOTAL-REPORT.

DISPLAY "THE SALES SUBTOTAL REPORT PROGRAM HAS ENDED".

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\* END OF PROGRAM \*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

/