add patched usbutils

Author: WaffleLapkin

configuration.nix

@@ -237,6 +237,7 @@
       "plugdev"
     ];
     packages = with pkgs; [
+      (callPackage ./custom-pkgs/usbutils/package.nix { })
       nix-output-monitor
       ffmpeg-full
       # davinci-resolve

custom-pkgs/usbutils/0001-Fix-display-of-HID-descriptors.patch

@@ -0,0 +1,38 @@
+From fdf51e7bb74ba4388f5dd6151d1a94e09563011b Mon Sep 17 00:00:00 2001
+From: Waffle Lapkin <waffle.lapkin@gmail.com>
+Date: Sun, 13 Apr 2025 20:23:31 +0200
+Subject: [PATCH] Fix display of HID descriptors
+
+The switch from hash tables to arrays + linear lookups created a bug --
+`names_genericstrtable` uses two variables (`h` and `t`) inconsistently
+in a loop, causing it to always return `NULL`, except for the first
+element in the array table.
+
+This in turn causes everything (except "Usage Page") in the HID
+descriptors to be `(null)` instead of the right string.
+---
+ names.c | 8 +++-----
+ 1 file changed, 3 insertions(+), 5 deletions(-)
+
+diff --git a/names.c b/names.c
+index b47532f..6c25404 100644
+--- a/names.c
++++ b/names.c
+@@ -35,11 +35,9 @@ static struct udev_hwdb *hwdb = NULL;
+ static const char *names_genericstrtable(const struct genericstrtable *t,
+ 					 unsigned int idx)
+ {
+-	const struct genericstrtable *h;
+-
+-	for (h = t; t->name; t++)
+-		if (h->num == idx)
+-			return h->name;
++	for (; t->name; t++)
++		if (t->num == idx)
++			return t->name;
+ 	return NULL;
+ }
+ 
+-- 
+2.48.1
+

custom-pkgs/usbutils/fix-paths.patch

@@ -0,0 +1,14 @@
+diff --git a/lsusb.py b/lsusb.py
+index bbc4dbb..8af1b1f 100755
+--- a/lsusb.py
++++ b/lsusb.py
+@@ -27,8 +27,7 @@ showwakeup = False
+ 
+ prefix = "/sys/bus/usb/devices/"
+ usbids = [
+-	"/usr/share/hwdata/usb.ids",
+-	"/usr/share/usb.ids",
++	"@hwdata@/share/hwdata/usb.ids",
+ ]
+ cols = ("", "", "", "", "", "")
+

custom-pkgs/usbutils/package.nix

@@ -0,0 +1,76 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  replaceVars,
+  fetchpatch,
+  meson,
+  ninja,
+  pkg-config,
+  libusb1,
+  hwdata,
+  python3,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "usbutils";
+  version = "018";
+
+  src = fetchurl {
+    url = "mirror://kernel/linux/utils/usb/usbutils/usbutils-${version}.tar.xz";
+    hash = "sha256-g/aLWbWFR1icACZugmcYZGJ1k6tDYtjIB/UO6pI8rZM=";
+  };
+
+  patches =
+    [
+      (replaceVars ./fix-paths.patch {
+        inherit hwdata;
+      })
+      ./0001-Fix-display-of-HID-descriptors.patch
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [
+      (fetchpatch {
+        url = "https://raw.githubusercontent.com/Homebrew/formula-patches/24a6945778381a62ecdcc1d78bcc16b9f86778c1/usbutils/portable.patch";
+        hash = "sha256-spTkWURij4sPLoWtDaWVMIk81AS5W+qUUOQL1pAZEvs=";
+      })
+    ];
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+  buildInputs = [
+    libusb1
+    python3
+  ];
+
+  outputs =
+    [
+      "out"
+      "man"
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isLinux [
+      "python" # uses sysfs
+    ];
+
+  postInstall = lib.optionalString stdenv.hostPlatform.isLinux ''
+    moveToOutput "bin/lsusb.py" "$python"
+    install -Dm555 usbreset -t $out/bin
+  '';
+
+  meta = {
+    homepage = "http://www.linux-usb.org/";
+    description = "Tools for working with USB devices, such as lsusb";
+    maintainers = with lib.maintainers; [
+      cafkafk
+      chuangzhu
+    ];
+    license = with lib.licenses; [
+      gpl2Only # manpages, usbreset
+      gpl2Plus # most of the code
+    ];
+    platforms = with lib.platforms; linux ++ darwin;
+    mainProgram = "lsusb";
+  };
+}