****

IBM-PC汇编语言

实验报告

|  |  |
| --- | --- |
| 实验内容： | 查找电话号码 |
| 姓 名： | 乔 楠 |
| 学 号： | 0919170210 |
| 专业班级： | 物联网工程1702班 |
| 指导教师： | 贺建飚 |

**实验四 查找电话号码**

1. **设计说明**

1.1实验目的与要求

学习用汇编语言设计与编写子程序。

题目：查找电话号码phone

1.2实验内容

(1) 要求程序建立一个可存放50项的电话号码表，每项包括人名(20个字符)及电话号码(8个字符)两部分；

(2) 程序可接收输入人名及相应的电话号码，并把它们加入电话号码表中；

(3) 凡有新的输入后，程序应按人名对电话号码表重新排序；

(4) 程序可接收需要查找电话号码的人名，并从电话号码表中查出其电话号码，再在屏幕上以如下格式显示出来。

name tel．

X X X X X X X X

1.3算法设计

关于查找电话号码的问题有多种程序能实现,但是所用的设计思想都是一样的,其实现的主要思想都是使用子程序结构.主程序的主要部分如下:

.显示提示符 Input name:

.调用子程序 input\_name 接收人名；

.调用子程序 stor\_name 把人名存入电话号码表tel\_tab中；

.显示提示符 Input a telephone number:

.调用子程序inphone接收电话号码,并把它存入电话号码表tel\_tab中；

.如输入已结束则调用name\_sort子程序对电话号码表按人名排序；

.显示提示符 Do you want a telephone number?(Y/N)；

.回答N则退出程序；

.回答Y则再显示提示符 name ；

.调用子程序 input\_name 接收人名；


.调用子程序 name\_search在电话号码表中查找所要的电话号码；


.调用子程序 printline按要求格式显示人名和电话号码；


.重复查号提示符直至用户不再要求查号为止．


1. **调试说明**

**2.1实验结果**














**2.2实验调试**











**2.3观察现象**

1. 在程序运行前，数据段的变量并没有进入数据段。

2. 在078D：0000中依次存入

**2.4实验心得**

我认为本次实验主要是要清楚各分支程序。什么时候该跳转到哪个分支，并在分支中做好各项处理工作是本次实验的重点。

并且此次实验也让我们明白了，汇编的输出都是“字符”，也就是说要想输出两位数字必须做一点处理，将它转换为相应的字符“一个一个”地输出，从而解决了实验中的疑问。

还有一点就是关于输入的问题，我采用的是单字符输入，边输入边处理。因为用字符串的话，输入之后，仍然要“一个一个”字符取出来去做判断，还不如直接就判断了。

1. **程序框图**



1. **程序清单**

**实验代码如下：**

;tele

;南有乔木

.MODEL SMALL

.STACK 64

;....................................................

.DATA

TEL\_TAB DB 50 DUP(20 DUP(?),8 DUP(?)) ;电话号码表（电话号码和人名）

MESS1 DB 0DH,0AH,0DH,0AH,11 DUP('.'),'Tel Table',11 DUP('.'),0DH,0AH,'$'

MESS2 DB 31 DUP('.'),0DH,0AH,'$'

MESS3 DB 0DH,0AH,0DH,0AH,9 DUP('-'),'Search Result',9 DUP('-'),0DH,0AH,'$'

MESS4 DB 31 DUP('-'),0DH,0AH,'$'

MESSNAME DB 0DH,0AH,'Input name:','$' ;提示输入姓名

MESSTEL DB 0DH,0AH,'Input a telephone number:','$' ;提示输入电话号码

MESSFIND DB 0DH,0AH,'Do you want a telephone number?(N/Y)','$';提示是否要进行查找操作

MESSERROR DB 0DH,0AH,'Invalid input!!',0DH,0AH,'$'

MESSN DB 0DH,0AH,'Name?','$' ;输入要查找的人名

MESSERROE DB 0DH,0AH,'Invlid input!please input again!','$' ;输入错误的提示

MESSDIS DB 0DH,0AH,'NAME',16 DUP(20H),'TEL',0DH,0AH,'$';输出号码表的格式

MESSNOTFIND DB 0DH,0AH,'The name is not in the table!!',0DH,0AH,'$'

INPUTNAME LABEL BYTE ;输入姓名的缓冲区

