**POSMacros**

------------------------------------------------------------------------------------------------------------------

Sub AddItem()

Dim ws As Worksheet, ws3 As Worksheet

Dim itemRow As Long, AvailRow As Long

Dim imgPath As String

Set ws = Sheet1

Set ws3 = Sheet3

With ws

If .Range("B5").Value = Empty Then Exit Sub

On Error GoTo 0

' Get Item Row from input

itemRow = .Range("B5").Value

' Get First Available Row in Column L

If Application.WorksheetFunction.CountA(.Range("L:L")) = 0 Then

AvailRow = 1

Else

AvailRow = .Cells(.Rows.Count, "L").End(xlUp).Row + 1

End If

' Set Receipt Row

.Range("B6").Value = AvailRow

' Get Item Details

.Range("E3").Value = ws3.Range("B" & itemRow).Value ' Item Name

.Range("F6").Value = ws3.Range("G" & itemRow).Value ' Item Price

.Range("F8").Value = 1 ' Default Quantity to 1

' Add Item Detail to Receipt

.Range("L" & AvailRow).Value = .Range("B8").Value ' Item No

.Range("M" & AvailRow).Value = .Range("E3").Value ' Item Name

.Range("O" & AvailRow).Value = .Range("F8").Value ' Item Qty

.Range("P" & AvailRow).Value = .Range("F6").Value ' Item Price

.Range("Q" & AvailRow).Formula = "=O" & AvailRow & "\*P" & AvailRow ' Total Price Formula

.Range("B8").Value = .Range("B8").Value + 1

' Clear Selection

.Range("E10:F10").ClearContents

.Range("E10").Select

End With

End Sub

------------------------------------------------------------------------------------------------------------------

Sub EnterNumberBtn()

With Sheet1

ActiveCell.Value = ActiveCell.Value & Right(Application.Caller, 1)

End With

End Sub

------------------------------------------------------------------------------------------------------------------

Sub ClearItemBtn()

With Sheet1

If ActiveCell.Address = "$E$10" Then

.Range("E10:F10").ClearContents

Else:

ActiveCell.ClearContents

End If

End With

End Sub

------------------------------------------------------------------------------------------------------------------

Sub EnterDecimalBtn()

ActiveCell.Value = ActiveCell.Value & "."

End Sub

------------------------------------------------------------------------------------------------------------------

Sub EnterPaymentCell()

Sheet1.Range("I7").Select

End Sub

------------------------------------------------------------------------------------------------------------------

Sub EnterPayType()

Sheet1.Range("I6").Value = Application.Caller

Sheet1.Range("I7").Select 'Enter Payment Cell

End Sub

------------------------------------------------------------------------------------------------------------------

Sub PrintReceipt()

Dim LastItemRow As Long

With Sheet1

' Check if payment is sufficient

If .Range("I7").Value < .Range("I5").Value Then

MsgBox "Please enter a payment at or above the total.", vbExclamation, "Payment Error"

Exit Sub

End If

' Store payment amount

.Range("T7").Value = .Range("I7").Value

' Determine the last item row

LastItemRow = .Range("L9999").End(xlUp).Row

If LastItemRow < 10 Then Exit Sub

' Clear selected receipt row

.Range("B6").ClearContents

' Copy footer values

.Range("footer\_range").Copy

.Range("P" & LastItemRow + 1).PasteSpecial xlPasteValues

.Range("P" & LastItemRow + 1 & ":Q" & LastItemRow + .Range("footer\_range").Rows.Count).Font.Bold = True

' Disable CutCopyMode

Application.CutCopyMode = False

' Position and display the footer group shape

With .Shapes("FooterGrup")

.Left = Sheet1.Range("L" & LastItemRow + 7).Left

.Top = Sheet1.Range("L" & LastItemRow + 7).Top

.Visible = msoTrue

End With

' Set print area and print receipt

.PageSetup.PrintArea = "L1:Q" & LastItemRow + 7

.PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False

' Select cell E10 after printing

.Range("E10").Select

End With

End Sub

------------------------------------------------------------------------------------------------------------------

Sub SaveAndClear()

Dim LastItemRow As Long, FirstDBRow As Long, TotalRow As Long

With Sheet1

LastItemRow = .Range("L9999").End(xlUp).Row 'Last Item Row

TotalRows = LastItemRow - 12 'Total Items

FirstDBRow = Sheet2.Range("A99999").End(xlUp).Row + 1 'First Avail Row

Sheet2.Range("A" & FirstDBRow & ":A" & FirstDBRow + TotalRows - 1).Value = .Range("P8:Q8").Value 'Receipt No

