\*\*\*\*\* Program 5.1: Complete Covariate (CC) Analysis \*\*\*\*\*;

**PROC** **FORMAT**;

VALUE FORMATYN **0** = 'NO'

**1** = 'YES';

**RUN**;

%LET VARLIST = AGE BMIR GAILMORE LSC LTOTBMR FNC NECKBMDR AESCORE SQ FAMHXBCN

KHYSYN NVFX PREVHRT PREVVERT SMOKE VFX;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* COMPLETE COVARIATE (CC) ANALYSIS;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

**PROC** **LOGISTIC** DATA = ANALDATA NOPRINT;

MODEL BISMORE = &VARLIST;

OUTPUT OUT=PRED PREDICTED=P;

**RUN**;

**DATA** PRED;

SET PRED;

IF BISMORE = **0** THEN PROB = P;

IF BISMORE = **1** THEN PROB = **1**-P;

W = **1**/PROB;

**RUN**;

**PROC** **SORT** DATA=PRED;

BY BISMORE;

**RUN**;

TITLE 'ANALYSIS RESULTS USING THE COMPLETE COVARIATE (CC) METHOD';

**PROC** **MIXED** DATA = PRED;

CLASS BISMORE;

MODEL FNBMD\_C = BISMORE;

WEIGHT W;

FORMAT BISMORE FORMATYN.;

LSMEANS BISMORE/DIFF=ALL;

**RUN**;

\*\*\*\*\* Program 5.2: Indicator Variable (IND) Analysis \*\*\*\*\*:

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* INDICATOR VARIABLE (IND) ANALYSIS;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

**PROC** **MEANS** DATA = ANALDATA NOPRINT;

VAR AGE BMIR GAILMORE LSC LTOTBMR FNC NECKBMDR AESCORE SQ;

OUTPUT OUT = ANALDATA\_MEAN MEAN=AGE\_M BMIR\_M GAILMORE\_M LSC\_M LTOTBMDR\_M FNC\_M NECKBMDR\_M AESCORE\_M SQ\_M;

BY STUDY;

**RUN**;

**DATA** ANALDATA\_2;

MERGE ANALDATA ANALDATA\_MEAN;

BY STUDY;

**RUN**;

**DATA** ANALDATA\_IV;

SET ANALDATA\_2;

ARRAY X{**9**} AGE BMIR GAILMORE LSC LTOTBMR FNC NECKBMDR AESCORE SQ;

ARRAY M{**9**} M1-M9;

ARRAY XM{**9**} AGE\_M BMIR\_M GAILMORE\_M LSC\_M LTOTBMDR\_M FNC\_M NECKBMDR\_M AESCORE\_M SQ\_M;

DO I = **1** TO **9**;

IF X{I} = **.** THEN DO;

M{I} = **1**;

X{I} = XM{I};

END;

ELSE M{I} = **0**;

END;

ARRAY XC{**7**} FAMHXBCN KHYSYN NVFX PREVHRT PREVVERT SMOKE VFX;

DO I = **1** TO **7**;

IF XC{I} = **.** THEN XC{I} = -**1**;

END;

**RUN**;

**PROC** **LOGISTIC** DATA = ANALDATA\_IV NOPRINT;

CLASS FAMHXBCN KHYSYN NVFX PREVHRT PREVVERT SMOKE VFX;

MODEL BISMORE = &VARLIST M1-M9;

OUTPUT OUT=PRED PREDICTED=P;

**RUN**;

**DATA** PRED;

SET PRED;

IF BISMORE = **0** THEN PROB = P;

IF BISMORE = **1** THEN PROB = **1**-P;

W = **1**/PROB;

**RUN**;

**PROC** **SORT** DATA=PRED;

BY BISMORE;

**RUN**;

TITLE 'ANALYSIS RESULTS USING THE INDICATOR VARIABLE (IND) METHOD';

**PROC** **MIXED** DATA = PRED;

CLASS BISMORE;

MODEL FNBMD\_C = BISMORE;

WEIGHT W;

LSMEANS BISMORE/DIFF=ALL;

FORMAT BISMORE FORMATYN.;

**RUN**;

\*\*\*\*\* Program 5.3: The Multiple Imputation (MI) Analysis \*\*\*\*\*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* ANALYSIS RESULTS USING THE MULTIPLE IMPUTATION (MI) METHOD;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

