**Граматика мови програмування**

<програма> ::= program <ім’я програми> var <список оголошень> start <список операторів> end

<ім’я програми> ::= <ідентифікатор>

<список оголошень> ::= <оголошення>; | <список оголошень><оголошення>;

<оголошення> ::= <тип> : <список ідентифікаторів>

<тип> ::= int | label

<список ідентифікаторів> ::= <ідентифікатор> | <список ідентифікаторів>, <ідентифікатор>

<список операторів> ::= <оператор>; | <список операторів> <оператор>;

<оператор> ::= <присвоєння> | <введення> | <виведення> | <цикл> | <умовний перехід> | <присвоєння мітки> | <тернарний оператор>

<присвоєння> ::= <ідентифікатор> = <вираз>

<присвоєння мітки> ::= <ідентифікатор> :

<введення> ::= cin <список введення>

<список введення> ::= >> <ідентифікатор> | <список введення> >> <ідентифікатор>

<виведення> ::= cout <список виведення>

<список виведення> ::= << <ідентифікатор> | <список виведення> << <ідентифікатор>

<цикл> ::= for <ідентифікатор> = <вираз> by <вираз> while <відношення> do <оператор>

<умовний перехід> ::= if <відношення> then goto <ідентифікатор>

<тернарний оператор> ::= [<ідентифікатор> = <відношення> ? <вираз> : <вираз>]

<вираз> ::= <термінал> | <вираз> + <термінал> | <вираз> – <термінал> | – <термінал>

<термінал> ::= <множник> | <термінал> \* <множник> | <термінал> / <множник>

<множник> ::= <первинний вираз> | <множник> ↑ <первинний вираз>

<первинний вираз> ::= (<вираз>) | <ідентифікатор> | <константа>

<константа> ::= <цифра> | <константа><цифра>

<ідентифікатор> ::= <буква> | <ідентифікатор> <буква> | <ідентифікатор> <цифра>

<буква> ::= a | b | … | z

<цифра> ::= 0 | 1 | … | 9

<відношення> ::= <вираз> <оператор відношення> <вираз>

<оператор відношення> ::= < | <= | > | >= | == | !=