Sheet2.Range("B" & FirstDBRow & ":B" & FirstDBRow + TotalRows - 1).Value = .Range("M8").Value 'Customer

Sheet2.Range("C" & FirstDBRow & ":C" & FirstDBRow + TotalRows - 1).Value = .Range("M9").Value 'Email

Sheet2.Range("D" & FirstDBRow & ":D" & FirstDBRow + TotalRows - 1).Value = .Range("M10").Value 'Phone

Sheet2.Range("E" & FirstDBRow & ":E" & FirstDBRow + TotalRows - 1).Value = .Range("P7:Q7").Value 'Date

Sheet2.Range("F" & FirstDBRow & ":F" & FirstDBRow + TotalRows - 1).Value = .Range("P10:Q10").Value 'Sales Person

Sheet2.Range("G" & FirstDBRow & ":L" & FirstDBRow + TotalRows - 1).Value = .Range("L13:Q" & LastItemRow).Value 'Item Details

.Shapes("FooterGrup").Visible = msoFalse 'Hide Footer Group

On Error GoTo 0

.Range("L13:Q9999").ClearContents

.Calculate

.Range("P8:Q8").Value = .Range("B7").Value 'Next Receipt No

.Range("B8").Value = 1

.Range("B6,E3:F3,F6,F8,I7,D13:F13,H11:J11,I13:J13,I14:J14").ClearContents 'Clear Item Fields

.Range("E10:F10").Select

.Range("P" & LastItemRow + 1 & ":Q" & LastItemRow + .Range("footer\_range").Rows.Count).Font.Bold = False

End With

End Sub

------------------------------------------------------------------------------------------------------------------

Sub UpdateStock()

Dim wsStock As Worksheet, wsSales As Worksheet

Dim lastRowStock As Long, lastRowSales As Long

Dim stockCell As Range, salesCell As Range

Dim stockDict As Object

Dim i As Integer

' Set worksheets

Set wsStock = ThisWorkbook.Sheets("Stock")

Set wsSales = ThisWorkbook.Sheets("Sales")

' Find last row in both sheets

lastRowStock = wsStock.Cells(Rows.Count, 1).End(xlUp).Row

lastRowSales = wsSales.Cells(Rows.Count, 1).End(xlUp).Row

' Create a dictionary to store stock quantities

Set stockDict = CreateObject("Scripting.Dictionary")

' Load stock data into dictionary (Product Name ? Quantity)

For i = 3 To lastRowStock ' Assuming headers are in row 2

stockDict(wsStock.Cells(i, 2).Value) = wsStock.Cells(i, 8).Value ' Column B (Name) and Column H (QTY)

Next i

' Loop through Sales and update stock

For i = 3 To lastRowSales

Dim productName As String

Dim quantitySold As Integer

' Check if this sale has already been processed

If wsSales.Cells(i, 12).Value = "" Then ' Assuming column M is "Processed"

productName = wsSales.Cells(i, 8).Value ' Column H (Item Name)

quantitySold = wsSales.Cells(i, 10).Value ' Column J (Quantity Sold)

' Check if the product exists in stock

If stockDict.exists(productName) Then

' Deduct the quantity from stock

stockDict(productName) = stockDict(productName) - quantitySold

End If

' Mark the sale as processed

wsSales.Cells(i, 12).Value = "Processed"

End If

Next i

' Write back updated stock values

For i = 3 To lastRowStock

wsStock.Cells(i, 8).Value = stockDict(wsStock.Cells(i, 2).Value) ' Update Column H (QTY)

Next i

MsgBox "Stock updated successfully!", vbInformation

End Sub

------------------------------------------------------------------------------------------------------------------

Sub FetchInvoiceDetails()

Dim wsSales As Worksheet, wsPOS As Worksheet

Dim invoiceNo As String

Dim salesRow As Range

Dim lastRow As Long, posRow As Long

' Set your sheets

Set wsSales = ThisWorkbook.Sheets("Sales") ' Change to your Sales sheet name

Set wsPOS = ThisWorkbook.Sheets("POS") ' Change to your POS sheet name

' Get Invoice Number from POS sheet (Assume it's in Cell B6)

invoiceNo = wsPOS.Range("F14").Value

If invoiceNo = "" Then

MsgBox "Please enter Invoice Number!", vbExclamation

Exit Sub

End If

' Find the last row in Sales Sheet

lastRow = wsSales.Cells(wsSales.Rows.Count, 1).End(xlUp).Row

' Search Invoice No.

Set salesRow = wsSales.Range("A2:A" & lastRow).Find(invoiceNo, LookAt:=xlWhole)

If salesRow Is Nothing Then

