Centering in Cross Sectional Data

Andy Grogan-Kaylor

24 May 2021 18:09:20

# Background

# Introduction

These notes represent a brief discussion of centering with cross sectional data. Since so much of my current work focuses on cross national work on parenting and child development, I use these ideas as my substantive example.

Consider a cross-national data set where we are attempting to understand predictors of *behavior problems* as a function of *per capita income* and *parental use of physical punishment*.

# Simulate Some Data

Show / Hide Data Simulation Code

. clear all

. set obs 100  
Number of observations (\_N) was 0, now 100.

. generate income = runiform(10000, 70000)

. generate physical\_punishment = rbinomial(1,.3)

. generate country = int(\_n/10) + 1

. generate e = rnormal(0,1) // individual error

. generate u = country - 5 // random intercept

. generate behavior\_problems = 110 + -.0001 \* income + 10 \* physical\_punishment + u + e // plausible regression relationship

. list in 1/10, abb(20) // list out some data  
  
 ┌───────────────────────────────────────────────────────────────────────────────┐  
 │ income physical\_punishment country e u behavior\_problems │  
 ├───────────────────────────────────────────────────────────────────────────────┤  
 1. │ 67330.63 0 1 -.5072625 -4 98.75967 │  
 2. │ 41927 0 1 -1.108992 -4 100.6983 │  
 3. │ 33965.06 0 1 -2.13616 -4 100.4673 │  
 4. │ 28669.77 1 1 -.1319105 -4 113.0011 │  
 5. │ 51365.27 0 1 -1.529223 -4 99.33425 │  
 ├───────────────────────────────────────────────────────────────────────────────┤  
 6. │ 59354.73 1 1 -.890623 -4 109.1739 │  
 7. │ 60771.51 1 1 .1684569 -4 110.0913 │  
 8. │ 16748.94 0 1 -.084422 -4 104.2407 │  
 9. │ 44340.91 0 1 -.778522 -4 100.7874 │  
 10. │ 26909.24 0 2 -.8336996 -3 103.4754 │  
 └───────────────────────────────────────────────────────────────────────────────┘


# Uncentered Data

## Equation

## Graph

. twoway (scatter behavior\_problems income if physical\_punishment ==0) ///  
> (scatter behavior\_problems income if physical\_punishment == 1), ///  
> legend(order(1 "no physical punishment" 2 "physical punishment") pos(6)) ///  
> title("Behavior Problems by Income and Physical Punishment") ///  
> xtitle("Per Capita Income") ///  
> ytitle("Behavior Problems") ///  
> scheme(michigan)

. graph export myscatter.png, width(1000) replace  
file myscatter.png saved as PNG format



Scatterplot

## Multilevel Model

. mixed behavior\_problems income physical\_punishment || country:  
  
Performing EM optimization:   
  
Performing gradient-based optimization:   
  
Iteration 0: log likelihood = -173.11752   
Iteration 1: log likelihood = -173.11752   
  
Computing standard errors:  
  
Mixed-effects ML regression Number of obs = 100  
Group variable: country Number of groups = 11  
 Obs per group:  
 min = 1  
 avg = 9.1  
 max = 10  
 Wald chi2(2) = 1617.44  
Log likelihood = -173.11752 Prob > chi2 = 0.0000  
  
────────────────────┬────────────────────────────────────────────────────────────────  
 behavior\_problems │ Coefficient Std. err. z P>|z| [95% conf. interval]  
────────────────────┼────────────────────────────────────────────────────────────────  
 income │ -.0000968 6.80e-06 -14.23 0.000 -.0001101 -.0000835  
physical\_punishment │ 9.891857 .2486609 39.78 0.000 9.404491 10.37922  
 \_cons │ 110.4318 .9338654 118.25 0.000 108.6014 112.2621  
────────────────────┴────────────────────────────────────────────────────────────────  
  
─────────────────────────────┬────────────────────────────────────────────────  
 Random-effects parameters │ Estimate Std. err. [95% conf. interval]  
─────────────────────────────┼────────────────────────────────────────────────  
country: Identity │  
 var(\_cons) │ 8.44086 3.683582 3.588585 19.8541  
─────────────────────────────┼────────────────────────────────────────────────  
 var(Residual) │ 1.194108 .1789771 .8901489 1.601861  
─────────────────────────────┴────────────────────────────────────────────────  
LR test vs. linear model: chibar2(01) = 161.59 Prob >= chibar2 = 0.0000

We note that -0.968 is the effect of every additional $10,000 of per capita income. 9.892 is the effect of physical punishment. Notably, for this handout, 110.432 is the level of behavior problems for a child who did *not recieve physical punishment* living in a family with **$0** *income*.

# Grand Mean Centering

Grand mean centering helps us to have more meaningful intercepts of our continuous variables.


Essentially, we are going to create

. egen m\_income = mean(income) // grand mean of income

. generate c\_income = income - m\_income // grand mean centered income

. twoway (scatter behavior\_problems c\_income if physical\_punishment ==0) ///  
> (scatter behavior\_problems c\_income if physical\_punishment == 1), ///  
> legend(order(1 "no physical punishment" 2 "physical punishment") pos(6)) ///  
> title("Behavior Problems by Income and Physical Punishment") ///  
> caption("Income is Grand Mean Centered") ///  
> xtitle("Per Capita Income") ///  
> ytitle("Behavior Problems") ///  
> scheme(michigan)

. graph export myscatter2.png, width(1000) replace  
file myscatter2.png saved as PNG format



Scatterplot With Grand Mean Centering

In a graph, we see that *grand mean centering* has transformed the intercept so now the term is the level of behavior problems for the *average* child who did *not recieve physical punishment*.

# Group Mean Centering

In group mean centering, we are doing something slightly different. We are creating a mean for each *group*, which in this data is *country*: , where is the index for *group* or *country*.

. bysort country: egen m\_g\_income = mean(income) // GROUP mean of income

. generate c\_g\_income = income - m\_g\_income // GROUP mean centered income

. bysort country: egen m\_g\_physical\_punishment = mean(physical\_punishment) // GROUP mean of physical punishment

. generate c\_g\_physical\_punishment = physical\_punishment - m\_g\_physical\_punishment // GROUP mean centered physical punishment

## Multilevel Model

Interestingly, *group mean centering* has many implications. Here I focus on how employing different variables might provide *conceptually* or *theoretically* different results. For the sake of parismony, in the brief discussion below I focus on these *conceptual* or *theoretical* differences, and do not provide output. I use the quietly prefix to suppress output.

### Covariate, and Group Mean

One parameterization of the multilevel model is to enter the *covariate* and its *group level mean* i.e. and .

This first parameterization focuses on *individual scores on covariates* and their *country level means*.

What is the effect of *income*, *country level mean income*, *physical punishment* and *country level mean of physical punishment* on *behavior problems*?

. quietly: mixed behavior\_problems income m\_g\_income physical\_punishment m\_g\_physical\_punishment || country:

### Group Mean Centered Covariate, and Group Mean

A second, equally valid, but conceptually different parameterization of the multilevel model is to enter the *covariate deviated from its group level mean* and the *group level mean* i.e. and .

This second parameterization focuses on how *individuals differ from their country level means*, and *country level means*.

What is the effect of *income deviated from its country level mean*, *country level mean income*, *physical punishment deviated from its country level punishment*, and *country level mean of physical punishment* on *behavior problems*?

. quietly: mixed behavior\_problems c\_g\_physical\_punishment m\_g\_income c\_g\_physical\_punishment m\_g\_physical\_punishment || country: