Skip to content

HTTPS clone URL

Subversion checkout URL

You can clone with
or
.
Download ZIP
Browse files

-a

initial commit
  • Loading branch information...
commit 05abdb13f45133d12cafd48c9da2eb04e8f0acd6 0 parents
@anzaika authored
1  ftdetect/gofiletype.vim
@@ -0,0 +1 @@
+au BufRead,BufNewFile *.go set filetype=go
201 ftplugin/go/import.vim
@@ -0,0 +1,201 @@
+" Copyright 2011 The Go Authors. All rights reserved.
+" Use of this source code is governed by a BSD-style
+" license that can be found in the LICENSE file.
+"
+" import.vim: Vim commands to import/drop Go packages.
+"
+" This filetype plugin adds three new commands for go buffers:
+"
+" :Import {path}
+"
+" Import ensures that the provided package {path} is imported
+" in the current Go buffer, using proper style and ordering.
+" If {path} is already being imported, an error will be
+" displayed and the buffer will be untouched.
+"
+" :ImportAs {localname} {path}
+"
+" Same as Import, but uses a custom local name for the package.
+"
+" :Drop {path}
+"
+" Remove the import line for the provided package {path}, if
+" present in the current Go buffer. If {path} is not being
+" imported, an error will be displayed and the buffer will be
+" untouched.
+"
+" In addition to these commands, there are also two shortcuts mapped:
+"
+" \f - Runs :Import fmt
+" \F - Runs :Drop fmt
+"
+" The backslash is the default maplocalleader, so it is possible that
+" your vim is set to use a different character (:help maplocalleader).
+"
+if exists("b:did_ftplugin")
+ finish
+endif
+
+command! -buffer -nargs=? Drop call s:SwitchImport(0, '', <f-args>)
+command! -buffer -nargs=1 Import call s:SwitchImport(1, '', <f-args>)
+command! -buffer -nargs=* ImportAs call s:SwitchImport(1, <f-args>)
+map <buffer> <LocalLeader>f :Import fmt<CR>
+map <buffer> <LocalLeader>F :Drop fmt<CR>
+
+function! s:SwitchImport(enabled, localname, path)
+ let view = winsaveview()
+ let path = a:path
+
+ " Quotes are not necessary, so remove them if provided.
+ if path[0] == '"'
+ let path = strpart(path, 1)
+ endif
+ if path[len(path)-1] == '"'
+ let path = strpart(path, 0, len(path) - 1)
+ endif
+ if path == ''
+ call s:Error('Import path not provided')
+ return
+ endif
+
+ let qpath = '"' . path . '"'
+ if a:localname != ''
+ let qlocalpath = a:localname . ' ' . qpath
+ else
+ let qlocalpath = qpath
+ endif
+ let indentstr = 0
+ let packageline = -1 " Position of package name statement
+ let appendline = -1 " Position to introduce new import
+ let deleteline = -1 " Position of line with existing import
+ let linesdelta = 0 " Lines added/removed
+
+ " Find proper place to add/remove import.
+ let line = 0
+ while line <= line('$')
+ let linestr = getline(line)
+
+ if linestr =~# '^package\s'
+ let packageline = line
+ let appendline = line
+
+ elseif linestr =~# '^import\s\+('
+ let appendstr = qlocalpath
+ let indentstr = 1
+ let appendline = line
+ while line <= line("$")
+ let line = line + 1
+ let linestr = getline(line)
+ let m = matchlist(getline(line), '^\()\|\(\s\+\)\(\S*\s*\)"\(.\+\)"\)')
+ if empty(m)
+ continue
+ endif
+ if m[1] == ')'
+ break
+ endif
+ if a:localname != '' && m[3] != ''
+ let qlocalpath = printf('%-' . (len(m[3])-1) . 's %s', a:localname, qpath)
+ endif
+ let appendstr = m[2] . qlocalpath
+ let indentstr = 0
+ if m[4] == path
+ let appendline = -1
+ let deleteline = line
+ break
+ elseif m[4] < path
+ let appendline = line
+ endif
+ endwhile
+ break
+
+ elseif linestr =~# '^import '
+ if appendline == packageline
+ let appendstr = 'import ' . qlocalpath
+ let appendline = line - 1
+ endif
+ let m = matchlist(linestr, '^import\(\s\+\)\(\S*\s*\)"\(.\+\)"')
+ if !empty(m)
+ if m[3] == path
+ let appendline = -1
+ let deleteline = line
+ break
+ endif
+ if m[3] < path
+ let appendline = line
+ endif
+ if a:localname != '' && m[2] != ''
+ let qlocalpath = printf("%s %" . len(m[2])-1 . "s", a:localname, qpath)
+ endif
+ let appendstr = 'import' . m[1] . qlocalpath
+ endif
+
+ elseif linestr =~# '^\(var\|const\|type\|func\)\>'
+ break
+
+ endif
+ let line = line + 1
+ endwhile
+
+ " Append or remove the package import, as requested.
+ if a:enabled
+ if deleteline != -1
+ call s:Error(qpath . ' already being imported')
+ elseif appendline == -1
+ call s:Error('No package line found')
+ else
+ if appendline == packageline
+ call append(appendline + 0, '')
+ call append(appendline + 1, 'import (')
+ call append(appendline + 2, ')')
+ let appendline += 2
+ let linesdelta += 3
+ let appendstr = qlocalpath
+ let indentstr = 1
+ endif
+ call append(appendline, appendstr)
+ execute appendline + 1
+ if indentstr
+ execute 'normal >>'
+ endif
+ let linesdelta += 1
+ endif
+ else
+ if deleteline == -1
+ call s:Error(qpath . ' not being imported')
+ else
+ execute deleteline . 'd'
+ let linesdelta -= 1
+
+ if getline(deleteline-1) =~# '^import\s\+(' && getline(deleteline) =~# '^)'
+ " Delete empty import block
+ let deleteline -= 1
+ execute deleteline . "d"
+ execute deleteline . "d"
+ let linesdelta -= 2
+ endif
+
+ if getline(deleteline) == '' && getline(deleteline - 1) == ''
+ " Delete spacing for removed line too.
+ execute deleteline . "d"
+ let linesdelta -= 1
+ endif
+ endif
+ endif
+
+ " Adjust view for any changes.
+ let view.lnum += linesdelta
+ let view.topline += linesdelta
+ if view.topline < 0
+ let view.topline = 0
+ endif
+
+ " Put buffer back where it was.
+ call winrestview(view)
+
+endfunction
+
+function! s:Error(s)
+ echohl Error | echo a:s | echohl None
+endfunction
+
+" vim:ts=4:sw=4:et
37 readme.txt
@@ -0,0 +1,37 @@
+Vim syntax highlighting for Go (http://golang.org)
+==================================================
+
+To install automatic syntax highlighting for GO programs:
+
+ 1. Copy or link the filetype detection script to the ftdetect directory
+ underneath your vim runtime directory (normally $HOME/.vim/ftdetect)
+ 2. Copy or link syntax/go.vim to the syntax directory underneath your vim
+ runtime directory (normally $HOME/.vim/syntax). Linking this file rather
+ than just copying it will ensure any changes are automatically reflected
+ in your syntax highlighting.
+ 3. Add the following line to your .vimrc file (normally $HOME/.vimrc):
+
+ syntax on
+
+In a typical unix environment you might accomplish this using the following
+commands:
+
+ mkdir -p $HOME/.vim/ftdetect
+ mkdir -p $HOME/.vim/syntax
+ ln -s $GOROOT/misc/vim/ftdetect/gofiletype.vim $HOME/.vim/ftdetect/
+ ln -s $GOROOT/misc/vim/syntax/go.vim $HOME/.vim/syntax
+ echo "syntax on" >> $HOME/.vimrc
+
+
+Vim filetype plugins for Go
+===========================
+
+To install one of the available filetype plugins for Go:
+
+ 1. Same as 1 above.
+ 2. Copy or link one or more plugins from ftplugin/go/*.vim to the
+ Go-specific ftplugin directory underneath your vim runtime directory
+ (normally $HOME/.vim/ftplugin/go/*.vim).
+ 3. Add the following line to your .vimrc file (normally $HOME/.vimrc):
+
+ filetype plugin on
208 syntax/go.vim
@@ -0,0 +1,208 @@
+" Copyright 2009 The Go Authors. All rights reserved.
+" Use of this source code is governed by a BSD-style
+" license that can be found in the LICENSE file.
+"
+" go.vim: Vim syntax file for Go.
+"
+" Options:
+" There are some options for customizing the highlighting; the recommended
+" settings are the default values, but you can write:
+" let OPTION_NAME = 0
+" in your ~/.vimrc file to disable particular options. You can also write:
+" let OPTION_NAME = 1
+" to enable particular options. At present, all options default to on.
+"
+" - go_highlight_array_whitespace_error
+" Highlights white space after "[]".
+" - go_highlight_chan_whitespace_error
+" Highlights white space around the communications operator that don't follow
+" the standard style.
+" - go_highlight_extra_types
+" Highlights commonly used library types (os.Error, etc.).
+" - go_highlight_space_tab_error
+" Highlights instances of tabs following spaces.
+" - go_highlight_trailing_whitespace_error
+" Highlights trailing white space.
+
+" Quit when a (custom) syntax file was already loaded
+if exists("b:current_syntax")
+ finish
+endif
+
+if !exists("go_highlight_array_whitespace_error")
+ let go_highlight_array_whitespace_error = 1
+endif
+if !exists("go_highlight_chan_whitespace_error")
+ let go_highlight_chan_whitespace_error = 1
+endif
+if !exists("go_highlight_extra_types")
+ let go_highlight_extra_types = 1
+endif
+if !exists("go_highlight_space_tab_error")
+ let go_highlight_space_tab_error = 1
+endif
+if !exists("go_highlight_trailing_whitespace_error")
+ let go_highlight_trailing_whitespace_error = 1
+endif
+
+syn case match
+
+syn keyword goDirective package import
+syn keyword goDeclaration var const type
+syn keyword goDeclType struct interface
+
+hi def link goDirective Statement
+hi def link goDeclaration Keyword
+hi def link goDeclType Keyword
+
+" Keywords within functions
+syn keyword goStatement defer go goto return break continue fallthrough
+syn keyword goConditional if else switch select
+syn keyword goLabel case default
+syn keyword goRepeat for range
+
+hi def link goStatement Statement
+hi def link goConditional Conditional
+hi def link goLabel Label
+hi def link goRepeat Repeat
+
+" Predefined types
+syn keyword goType chan map bool string
+syn keyword goSignedInts int int8 int16 int32 int64
+syn keyword goUnsignedInts byte uint uint8 uint16 uint32 uint64 uintptr
+syn keyword goFloats float32 float64
+syn keyword goComplexes complex64 complex128
+
+hi def link goType Type
+hi def link goSignedInts Type
+hi def link goUnsignedInts Type
+hi def link goFloats Type
+hi def link goComplexes Type
+
+" Treat func specially: it's a declaration at the start of a line, but a type
+" elsewhere. Order matters here.
+syn match goType /\<func\>/
+syn match goDeclaration /^func\>/
+
+" Predefined functions and values
+syn keyword goBuiltins append cap close closed complex copy imag len
+syn keyword goBuiltins make new panic print println real recover
+syn keyword goConstants iota true false nil
+
+hi def link goBuiltins Keyword
+hi def link goConstants Keyword
+
+" Comments; their contents
+syn keyword goTodo contained TODO FIXME XXX BUG
+syn cluster goCommentGroup contains=goTodo
+syn region goComment start="/\*" end="\*/" contains=@goCommentGroup,@Spell
+syn region goComment start="//" end="$" contains=@goCommentGroup,@Spell
+
+hi def link goComment Comment
+hi def link goTodo Todo
+
+" Go escapes
+syn match goEscapeOctal display contained "\\[0-7]\{3}"
+syn match goEscapeC display contained +\\[abfnrtv\\'"]+
+syn match goEscapeX display contained "\\x\x\{2}"
+syn match goEscapeU display contained "\\u\x\{4}"
+syn match goEscapeBigU display contained "\\U\x\{8}"
+syn match goEscapeError display contained +\\[^0-7xuUabfnrtv\\'"]+
+
+hi def link goEscapeOctal goSpecialString
+hi def link goEscapeC goSpecialString
+hi def link goEscapeX goSpecialString
+hi def link goEscapeU goSpecialString
+hi def link goEscapeBigU goSpecialString
+hi def link goSpecialString Special
+hi def link goEscapeError Error
+
+" Strings and their contents
+syn cluster goStringGroup contains=goEscapeOctal,goEscapeC,goEscapeX,goEscapeU,goEscapeBigU,goEscapeError
+syn region goString start=+"+ skip=+\\\\\|\\"+ end=+"+ contains=@goStringGroup
+syn region goRawString start=+`+ end=+`+
+
+hi def link goString String
+hi def link goRawString String
+
+" Characters; their contents
+syn cluster goCharacterGroup contains=goEscapeOctal,goEscapeC,goEscapeX,goEscapeU,goEscapeBigU
+syn region goCharacter start=+'+ skip=+\\\\\|\\'+ end=+'+ contains=@goCharacterGroup
+
+hi def link goCharacter Character
+
+" Regions
+syn region goBlock start="{" end="}" transparent fold
+syn region goParen start='(' end=')' transparent
+
+" Integers
+syn match goDecimalInt "\<\d\+\([Ee]\d\+\)\?\>"
+syn match goHexadecimalInt "\<0x\x\+\>"
+syn match goOctalInt "\<0\o\+\>"
+syn match goOctalError "\<0\o*[89]\d*\>"
+
+hi def link goDecimalInt Integer
+hi def link goHexadecimalInt Integer
+hi def link goOctalInt Integer
+hi def link Integer Number
+
+" Floating point
+syn match goFloat "\<\d\+\.\d*\([Ee][-+]\d\+\)\?\>"
+syn match goFloat "\<\.\d\+\([Ee][-+]\d\+\)\?\>"
+syn match goFloat "\<\d\+[Ee][-+]\d\+\>"
+
+hi def link goFloat Float
+
+" Imaginary literals
+syn match goImaginary "\<\d\+i\>"
+syn match goImaginary "\<\d\+\.\d*\([Ee][-+]\d\+\)\?i\>"
+syn match goImaginary "\<\.\d\+\([Ee][-+]\d\+\)\?i\>"
+syn match goImaginary "\<\d\+[Ee][-+]\d\+i\>"
+
+hi def link goImaginary Number
+
+" Spaces after "[]"
+if go_highlight_array_whitespace_error != 0
+ syn match goSpaceError display "\(\[\]\)\@<=\s\+"
+endif
+
+" Spacing errors around the 'chan' keyword
+if go_highlight_chan_whitespace_error != 0
+ " receive-only annotation on chan type
+ syn match goSpaceError display "\(<-\)\@<=\s\+\(chan\>\)\@="
+ " send-only annotation on chan type
+ syn match goSpaceError display "\(\<chan\)\@<=\s\+\(<-\)\@="
+ " value-ignoring receives in a few contexts
+ syn match goSpaceError display "\(\(^\|[={(,;]\)\s*<-\)\@<=\s\+"
+endif
+
+" Extra types commonly seen
+if go_highlight_extra_types != 0
+ syn match goExtraType /\<bytes\.\(Buffer\)\>/
+ syn match goExtraType /\<io\.\(Reader\|Writer\|ReadWriter\|ReadWriteCloser\)\>/
+ syn match goExtraType /\<\(os\.Error\)\>/
+ syn match goExtraType /\<reflect\.\w*\(Type\|Value\)\>/
+ syn match goExtraType /\<unsafe\.Pointer\>/
+endif
+
+" Space-tab error
+if go_highlight_space_tab_error != 0
+ syn match goSpaceError display " \+\t"me=e-1
+endif
+
+" Trailing white space error
+if go_highlight_trailing_whitespace_error != 0
+ syn match goSpaceError display excludenl "\s\+$"
+endif
+
+hi def link goExtraType Type
+hi def link goSpaceError Error
+
+" Search backwards for a global declaration to start processing the syntax.
+"syn sync match goSync grouphere NONE /^\(const\|var\|type\|func\)\>/
+
+" There's a bug in the implementation of grouphere. For now, use the
+" following as a more expensive/less precise workaround.
+syn sync minlines=500
+
+let b:current_syntax = "go"

0 comments on commit 05abdb1

Please sign in to comment.
Something went wrong with that request. Please try again.