**PROC** **MI** DATA = ANALDATA ROUND=**.001** NIMPUTE=**5** SEED=**6731205** OUT=IMPUTED\_DATA NOPRINT;

VAR &VARLIST FNBMD\_C BISMORE;

**RUN**;

**PROC** **LOGISTIC** DATA = IMPUTED\_DATA NOPRINT;

MODEL BISMORE = &VARLIST;

OUTPUT OUT=PRED PREDICTED=P;

BY \_IMPUTATION\_;

**RUN**;

**DATA** PRED;

SET PRED;

IF BISMORE = **0** THEN PROB = P;

IF BISMORE = **1** THEN PROB = **1**-P;

W = **1**/PROB;

**RUN**;

**PROC** **SORT** DATA=PRED;

BY \_IMPUTATION\_ BISMORE;

**RUN**;

ODS LISTING CLOSE;

ODS OUTPUT LSMEANS = LSM DIFFS=DIFFS;

**PROC** **MIXED** DATA = PRED;

CLASS BISMORE;

MODEL FNBMD\_C = BISMORE;

WEIGHT W;

BY \_IMPUTATION\_;

LSMEANS BISMORE/ DIFF=ALL;

**RUN**;

ODS LISTING;

TITLE 'ANALYSIS RESULTS USING THE MULTIPLE IMPUTATION (MI) METHOD';

TITLE2 'POINT ESTIMATES BY TREATMENT GROUP';

**PROC** **MEANS** DATA=LSM;

CLASS BISMORE;

VAR ESTIMATE;

FORMAT BISMORE FORMATYN.;

**RUN**;

TITLE2 'POINT ESTIMATE FOR THE TREATMENT DIFFERENCE';

**PROC** **MEANS** DATA = DIFFS;

VAR ESTIMATE;

**RUN**;

\*\*\*\*\* Program 5.4: Summarize the Estimates from the MI Method Using PROC MIANALYZE \*\*\*;

TITLE2 'ESTIMATE THE TREATMENT DIFFERENCE USING PROC MIANALYZE';

**DATA** FOR\_MI\_EST (KEEP = \_IMPUTATION\_ EFFECT ESTIMATE RENAME=(EFFECT= PARAMETER));

SET DIFFS;

EFFECT = 'DIFF';

**RUN**;

**DATA** FOR\_MI\_COV (KEEP = \_IMPUTATION\_ ROWNAME BISMORE DIFF );

SET DIFFS;

DIFF = STDERR\*\***2**;

ROWNAME = "DIFF";

**RUN**;

**PROC** **MIANALYZE** PARMS=FOR\_MI\_EST COVB=FOR\_MI\_COV;

MODELEFFECTS DIFF;

ODS OUTPUT PARAMETERESTIMATES=MI\_EST

VARIANCEINFO=MI\_VAR; run;

**\*\*\*\*\* Program 5.5** Macro to Pool Small Missingness Pattern \*\*\*\*\*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* Input parameters:

\* indata = input data set;

\* outdata = output data set;

\* varlist = a list of variables to be included in the propensity score

estimation;

\* M\_MP\_MIN = minimum number of observations for each missing pattern.

\* Missing patterns with less than MIN\_MP observations will be

pooled;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

**%MACRO** MP\_ASSIGN(MSDATA = , OUTDATA =, VARLIST =, N\_MP\_MIN = **100**);

/\* Determine how many variables to include in the propensity score

estimation \*/

%LET N = 1;

%LET VARINT = ;

%DO %UNTIL(%QSCAN(&VARLIST., &N. , %STR( )) EQ %STR( ));

%LET VAR = %QSCAN(&VARLIST. , &N. , %STR( ));

%LET VARINT = &VARINT &VAR.\*MP;

%LET N = %EVAL(&N. + 1);

%END;

%LET KO = %EVAL(&N-1);

%LET M\_MISSING = %EVAL(&N-1);

%PUT &VARINT;

%PUT &KO;

%PUT &M\_MISSING;

/\* Create indicators for missing values and missingness patterns \*/

DATA MS;

SET &MSDATA;

ARRAY MS{&M\_MISSING} M1-M&M\_MISSING.;

ARRAY X{&M\_MISSING} &VARLIST;

MV = **0**;

DO I = **1** TO &M\_MISSING;