NMAXLEN DB 21

NAMELEN DB ?

I\_NAME DB 21 DUP(?)

INPUTTEL LABEL BYTE ;输入电话号码的缓冲区

TMAXLEN DB 9

TELLEN DB ?

I\_TEL DB 9 DUP(?)

TEMP DB 20 DUP(' '),8 DUP(' '),0DH,0AH,'$' ;输出电话表时借助的存储位置

TEMP\_TEL DW 0

COUNT DW 0 ;记录电话号码表的记录的个数

ENDADDR DW 0

SWAP DW 0

;....................................................

.CODE

MAIN PROC FAR

MOV AX,@DATA

MOV DS,AX

MOV ES,AX

CLD

LEA DI,TEL\_TAB

INPUT\_LOOP:

LEA DX,MESSNAME ;提示输入姓名

MOV AH,09H

INT 21H

CALL INPUT\_NAME ;输入姓名（调用输入姓名的子程序）

CMP NAMELEN,0 ;如果没有输入姓名则跳转

JZ NEXT

CMP COUNT,50 ;如果电话号码表满也跳转

JE NEXT

CALL STOR\_NAME ;调用保存姓名的子程序

CALL IPHONE ;输入电话号码和保存电话号码到电话号码表中

JMP INPUT\_LOOP ;循环输入电话号码和姓名

NEXT:

CALL NAME\_SORT

CALL DISPLAY ;输出电话号码表

SEARCH\_LOOP:

LEA DX,MESSFIND ;输入要进行查找的提示

MOV AH,09H

INT 21H

MOV AH,01H ;输入Y或y则查找，输入N或n则退出，其它则提示非法

INT 21H

CMP AL,'N'

JE EXIT

CMP AL,'n'

JE EXIT

CMP AL,'Y'

JE FIND

CMP AL,'y'

JE FIND

MOV AH,09H

LEA DX,MESSERROR

INT 21H

JMP SEARCH\_LOOP

FIND: MOV AH,09H

LEA DX,MESSN

INT 21H

CALL INPUT\_NAME ;输入要查找的姓名（调用输入姓名的子程序）

CALL NAME\_SEARCH ;调用查找姓名的子程序

CALL PRINTLINE

JMP SEARCH\_LOOP

EXIT: MOV AH,4CH

INT 21H

MAIN ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;输入姓名的子例程

INPUT\_NAME PROC NEAR

MOV AH,0AH

LEA DX,INPUTNAME ;输入姓名

INT 21H

MOV BH,0

MOV BL,NAMELEN

MOV CX,21

SUB CX,BX

NAME\_LOOP: MOV I\_NAME[BX],20H ;除了姓名以外的字符均以空格代替

INC BX

LOOP NAME\_LOOP

RET

INPUT\_NAME ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;把人名存入电话号码表tel\_tab的子例程

STOR\_NAME PROC NEAR

INC COUNT

CLD

LEA SI,I\_NAME ;将输入的姓名放入电话号码表中

MOV CX,10

REP MOVSW

RET

STOR\_NAME ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;接收电话号码，并把它存入电话号码表中的iphone子例程

IPHONE PROC NEAR

I\_START: LEA DX,MESSTEL ;提示输入电话号码提示

MOV AH,09H

INT 21H

LEA DX,INPUTTEL ;输入电话号码

MOV AH,0AH

INT 21H

MOV BX,0

MOV CH,0

MOV CL,TELLEN

CHECK: MOV AL,I\_TEL[BX] ;检查电话号码输入是否合法

INC BX

CMP AL,30H

JB I\_NEXT ;如果输入不合法就输出提示信息

CMP AL,39H

JA I\_NEXT ;如果输入不合法就输出提示信息

LOOP CHECK

MOV BH,0

MOV BL,TELLEN

MOV CX,9

SUB CX,BX

TEL\_LOOP:

MOV I\_TEL[BX],20H ;除了电话号码以外的字符都以空格代替

INC BX

LOOP TEL\_LOOP

CLD

LEA SI,I\_TEL ;将电话号码存放在电话号码表中

MOV CX,4

REP MOVSW

RET

I\_NEXT:MOV AH,09H

LEA DX,MESSERROR

INT 21H

JMP I\_START

IPHONE ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;NAME\_SORT子程序，此时DI已经指向了电话号码表中的最后一项的末尾

