S -> SUBPROCESO | PROCESO.

SUBPROCESO -> subproceso id SUBPROCESO1.

SUBPROCESO1 -> token\_asig id token\_par\_izq id token\_par\_der SUB | SUBP.

SUB -> definir SUB1.

SUB1 -> ASIGNACION SUBP | CICLO SUB1 | INSTRUCCION SUB1.

SUBP -> ASIGNACION SUBP | CICLO SUBP| INSTRUCCION SUBP | FINSUBPROCESO.

FINSUBPROCESO -> finsubproceso S.

PROCESO -> proceso id PROC | algoritmo id PROC.

PROC -> ASIGNACION PROC |CICLO PROC | INSTRUCCION PROC | FINPROCESO.

FINPROCESO -> finproceso eof | finalgoritmo eof.

INSTRUCCION -> DEFINIR | DIMENSION | ESCRIBIR | LEER | SI.

SI -> si IF0.

IF -> ASIGNACION IF |CICLO IF | INSTRUCCION IF | sino IF1 | finsi.

IF0 -> EXPRESION entonces IF.

IF1 -> ASIGNACION IF1 |CICLO IF1 | INSTRUCCION IF1 | finsi.

LEER -> leer id LEER1.

LEER1 -> id token\_coma LEER1 | LEE.

LEE -> token\_pyc.

ESCRIBIR -> escribir ESCRIBIR1.

ESCRIBIR1 -> token\_cadena ESC\_C | EXPRESION ESC\_C.

ESC\_C -> token\_coma ESCRIBIR1 | token\_pyc.

DIMENSION -> dimension id token\_cor\_izq DIM.

DIM -> EXPRESION DIMENSION1.

DIMENSION1 -> token\_coma DIM | token\_cor\_der token pyc.

DEFINIR -> definir id DEFINIR1.

DEFINIR1 -> como DEF| token\_coma id DEFINIR1.

DEF -> entero token\_pyc | real token\_pyc | texto token\_pyc | numerico token\_pyc | numero token\_pyc | caracter token\_pyc | logico token\_pyc | cadena token\_pyc.

ASIGNACION -> id token\_asig ASIGNACION1.

ASIGNACION1 -> token\_cadena token\_pyc | EXPRESION.

CICLO -> para EXPRESION hasta CIC | mientras EXPRESION hacer MIEN | repetir REP | segun EXPRESION hacer SEG.

CIC -> EXPRESION CIC0.

CIC0 -> hacer | con paso EXPRESION hacer | CIC1.

CIC1 -> ASIGNACION CIC1 |CICLO CIC1 | INSTRUCCION CIC1 | finpara.

MIEN -> ASIGNACION MIEN |CICLO MIEN | INSTRUCCION MIEN | finmientras.

REP -> ASIGNACION REP |CICLO REP | INSTRUCCION REP | hasta que EXPRESION.

SEG -> caso EXPRESION token\_dosp SEG1 | finsegun.

SEG1 -> ASIGNACION SEG1 |CICLO SEG1 | INSTRUCCION SEG1 | caso EXPRESION token\_dosp SEG1 | de otro modo token\_dosp SEG2 | finsegun.

SEG2 -> ASIGNACION SEG2 |CICLO SEG2 | INSTRUCCION SEG2 | finsegun.

EXPRESION -> F EXPRESION\_P.

EXPRESION\_P -> token\_asig F EXPRESION\_P | .

F -> G F\_P.

F\_P -> token\_o G F\_P | .

G -> H G\_P.

G\_P -> token\_y H G\_P | .

H -> I H\_P.

H\_P -> H1 H\_P | .

H1 -> token\_igual I | token\_dif I.

I -> J I\_P.

I\_P -> I1 I\_P | .

I1 -> token\_mayor J | token\_menor J | token\_menor\_igual J | token\_mayor\_igual J.

J -> token\_neg K | K.

K -> L K\_P.

K\_P -> K1 K\_P | .

K1 -> token\_mas L | token\_menos L.

L -> M L\_P.

L\_P -> L1 L\_P | .

L1 -> token\_div M | token\_mul M | token\_mod M.

M -> N M\_P.

M\_P -> token\_pot N M\_P | .

N -> token\_par\_izq EXPRESION token\_par\_der | id INST| token\_entero | token\_real | verdadero | falso.

INST -> token\_pyc | token\_par\_izq INST1.

INST1 -> token\_par\_der token\_pyc | EXPRESION token\_par\_der token\_pyc.