From a63a1c3ba7448cfbc5a3c25654b66f60a7ea957e Mon Sep 17 00:00:00 2001
From: Colin Arnott <colin@urandom.co.uk>
Date: Tue, 1 Nov 2022 14:15:57 +0000
Subject: [PATCH] mgmt: init at unstable-2022-10-24

Fixes #98458
Updates purpleidea/mgmt#610
---
 pkgs/applications/system/mgmt/default.nix | 67 +++++++++++++++++++++++
 pkgs/top-level/all-packages.nix           |  2 +
 2 files changed, 69 insertions(+)
 create mode 100644 pkgs/applications/system/mgmt/default.nix

diff --git a/pkgs/applications/system/mgmt/default.nix b/pkgs/applications/system/mgmt/default.nix
new file mode 100644
index 000000000000000..0bc65dc95052dd4
--- /dev/null
+++ b/pkgs/applications/system/mgmt/default.nix
@@ -0,0 +1,67 @@
+{ augeas
+, buildGoModule
+, fetchFromGitHub
+, gotools
+, lib
+, libvirt
+, libxml2
+, nex
+, pkg-config
+, ragel
+}:
+buildGoModule rec {
+  pname = "mgmt";
+  version = "unstable-2022-10-24";
+
+  src = fetchFromGitHub {
+    owner = "purpleidea";
+    repo = pname;
+    rev = "d8820fa1855668d9e0f7a7829d9dd0d122b2c5a9";
+    hash = "sha256-jurZvEtiaTjWeDkmCJDIFlTzR5EVglfoDxkFgOilo8s=";
+  };
+
+  # patching must be done in prebuild, so it is shared with go-modules
+  # see https://github.com/NixOS/nixpkgs/issues/208036
+  preBuild = ''
+    for file in `find -name Makefile -type f`; do
+      substituteInPlace $file --replace "/usr/bin/env " ""
+    done
+
+    substituteInPlace lang/types/Makefile \
+      --replace "unset GOCACHE && " ""
+    patchShebangs misc/header.sh
+    make lang funcgen
+  '';
+
+  buildInputs = [
+    augeas
+    libvirt
+    libxml2
+  ];
+
+  nativeBuildInputs = [
+    gotools
+    nex
+    pkg-config
+    ragel
+  ];
+
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.program=${pname}"
+    "-X main.version=${version}"
+  ];
+
+  subPackages = [ "." ];
+
+  vendorHash = "sha256-Dtqy4TILN+7JXiHKHDdjzRTsT8jZYG5sPudxhd8znXY=";
+
+  meta = with lib; {
+    description = "Next generation distributed, event-driven, parallel config management!";
+    homepage = "https://mgmtconfig.com";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ urandom ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 0cd90d9f7d9432e..9d34511e2d7b07a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1431,6 +1431,8 @@ with pkgs;
 
   mnc = callPackage ../tools/misc/mnc { };
 
+  mgmt = callPackage ../applications/system/mgmt {};
+
   mprocs = callPackage ../tools/misc/mprocs { };
 
   nominatim = callPackage ../servers/nominatim { };