## Léxico

|  |  |  |
| --- | --- | --- |
| Token | Código/Atributo | Observaciones |
| <Tipo> | 0 | Tipos de datos:  int|float|double|string|char|bool |
| <Identificador> | 1 | Identificador de variable o función:  [a-zA-Z\_][a-zA-Z0-9\_]\* |
| <Constante Entera> | 2 | Número constante entero:  [1-9][0-9]\*|0 |
| <Constante Flotante> | 3 | Número constante con decimales:  ([1-9][0-9]\*|0)\.[0-9]+ |
| <Operador Aditivo> | 4 | Operadores de suma y resta:  +|- |
| <Operador Multiplicativo> | 5 | Operadores de multiplicación, división y módulo:  \*|/|% |
| <Operador Relacional> | 6 | Operadores relacionales:  ==|<=|>=|!=|<|> |
| <Operador Lógico> | 7 | Operadores lógicos AND y OR:  &&|\|\| |
| ¡ | 8 | Operador de negación. |
| = | 9 | Operador de asignación. |
| ; | 10 | Separador de sentencia. |
| { | 11 | Apertura de bloque de código. |
| } | 12 | Cierre de bloque de código. |
| ( | 13 | Paréntesis de apertura. |
| ) | 14 | Paréntesis de cierre. |
| , | 15 | Separador de variables y parámetros. |
| if | 16 | Condicional SI. |
| else | 17 | Condicional SI NO. |
| for | 18 | Bucle for. |
| while | 19 | Bucle while. |
| continue | 20 | continue de un bucle. |
| break | 21 | break de un bucle o un switch. |
| switch | 22 | Condicional de casos switch. |
| case | 23 | Prefijo para un caso switch. |
| : | 24 | Sufijo para un caso switch. |
| return | 25 | Retorno de una función. |
| main | 26 | Identificador de la función de arranque inicial. |
| default | 27 | Default de un switch |
| <Cadena> | 28 | Cadena de caracteres entre comillas dobles. |
| <Carácter Constante> | 29 | Carácter entre comillas simples. |
| <Operador Incremento> | 30 | Operadores de incremento ++ y – |
| <Booleano> | 31 | Palabras reservadas true y false. |
| <SASM> | 32 | Funciones para usarse en SASM:  print\_int y newline |

## Gramática

**Reglas base**

1. <Programa> 🡪 <Contenido Global> <Más Contenido Global>
2. <Contenido Global> 🡪 <Declaración> ";" | <Función>
3. <Más Contenido Global> 🡪 <Contenido Global> <Más Contenido Global> | vacío
4. <Bloque> 🡪 "{" <Contenido Bloque> "}"
5. <Contenido Bloque> 🡪 <Sentencia> <Contenido Bloque> | <If> <Contenido Bloque> | <For> <Contenido Bloque> | <While> <Contenido Bloque> | <Switch> <Contenido Bloque> | <Retorno Función> <Contenido Bloque> | vacío
6. <Cuerpo Estructura> 🡪 <Bloque> | <Sentencia> | ";"
7. <Sentencia> 🡪 <Declaración> ";" | <Asignación> ";" | <Expresión> ";" | "break" ";" | "continue" ";"
8. <Declaración> 🡪 <Tipo> <Identificador> <Asignación Declaración> <Declaración Múltiple>
9. <Declaración Múltiple> 🡪 "," <Identificador> <Asignación Declaración> <Declaración Múltiple> | vacío
10. <Asignación Declaración> 🡪 "=" <Expresión> | vacío
11. <Asignación> 🡪 <Identificador> "=" <Expresión>

**Reglas para condicional if**

1. <If> 🡪 "if (" <Expresión> ")" <Cuerpo Estructura> <Else>
2. <Else> 🡪 "else if (" <Expresión> ")" <CuerpoEstructura> <Else> | "else" <Cuerpo Estructura> | <vacío>

**Reglas para bucle for**

1. <For> 🡪 "For (" <Control Variable For> ";" <Control Condicional For> ";" <Incremento For> ")" <Cuerpo Estructura>
2. <Control Variable For> 🡪 <Declaración> | <Asignación> | vacío
3. <Control Condicional For> 🡪 <Expresión> | vacío
4. <Incremento For> 🡪 <Expresión> | <Asignación> | vacío

**Reglas para bucle while**

1. <While> 🡪 "while (" <Expresión> ")" <Cuerpo Estructura>

**Reglas para condicional switch**

