Rust-Cross-Platform-Development/android-sample/app/build.gradle.kts at main · android10/Rust-Cross-Platform-Development · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
@file:Suppress("UnstableApiUsage")

class AppConfig {
  val id = "com.fernandocejas.sample"
  val javaVersion = JavaVersion.VERSION_17

  val compileSdk = libs.versions.compileSdk.get().toInt()
  val minSdk = libs.versions.minSdk.get().toInt()
  val targetSdk = libs.versions.targetSdk.get().toInt()
}


plugins {
  alias(libs.plugins.android.application)
  alias(libs.plugins.kotlin.android)
}

android {
  val appConfig = AppConfig()

  namespace = appConfig.id
  compileSdk = appConfig.compileSdk

  defaultConfig {
    applicationId = appConfig.id

    minSdk = appConfig.minSdk
    targetSdk = appConfig.targetSdk
    versionCode = 1
    versionName = "1.0"

    testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"

    ndk {
      // Specifies the ABI configurations of your native
      // libraries Gradle should build and package with your APK.
      // Here is a list of supported ABIs:
      // https://developer.android.com/ndk/guides/abis
      abiFilters.addAll(
        setOf(
          "armeabi-v7a",
          "arm64-v8a",
          "x86",
          "x86_64"
        )
      )
    }
  }

  compileOptions {
    sourceCompatibility = appConfig.javaVersion
    targetCompatibility = appConfig.javaVersion
  }

  kotlinOptions {
    jvmTarget = appConfig.javaVersion.toString()
  }

  buildFeatures {
    // https://developer.android.com/jetpack/compose/setup
    compose = true
  }

  composeOptions {
    // https://developer.android.com/jetpack/androidx/releases/compose-kotlin
    kotlinCompilerExtensionVersion = "1.4.8"
  }

  buildTypes {
    getByName("debug") {
      isMinifyEnabled = false
    }
    getByName("release") {
      isMinifyEnabled = true
    }
  }
}

dependencies {
  implementation(libs.kotlin.stdlib.jdk8)
  implementation(libs.kotlinx.coroutines.core)
  implementation(libs.kotlinx.coroutines.android)
  implementation(libs.android.core.ktx)
  implementation(libs.android.appcompat)

  // Jetpack Compose
  //  https://developer.android.com/jetpack/compose/setup#kotlin_1
  val composeBom = platform(libs.androidx.compose.bom)
  implementation(composeBom)
  androidTestImplementation(composeBom)

  // Livedata
  implementation(libs.androidx.compose.runtime.livedata)

  // Material Design 3
  implementation(libs.androidx.compose.material3)
  implementation(libs.androidx.compose.material3.window.size)

  // Compose Activity Integration
  implementation(libs.androidx.activty.compose)

  // Android Studio Preview support
  implementation(libs.androidx.compose.ui.tooling.preview)
  implementation(libs.androidx.compose.ui.tooling)
}