IF X{I} = **.** THEN MS{I} = **1**;

ELSE MS{I} = **0**;

MV = **2**\*MV + MS{I};

END;

MV = MV + **1**;

DROP I;

RUN;

/\* Only keep one record for each missingness pattern \*/

PROC SORT DATA = MS OUT = PATTERN NODUPKEY;

BY MV;

RUN;

/\* Calculate the number of observations in each missingness pattern \*/

PROC FREQ DATA = MS NOPRINT;

TABLES MV / OUT = M\_MP(KEEP = MV COUNT);

RUN;

DATA PATTERN;

MERGE PATTERN M\_MP;

BY MV;

RUN;

PROC SORT DATA = PATTERN;

BY DESCENDING COUNT;

RUN;

/\* Assign missingness pattern to new index from the largest to the smallest \*/

DATA PATTERN;

RETAIN M1-M&M\_MISSING MV COUNT MV\_S;

SET PATTERN;

KEEP M1-M&M\_MISSING MV COUNT MV\_S;

MV\_S = \_N\_;

RUN;

PROC IML;

USE PATTERN;

READ ALL INTO A;

CLOSE PATTERN;

MS = A[, **1**:&M\_MISSING];

MV = A[, **1**+&M\_MISSING];

N\_MP = A[, **2**+&M\_MISSING];

MV\_S = A[, **3**+&M\_MISSING];

M\_MP = NROW(MS);

M = NCOL(MS);

/\* Calculate the distance between missingness patterns \*/

DISTANCE = J(M\_MP, M\_MP, **0**);

DO I = **1** TO M\_MP;

DO J = **1** TO I-**1**;

D = **0**;

DO L = **1** TO M;

D = D + ( (MS[I,L]-MS[J,L])\*(MS[I,L]-MS[J,L]) );

END;

DISTANCE[I,J] = D;

DISTANCE[J,I] = D;

END;

END;

I = **0**;

K\_MV\_POOL = **0**;

MV\_POOL = J(M\_MP, **1**, **0**);

/\*Pooling small missingness patterns according to their similarities to

reach a prespecified minimum number of observations (&N\_MP\_MIN) in each

pattern \*/

DO WHILE( I < M\_MP);

I = I + **1**;

IF MV\_POOL[I] = **0** THEN

DO;

K\_MV\_POOL = K\_MV\_POOL + **1**;

N\_MP\_POOL = N\_MP[I];

IF N\_MP\_POOL >= &N\_MP\_MIN THEN

DO;

MV\_POOL[I] = K\_MV\_POOL;

END;

ELSE

DO;

IF I < M\_MP THEN

DO;

A = DISTANCE[(I+**1**):M\_MP, I];

B = MV[(I+**1**):M\_MP];

C = N\_MP[(I+**1**):M\_MP];

D = MV\_S[(I+**1**):M\_MP];

E = MV\_POOL[(I+**1**):M\_MP];

TT = A || B || C || D || E;

CALL SORT( TT, {**1 3**});

J = **0**;

DO WHILE( (N\_MP\_POOL < &N\_MP\_MIN) & (I+J < M\_MP) );

J = J+**1**;

IF (TT[J,**5**] = **0**) THEN

DO;

N\_MP\_POOL = N\_MP\_POOL + TT[J,**3**];

TT[J,**5**] = K\_MV\_POOL;

END;

END;

END;

IF ( N\_MP\_POOL >= &N\_MP\_MIN ) THEN

DO;

MV\_POOL[I] = K\_MV\_POOL;

DO K = **1** TO J;

MV\_POOL[TT[K,**4**]] = K\_MV\_POOL;

END;

END;

ELSE

DO J = I TO M\_MP;

SGN\_TMP = **0**;

K = **1**;

DO WHILE(SGN\_TMP = **0** & K <= M\_MP);

DO L = **1** TO M\_MP;

IF (DISTANCE[J,L] = K) & (MV\_POOL[J]=**0**) &

(MV\_POOL[L]>**0**) THEN

DO;

MV\_POOL[J] = MV\_POOL[L];

SGN\_TMP = **1**;

END;

END;

K = K + **1**;

END;

END;

END;

END;

END;

MV\_FINAL = MV || MV\_POOL;

VARNAMES={'MV' 'MV\_POOL'};