1. <Switch> 🡪 "switch (" <Expresión> ")" <Cuerpo Switch>
2. <Cuerpo Switch> 🡪 "{" <Caso Switch> <Más Casos Switch> <Caso Default Switch> "}"
3. <Más Casos Switch> 🡪 <Caso Switch> <Más Casos Switch> | vacío
4. <Caso Switch> 🡪 "case" <Constante Entera> ":" <Contenido Bloque> <Break Switch>
5. <Break Switch> 🡪 "break;" | vacío
6. <Caso Default Switch> 🡪 "default :" <Contenido Bloque> <Break Switch>

**Reglas para funciones**

1. <Función> 🡪 <Tipo> <Identificador> "(" <Parámetro Función> ")" <Bloque>
2. <Parámetro Función> 🡪 <Tipo> <Identificador> <Más Parámetros Función> | vacío
3. <Más Parámetros Función> 🡪 "," <Tipo> <Identificador> <Más Parámetros Función> | vacío
4. <Retorno Función> 🡪 "return" <Expresión> ";" | vacío
5. <Llamada Función> 🡪 <Identificador> "(" <Argumentos Función > ")"
6. <Argumentos Función> 🡪 <Expresión> <Más Argumentos> | vacío
7. <Más Argumentos> 🡪 "," <Expresión> <Más Argumentos> | vacío

**Reglas para expresiones**

1. <Expresión> 🡪 <Expresión Relacional> <Más Expresiones Relacionales>
2. <Expresión Relacional> 🡪 <Expresión Algebraica> <Más Expresiones Algebraicas>
3. <Más Expresiones Relacionales> 🡪 <Operador Lógico> <Expresión Relacional> <Más Expresiones Relacionales> | vacío
4. <Expresión Algebraica> 🡪 <Término> <Más Términos>
5. <Más Expresiones Algebraicas> 🡪 <Operador Relacional> <Expresión Algebraica> <Más Expresiones Algebraicas> | vacío
6. <Término> 🡪 <Factor> <Más Factores> | <Operador Aditivo> <Factor> <Más Factores>
7. <Más Términos> 🡪 <Operador Aditivo> <Término> <Más Términos> | vacío
8. <Factor> 🡪 <Identificador> | <Constante Entera> | <Constante Flotante> | <Cadena> | <Carácter> | "!" <Factor> | <Llamada Función> | <Incremento> | "(" <Expresión> ")" | true | false
9. <Más Factores> 🡪 <Operador Multiplicativo> <Factor> <Más Factores> | Vacío
10. <Incremento> 🡪 <Identificador> <Operador Incremento> | <Operador Incremento> <Identificador>

**Reglas base para tokens**

1. <Número> 🡪 "0" | … | "9"
2. <Tipo> 🡪 "int" | "double" | "float" | "char" | "string" | "bool" | "void"
3. <Letra> 🡪 "a" | … | "z"
4. <Cadena> 🡪 "\"" <Caracteres> "\""
5. <Caracteres> 🡪 <Carácter> <Caracteres> | vacío
6. <Carácter Constante> 🡪 "'" <Caracteres> "'" | vacío
7. <Carácter> 🡪 <\_\_ASCII\_\_>

**Reglas para token identificador**

1. <Identificador> 🡪 <Prefijo Identificador> <Sufijo Identificador>
2. <Prefijo Identificador> 🡪 <Letra> | \_
3. <Sufijo Identificador> 🡪 <Símbolos Sufijo Identificador> <Sufijo Identificador> | vacío
4. <Símbolos Sufijo Identificador> 🡪 <Letra> | <Número> | \_

**Reglas para token constante entera**

1. <Constante Entera> 🡪 <Prefijo Constante Entera> <Sufijo Constante Entera> | 0
2. <Prefijo Constante Entera> 🡪 "1" | … | "9"
3. <Sufijo Constante Entera> 🡪 <Número> <Sufijo Constante Entera> | vacío

**Reglas para token constante flotante**

1. <Constante Flotante> 🡪 <Constante Entera> "." <Decimales>
2. <Decimales> 🡪 <Número> <Decimales> | vacío

**Reglas para tokens de operadores**

1. <Operador Aditivo> 🡪 "+" | "-"
2. <Operador Multiplicativo> 🡪 "\*" | "/" | "%"
3. <Operador Relacional> 🡪 "==" | "<=" | ">=" | "!=" | "<" | ">"
4. <Operador Lógico> 🡪 "&&" | "||"