# Sparql Sample Queries

Please adapt these queries to your needs (e.g. adapting the dois of the articles to match the articles within your document collection rdfized with se4ojs).

**Query for the sections directly contained by the article**

prefix c4o: <http://purl.org/spar/c4o/>

prefix prism: <http://prismstandard.org/namespaces/basic/2.0/>

prefix co: <http://purl.org/co/>

prefix deo: <http://purl.org/spar/deo/>

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

prefix owl: <http://www.w3.org/2002/07/owl#>

prefix xsd: <http://www.w3.org/2001/XMLSchema#>

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

prefix po: <http://www.essepuntato.it/2008/12/pattern#>

prefix doco: <http://purl.org/spar/doco/>

prefix fabio: <http://purl.org/spar/fabio/>

#select the first-level sections of the article and the text contained in these sections.

select ?sec ?p ?text

where {

?article rdf:type fabio:Article.

?article prism:doi "10.5964/ejcop.v3i1.23".

?article po:contains ?list.

?list co:element ?sec.

?sec rdf:type doco:Section.

?sec po:contains ?listSubSecAndParagraphs.

?listSubSecAndParagraphs co:element ?p.

?p rdf:type doco:Paragraph.

?p c4o:hasContent ?text.

}

**Query for all sections (directly contained sections and transitively contained subsections) of the article**

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

prefix doco: <http://purl.org/spar/doco/>

prefix prism: <http://prismstandard.org/namespaces/basic/2.0/>

prefix co: <http://purl.org/co/>

prefix zpid\_doco: <http://www.zpid.de/zpid\_doco#>

prefix po: <http://www.essepuntato.it/2008/12/pattern#>

select ?article ?sec

where {

?article prism:doi "10.5964/ejcop.v3i1.23".

?article zpid\_doco:containsIndirectly ?list.

?list rdf:type po:Structured.

?list co:element ?sec.

?sec rdf:type doco:Section.

}

**Query that ranks the citations of references of an article according to frequency**

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

prefix owl: <http://www.w3.org/2002/07/owl#>

prefix xsd: <http://www.w3.org/2001/XMLSchema#>

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

prefix prism: <http://prismstandard.org/namespaces/basic/2.0/>

prefix cito: <http://purl.org/spar/cito/>

prefix biro: <http://purl.org/spar/biro/>

prefix c4o: <http://purl.org/spar/c4o/>

#The top 10 references cited in the article with in-text citation frequency > 1.

Select ?ref ?inTextCount

where {

?art prism:doi "10.5964/ejcop.v3i1.23".

?art cito:cites ?refText.

?ref biro:references ?refText.

?ref c4o:hasInTextCitationFrequency ?inTextCount

FILTER(?inTextCount > 1)

} ORDER BY DESC (?inTextCount ) LIMIT 10

**Query to retrieve the titles of the top 10 references cited in the article with in-text citation frequency > 1.**

prefix cito: <http://purl.org/spar/cito/>

prefix dcterms: <http://purl.org/dc/terms/>

prefix biro: <http://purl.org/spar/biro/>

prefix c4o: <http://purl.org/spar/c4o/>

prefix prism: <http://prismstandard.org/namespaces/basic/2.0/>

Select ?refTitle ?inTextCount

where {

?art prism:doi "10.5964/ejcop.v3i1.23".

?art cito:cites ?refText.

?ref biro:references ?refText.

?ref c4o:hasInTextCitationFrequency ?inTextCount.

?refText dcterms:title ?refTitle.

FILTER(?inTextCount > 1)

} ORDER BY DESC (?inTextCount ) LIMIT 10

**Retrieve the references’ titles and links to pdf of an article’s references that have a link to a PDF.**

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

prefix owl: <http://www.w3.org/2002/07/owl#>

prefix xsd: <http://www.w3.org/2001/XMLSchema#>

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

prefix frbr: <http://purl.org/vocab/frbr/core#>

prefix biro: <http://purl.org/spar/biro/>

prefix fabio: <http://purl.org/spar/fabio/>

prefix dcterms:<http://purl.org/dc/terms/>

prefix application:<http://purl.org/NET/mediatypes/application/>

prefix cito:<http://purl.org/spar/cito/>

SELECT \*

WHERE {

?article rdf:type fabio:Article.

?article dcterms:title ?title.

?article cito:cites ?ref.

?ref frbr:embodiment ?pdf.

?ref dcterms:title ?refTitle.

?pdf dcterms:format application:pdf.

?pdf dcterms:relation ?pdfLink.

FILTER(contains (?title, "Anger"))

}

**Query to retrieve the Top cited authors of an article.**

prefix foaf: <http://xmlns.com/foaf/0.1/>

prefix doco: <http://purl.org/spar/doco/>

prefix cito: <http://purl.org/spar/cito/>