MsgBox "Invoice Number not found!", vbExclamation

Exit Sub

End If

' Populate Customer Details

wsPOS.Range("M8").Value = salesRow.Offset(0, 1).Value ' Customer Name

wsPOS.Range("M9").Value = salesRow.Offset(0, 2).Value ' Email

wsPOS.Range("M10").Value = salesRow.Offset(0, 3).Value ' Phone

wsPOS.Range("P10:Q10").Value = salesRow.Offset(0, 5).Value ' Sales Person

' Populate Items

posRow = 13

Do While salesRow.Offset(0, 5).Value <> ""

wsPOS.Cells(posRow, 12).Value = salesRow.Offset(0, 6).Value ' Item No

wsPOS.Cells(posRow, 13).Value = salesRow.Offset(0, 7).Value ' Item Name

wsPOS.Cells(posRow, 15).Value = salesRow.Offset(0, 9).Value ' Quantity

wsPOS.Cells(posRow, 16).Value = salesRow.Offset(0, 10).Value ' Price

wsPOS.Cells(posRow, 17).Value = salesRow.Offset(0, 11).Value ' Price

'wsPOS.Cells(posRow, 17).Formula = "=O" & posRow & "\*P" & posRow ' Total

posRow = posRow + 1

Set salesRow = salesRow.Offset(1, 0)

Loop

MsgBox "Invoice Details Fetched Successfully!", vbInformation

End Sub

------------------------------------------------------------------------------------------------------------------

Sub ClearInvoiceDetails()

Dim wsPOS As Worksheet

Dim wsSales As Worksheet

Dim lastRow As Long

' Set your sheets

Set wsPOS = ThisWorkbook.Sheets("POS") ' Change to your POS sheet name

Set wsSales = ThisWorkbook.Sheets("Sales") ' Change to your Sales sheet name

' Clear Invoice Number

wsPOS.Range("F14").ClearContents

' Clear Customer Details

wsPOS.Range("M8:M10").ClearContents

wsPOS.Range("P10:Q10").ClearContents

' Clear Items

lastRow = wsPOS.Cells(wsPOS.Rows.Count, 12).End(xlUp).Row

If lastRow >= 13 Then

wsPOS.Range("L13:R" & lastRow).ClearContents

End If

' Update Sales Sheet (You can add specific updates here)

' Example: Refreshing formulas or recalculating sales data

wsSales.Calculate

MsgBox "Invoice Details Cleared Successfully!", vbInformation

End Sub

------------------------------------------------------------------------------------------------------------------

**Sheet 1 (POS)**

------------------------------------------------------------------------------------------------------------------

Private Sub Worksheet\_Change(ByVal Target As Range)

'On change of item, if Row found and add to receipt

If Not Intersect(Target, Range("E10")) Is Nothing And Range("E10").Value <> Empty Then AddItem

'On Change of Price Or Qty For Added Item

If Not Intersect(Target, Range("F8,F6")) Is Nothing And Range("B4").Value = False And Range("B6").Value <> Empty Then

Dim RecptRow As Long

RecptRow = Range("B6").Value 'Receipt Row

If Not Intersect(Target, Range("F6")) Is Nothing Then Range("P" & RecptRow).Value = Target.Value 'Update Price

If Not Intersect(Target, Range("F8")) Is Nothing Then Range("O" & RecptRow).Value = Target.Value 'Update Qty

End If

End Sub

------------------------------------------------------------------------------------------------------------------

Private Sub Worksheet\_SelectionChange(ByVal Target As Range)

'On Selection of Receipt Item, Load Item Details

If Not Intersect(Target, Range("L13:Q9999")) Is Nothing And Range("L" & Target.Row).Value <> Empty Then

Range("B6").Value = Target.Row 'Selected Row

Range("B4").Value = True

Range("E3").Value = Range("M" & Target.Row).Value 'Item Name

Range("F8").Value = Range("O" & Target.Row).Value 'Item Qty

Range("F6").Value = Range("P" & Target.Row).Value 'Item Price

Range("B4").Value = False

End If

End Sub

------------------------------------------------------------------------------------------------------------------

**Sheet 2 (Sales)**

------------------------------------------------------------------------------------------------------------------

Private Sub Worksheet\_Change(ByVal Target As Range)

If Not Intersect(Target, Me.Range("G:I")) Is Nothing Then ' Runs when Item or Quantity changes

Application.EnableEvents = False

UpdateStock

Application.EnableEvents = True

End If

End Sub

------------------------------------------------------------------------------------------------------------------

Private Sub Worksheet\_SelectionChange(ByVal Target As Range)

End Sub