NAME\_SORT PROC NEAR

SUB DI,56

MOV ENDADDR,DI ;用ENDADDER来记录电话号码表中的倒数第二项的偏移地址

SORT\_NEXT1:MOV SWAP,0

MOV SI,OFFSET TEL\_TAB ;SI得到电话号码表的偏移地址

SORT\_NEXT2:MOV CX,20

CLD

MOV DI,SI

ADD DI,28 ;DI指向SI的下一个电话号码项

MOV AX,DI ;AX保存DI的值

MOV BX,SI ;BX保存SI的值

REPE CMPSB ;等于则重复

JBE SORT\_NEXT3 ;不用交换跳转

CALL CHANGE ;调用交换子例程

SORT\_NEXT3:MOV SI,AX ;SI指向上一个DI的位置

CMP SI,ENDADDR ;判断SI是否位于倒数第二个电话号码项

JBE SORT\_NEXT2

CMP SWAP,0

JNZ SORT\_NEXT1 ;如果后面的项发生了交换就要重新进行扫描了，知道没有交 ;换的项为止

RET

NAME\_SORT ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;子程序CHANGE交换两个字符串（为了便于说明设为串1和串2）的子程序

CHANGE PROC NEAR

CLD

MOV CX,14

MOV SI,BX ;SI指向串1

LEA DI,TEMP ;将串1的字符串(电话号码的一项）移到TEMP

REP MOVSW

CLD

MOV CX,14 ;此时SI已经移动到了串2的位置

MOV DI,BX ;将DI指向串1

REP MOVSW ;这时把串2移动到了串1中

CLD

MOV CX,14 ;此时DI已经指向了串2

LEA SI,TEMP ;SI指向TEMP

REP MOVSW ;将TEMP中的内容移到了串2中

MOV SWAP,1

RET

CHANGE ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;子程序NAME\_SEARCH，在电话号码表中查找所要的电话号码

NAME\_SEARCH PROC NEAR

LEA SI,TEL\_TAB ;si指向电话号码表

MOV BX,SI ;bx用于保存si的值

MOV DX,COUNT ;dx保存了count电话号码表的项数的值，用来控制查找的次数

SEA\_LOOP: LEA DI,I\_NAME ;di指向要查找的姓名

MOV CX,10

REPE CMPSW ;比较si di相等重复比较

JCXZ SEA\_EXIT ;当cx为0就跳转，此时找到了要查找的字符

ADD BX,28

MOV SI,BX ;si移动到电话号码表的下一项

DEC DX

JNZ SEA\_LOOP

NOTAB: MOV CX,-1 ;如果查找结束以后发现没有找到就设cx为-1

RET

SEA\_EXIT: MOV SI,BX ;保存查找到的电话号码记录到temp

LEA DI,TEMP

MOV CX,14

REP MOVSW

RET

NAME\_SEARCH ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;子例程DISPLAY,按要求显示人名以及电话号码

DISPLAY PROC NEAR

MOV AH,09H ;显示要输出电话号码表的提示信息

LEA DX,MESS1

INT 21H

MOV AH,09H

LEA DX,MESSDIS

INT 21H

LEA SI,TEL\_TAB ;si指向电话号码表的开始地址

MOV BX,COUNT ;bx保存了电话号码表的项数

LOOP\_DIS: CLD

LEA DI,TEMP ;di指向temp,将电话号码表中要输出的项保存在temp

MOV CX,14

REP MOVSW

MOV AH,09H

LEA DX,TEMP ;输出temp中的电话号码项

INT 21H

DEC BX

JNZ LOOP\_DIS

MOV AH,09H

LEA DX,MESS2

INT 21H

RET

DISPLAY ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;printline子例程，用于输出查找的结果

PRINTLINE PROC NEAR

MOV AH,09H

LEA DX,MESS3

INT 21H

CMP CX,-1

JE NOTFIND

MOV AH,09H

LEA DX,MESSDIS

INT 21H

MOV AH,09H

LEA DX,TEMP

INT 21H

JMP P\_EXIT

NOTFIND: MOV AH,09H

MOV DX,OFFSET MESSNOTFIND

INT 21H

P\_EXIT: MOV AH,09H

LEA DX,MESS4

INT 21H

RET

PRINTLINE ENDP

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

END MAIN