prefix dcterms: <http://purl.org/dc/terms/>

prefix biro: <http://purl.org/spar/biro/>

prefix c4o: <http://purl.org/spar/c4o/>

prefix prism: <http://prismstandard.org/namespaces/basic/2.0/>

prefix pro: <http://purl.org/spar/pro/>

#The top cited authors of the article.

Select (sum(?inTextCount) AS ?count) ?authorName ?firstName

where {

?art prism:doi "10.5964/ejop.v8i3.308".

?art cito:cites ?reference.

?inTextCitation biro:references ?reference.

?inTextCitation c4o:hasInTextCitationFrequency ?inTextCount.

?reference dcterms:title ?refTitle.

?role pro:relatesToDocument ?reference.

?role pro:withRole pro:author.

?group pro:holdsRoleInTime ?role.

?group foaf:member ?member.

?member foaf:familyName ?authorName.

?member foaf:givenName ?firstName.

} GROUP BY ?authorName ?firstName ORDER BY Desc (?count)

**Query to retrieve the sections ranked by number of citations occurring within their paragraphs.**

prefix doco: <http://purl.org/spar/doco/>

prefix cito: <http://purl.org/spar/cito/>

prefix dcterms: <http://purl.org/dc/terms/>

prefix biro: <http://purl.org/spar/biro/>

prefix c4o: <http://purl.org/spar/c4o/>

prefix prism: <http://prismstandard.org/namespaces/basic/2.0/>

prefix po: <http://www.essepuntato.it/2008/12/pattern#>

#The sections with the most citations within an article.

Select (count(?ref) as ?refcount) ?sec

where {

?art prism:doi "10.5964/ejcop.v3i1.23".

?art cito:cites ?refText.

?ref biro:references ?refText.

?refPtr c4o:denotes ?ref.

?refPtr c4o:hasContext ?para.

?sec po:contains ?para.

} GROUP BY ?sec ORDER BY desc (?refcount)

**Query for "mental disorders" in the document collection**

This query searches the ONTOAD ontology:  
 - It searches for the children of the concept with the preferred label "Mental disorders" in the ONTOAD ontology (an owl / skos ontology that needs to be copied to the SPARQL endpoint and can be obtained from bioportal).  
- It matches ao:body's object in the rdf (which is the concept preferred label) to the corresponding preferred label of the matched child concepts.  
- It displays the title of the article where the match was found, the matched text itself, the paragraph, the paragraph starting position and the concept resource (of the ontology).  
  
prefix skos: [<http://www.w3.org/2004/02/skos/core#>](http://www.w3.org/2004/02/skos/core)  
prefix rdf: [<http://www.w3.org/1999/02/22-rdf-syntax-ns#>](http://www.w3.org/1999/02/22-rdf-syntax-ns)  
prefix owl: [<http://www.w3.org/2002/07/owl#>](http://www.w3.org/2002/07/owl)  
prefix xsd: [<http://www.w3.org/2001/XMLSchema#>](http://www.w3.org/2001/XMLSchema)  
prefix rdfs: [<http://www.w3.org/2000/01/rdf-schema#>](http://www.w3.org/2000/01/rdf-schema)  
prefix aot: [<http://purl.org/ao/types/>](http://purl.org/ao/types/)  
prefix aos: [<http://purl.org/ao/selectors/>](http://purl.org/ao/selectors/)  
prefix dcterms: [<http://purl.org/dc/terms/>](http://purl.org/dc/terms/)  
prefix aoa: [<http://purl.org/ao/annotea/>](http://purl.org/ao/annotea/)  
prefix c4o: [<http://purl.org/spar/c4o/>](http://purl.org/spar/c4o/)  
prefix biotea: [<http://www.biotea.ws/ontology/ao\_biotea.owl#>](http://www.biotea.ws/ontology/ao_biotea.owl)  
prefix ao: [<http://purl.org/ao/core/>](http://purl.org/ao/core/)  
  
SELECT ?title ?textMatch ?text ?label ?concept ?startPosition  
WHERE{  
 ?annotation ao:body ?body.

  ?annotation ao:context ?context.  
 ?context ao:exact ?textMatch.  
 ?context dcterms:referencesÂ  ?para.  
 ?context ao:offset ?startPosition.  
 ?para c4o:hasContent ?text.  
 ?annotation ao:annotatesResource ?doc.  
 BIND(IRI(CONCAT(STR(?doc), "/textual-entity")) AS ?docTextualEntity)  
 ?docTextualEntity dcterms:title ?title.?concept skos:prefLabel ?label.?concept rdfs:subClassOf ?parentConcept.?parentConcept skos:prefLabel ?parentLabel.  
FILTER(STR(?parentLabel) = 'Mental disorders')  
FILTER(STR(?label) = ?body)  
}