CREATE MVPOOL FROM MV\_FINAL[COLNAME=VARNAMES];

APPEND FROM MV\_FINAL;

QUIT;

PROC SORT DATA = MVPOOL;

BY MV;

RUN;

PROC SORT DATA = MS;

BY MV;

RUN;

/\* The variable MVPOOL in the &OUTDATA set indicates the pooled missingness

pattern \*/

DATA &OUTDATA(RENAME=(MV=MP\_ORIG MV\_POOL=MP));

MERGE MS MVPOOL;

BY MV;

RUN;

**%MEND** MP\_ASSIGN;

\*\*\*\*\* Program 5.6: The Missingness Pattern (MP) Analysis \*\*\*\*\*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* MISSINGNESS PATTERN (MP) METHOD;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

%**MP\_ASSIGN**(MSDATA = ANALDATA, OUTDATA = ANALDATA2, VARLIST = &VARLIST, N\_MP\_MIN = **100**);

**PROC** **MEANS** DATA = ANALDATA2 NOPRINT;

VAR &VARLIST;

OUTPUT OUT = MN MEAN = XM1-XM16;

BY STUDY;

**RUN**;

**DATA** TEMP;

MERGE ANALDATA2 MN;

BY STUDY;

**RUN**;

**DATA** TEMP;

SET TEMP;

ARRAY X{**16**} &VARLIST;

ARRAY XM{**16**} XM1-XM16;

DO I = **1** TO **16**;

IF X{I} = **.** THEN X{I} = XM{I};

END;

DROP I;

**RUN**;

**PROC** **SORT** DATA = TEMP;

BY MP;

**RUN**;

**PROC** **LOGISTIC** DATA = TEMP NOPRINT;

CLASS MP;

MODEL BISMORE = &VARLIST;

OUTPUT OUT=PRED PREDICTED=P;

BY MP;

**RUN**;

**DATA** PRED;

SET PRED;

IF BISMORE = **0** THEN PROB = P;

IF BISMORE = **1** THEN PROB = **1**-P;

W = **1**/PROB;

**RUN**;

**PROC** **SORT** DATA=PRED;

BY BISMORE;

**RUN**;

TITLE 'ANALYSIS RESULTS USING THE MISSINGNESS PATTERN (MP) METHOD';

**PROC** **MIXED** DATA = PRED;

CLASS BISMORE;

MODEL FNBMD\_C = BISMORE;

WEIGHT W;

LSMEANS BISMORE/DIFF=ALL;

FORMAT BISMORE FORMATYN.;

**RUN**;

\*\*\*\*\* Program 5.7: The Multiple Imputations Missingness Pattern (MIMP) Analysis \*\*\*\*\*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* Multiple Imputation Missingness Pattern (MIMP) Method;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

**PROC** **MI** DATA = ANALDATA2 ROUND=**.001** NIMPUTE=**5** SEED=**6731205** OUT=IMPUTED\_DATA NOPRINT;

VAR &VARLIST FNBMD\_C BISMORE;

**RUN**;

**PROC** **LOGISTIC** DATA = IMPUTED\_DATA NOPRINT;

CLASS MP;

MODEL BISMORE = &VARLIST MP;

OUTPUT OUT=PRED PREDICTED=P;

BY \_IMPUTATION\_;

**RUN**;

**DATA** PRED;

SET PRED;

IF BISMORE = **0** THEN PROB = P;

IF BISMORE = **1** THEN PROB = **1**-P;

W = **1**/PROB;

**RUN**;

**PROC** **SORT** DATA=PRED;

BY \_IMPUTATION\_ BISMORE;

**RUN**;

ODS OUTPUT LSMEANS = LSM DIFFS=DIFFS;

**PROC** **MIXED** DATA = PRED;

CLASS BISMORE;

MODEL FNBMD\_C = BISMORE;

WEIGHT W;

BY \_IMPUTATION\_;

LSMEANS BISMORE/ DIFF=ALL;

**RUN**;

TITLE 'ANALYSIS RESULTS USING THE MULTIPLE IMPUTATION MISSINGNESS PATTERN (MIMP) METHOD';

TITLE2 'POINT ESTIMATES BY TREATMENT GROUP';

**PROC** **MEANS** DATA=LSM;

CLASS BISMORE;

VAR ESTIMATE;

FORMAT BISMORE FORMATYN.;

**RUN**;

TITLE2 'POINT ESTIMATE FOR THE TREATMENT DIFFERENCE';

**PROC** **MEANS** DATA = DIFFS;

VAR ESTIMATE;

**RUN**;

\*\*\*\*\* Program 5.8: Summarize the Estimates from the MIMP Method Using PROC MIANALYZE \*\*\*;

TITLE2 'ESTIMATE THE TREATMENT DIFFERENCE USING PROC MIANALYZE';

**DATA** FOR\_MIMP\_EST (KEEP = \_IMPUTATION\_ EFFECT ESTIMATE RENAME=(EFFECT= PARAMETER));

SET DIFFS;

EFFECT = 'DIFF';

**RUN**;

**DATA** FOR\_MIMP\_COV (KEEP = \_IMPUTATION\_ ROWNAME BISMORE DIFF );

SET DIFFS;

DIFF = STDERR\*\***2**;

ROWNAME = "DIFF";

**RUN**;

**PROC** **MIANALYZE** PARMS=FOR\_MIMP\_EST COVB=FOR\_MIMP\_COV;

MODELEFFECTS DIFF;

ODS OUTPUT PARAMETERESTIMATES=MI\_EST

VARIANCEINFO=MI\_VAR;

**RUN**;

\*\*\* Program 5.9: Estimation of the Variance and Confidence Interval Using the Bootstrap Method \*\*;

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

MIMP\_ANALYSIS is a macro which calculates CC, MI, MP and MIMP estimates;

Q\_METH indicates the method

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

%INCLUDE ‘BOOTS.SAS’; /\* the file can be found in [**http://cuke.hort.ncsu.edu/cucurbit/wehner/software/pathsas/jackboot.txt**](http://cuke.hort.ncsu.edu/cucurbit/wehner/software/pathsas/jackboot.txt) \*/

%MACRO ANALYZE(DATA=BMDPS, OUT= );

%MIMP\_ANALYSIS(INDATA = &DATA, VARLIST = &VARLIST, Y = FNBMD\_C, G = BISMORE, M\_MP\_MIN = 100);

PROC SORT DATA = EST OUT = &OUT;

BY Q\_METH;

RUN;

%MEND ANALYZE;

PROC PRINTTO LOG=NOLOG;

RUN;

TITLE 'BOOSTRAP: NORMAL ("STANDARD") CONFIDENCE INTERVAL WITH BIAS CORRECTION';

TITLE2;

%BOOT(DATA=BMDPS, ALPHA=.05, SAMPLES=1000, RANDOM=123, ID=Q\_METH);

TITLE 'BOOTSTRAP BCA';

%BOOTCI(BCA, ID=Q\_METH);

PROC PRINTTO;

RUN;

\*\*\*\*\* Program 5.10 Illustration of the Sensitivity Analysis Using Propensity Score Stratified Regression Estimator \*\*\*\*\*;

/\* THIS STEP CAN BE REPLACED WITH ANY METHOD FOR OBTAINING PROPENSITY SCORES \*/

**PROC** **LOGISTIC** DATA = ANALDATA DESC NOPRINT;

MODEL BISMORE = &VARLIST;

OUTPUT OUT=PRED PREDICTED=P;

**RUN**;

/\* DEFINE THE QUINTILES WITH PROC RANK (GROUP=5) \*/

**PROC** **RANK** DATA = PRED OUT=PRED GROUPS=**5**;

VAR P;

RANKS PS\_STRATA;

**RUN**;

**PROC** **SORT** DATA=PRED; BY PS\_STRATA; **RUN**;

ODS LISTING CLOSE;

ODS OUTPUT SOLUTIONF=SF;

**PROC** **MIXED** DATA = PRED (WHERE=(PS\_STRATA NE **.**));

BY PS\_STRATA;

MODEL FNBMD\_C = BISMORE &VARLIST/SOLUTION;

**RUN**;

ODS LISTING;

TITLE 'ESTIMATING TREATMENT EFFECT BY ADJUSTING FOR BASELINE COVARIATES WITHIN EACH STRATA';

**PROC** **MEANS** DATA = SF N MEAN;

CLASS PS\_STRATA;

TYPES PS\_STRATA ();

VAR ESTIMATE;

where effect = 'BISMORE';

**RUN**;