Readonly Transaction being committed

[mburak]

Even when a controller method has the Transactional(readOnly = true) annotation, the object is being updated.

This is how the method looks like:

@Transactional(readOnly = true)
def validate(Club club) {
    club.validate()

    respond club
}

and doing this call:

echo '{"id": -6934245603440287743, "name": "FC Bayern Münchenn"}' | http PUT http://localhost:8080/neo4j-app/clubs/-6934245603440287743/validate

it updates the club's name even when the method is readonly.

It looks that it's not considering the @transactional(readOnly = true) on binding, just it is when entering the method.

[graemerocher]

So there is no readOnly state in Neo4j transactions, the only thing we can do is roll back the transaction if there is a readOnly transaction defined

[mburak]

Aren't you already doing that? Because if I do the binding manually inside the method it works fine and it doesn't update the object.
The issue only happens when I leave the binding to Grails.

[graemerocher]

This is an issue with the binding logic. In order to pass club to method Grails will call Club.get(params.id). This happens prior to the read-only transaction starting, hence it becomes writable. The binding logic needs to be made @Transactional aware, but that is a problem in Grails core not in GORM itself. /cc @jeffbrown

[jeffscottbrown]

@mburak Can you provide a simple sample app which shows one action that uses the auto-binding and one that uses manual binding which demonstrated different behaviors? I am having trouble recreating the behavior with Hibernate and the latest 2.5.x code.

[mburak]

Sure @jeffbrown , you can download it from http://github.com/mburak/neo4j-app. There's two actions in ClubController. One is validate that has auto-binding and the other is validateManualBinding that uses manual binding. I am testing it using httpie and doing this kind of call:
echo '{"id": -6934245603440287743, "name": "FC Bayern Münchenn"}' | http PUT http://localhost:8080/neo4j-app/clubs/-6934245603440287743/validate
You need to replace the id with the one it generates for you for any club. Then when you do that call it will update the club's name. If you doing with validateManualBinding it won't.

[jeffscottbrown]

I am seeing different behavior with hibernate. The project at https://github.com/jeffbrown/txdemo contains the following:

package demo

import grails.transaction.Transactional

@Transactional
class DemoController {

    def create(Person p) {
        p.save()
        respond p
    }

    def show(Person p) {
        respond p
    }

    def autoBind(Person p) {
        respond p
    }

    def manualBind() {
        Person p = Person.get(params.id)
        p.properties = request
        respond p
    }

    @Transactional(readOnly=true)
    def autoBindReadOnly(Person p) {
        respond p
    }

    @Transactional(readOnly=true)
    def manualBindReadOnly() {
        Person p = Person.get(params.id)
        p.properties = request
        respond p
    }
}

The read-only nature of the transactions appears to be respected:

~ $ curl http://localhost:8080/txdemo/demo/show/1.json
{"class":"demo.Person","id":1,"name":"Jeff"}
~ $ 
~ $ curl -X PUT -H "Content-Type: application/json" -d '{"name":"First New Name"}' http://localhost:8080/txdemo/demo/autoBind/1.json
{"class":"demo.Person","id":1,"name":"First New Name"}
~ $ 
~ $ curl http://localhost:8080/txdemo/demo/show/1.json
{"class":"demo.Person","id":1,"name":"First New Name"}
~ $ 
~ $ curl -X PUT -H "Content-Type: application/json" -d '{"name":"Second New Name"}' http://localhost:8080/txdemo/demo/manualBind/1.json
{"class":"demo.Person","id":1,"name":"Second New Name"}
~ $ 
~ $ curl http://localhost:8080/txdemo/demo/show/1.json
{"class":"demo.Person","id":1,"name":"Second New Name"}
~ $ 
~ $ curl -X PUT -H "Content-Type: application/json" -d '{"name":"Third New Name"}' http://localhost:8080/txdemo/demo/autoBindReadOnly/1.json
{"class":"demo.Person","id":1,"name":"Third New Name"}
~ $ 
~ $ curl http://localhost:8080/txdemo/demo/show/1.json
{"class":"demo.Person","id":1,"name":"Second New Name"}
~ $ 
~ $ curl -X PUT -H "Content-Type: application/json" -d '{"name":"Fourth New Name"}' http://localhost:8080/txdemo/demo/manualBindReadOnly/1.json
{"class":"demo.Person","id":1,"name":"Fourth New Name"}
~ $ 
~ $ curl http://localhost:8080/txdemo/demo/show/1.json
{"class":"demo.Person","id":1,"name":"Second New Name"}
~ $ 

The project contains the following test which passes:

package demo

import grails.test.mixin.TestFor
import grails.test.mixin.TestMixin
import grails.test.mixin.hibernate.HibernateTestMixin
import spock.lang.Specification
import spock.lang.Stepwise

/**
 * See the API for {@link grails.test.mixin.web.ControllerUnitTestMixin} for usage instructions
 */
@TestFor(DemoController)
@TestMixin(HibernateTestMixin)
@Stepwise
class DemoControllerSpec extends Specification {

    void setupSpec() {
        hibernateDomain([Person])
    }

    void "test creating person"() {
        when:
        request.addHeader 'Accept', 'application/json'
        request.method = 'POST'
        request.json = '{"name":"original name"}'
        controller.create()

        then:
        response.status == 200
        response.text.contains '"original name"'
    }

    void "test retrieving person"() {
        when:
        request.addHeader 'Accept', 'application/json'
        params.id = 1
        controller.show()

        then:
        response.status == 200
        response.text.contains '"original name"'
    }

    void "test auto bind"() {
        when:
        request.addHeader 'Accept', 'application/json'
        request.method = 'PUT'
        request.json = '{"name":"first new name"}'
        params.id = 1
        controller.autoBind()

        then:
        response.status == 200
        response.text.contains '"first new name"'
    }

    void "test retrieving person after auto bind"() {
        when:
        request.addHeader 'Accept', 'application/json'
        params.id = 1
        controller.show()

        then:
        response.status == 200
        response.text.contains '"first new name"'
    }

    void "test manual bind"() {
        when:
        request.addHeader 'Accept', 'application/json'
        request.method = 'PUT'
        request.json = '{"name":"second new name"}'
        params.id = 1
        controller.manualBind()

        then:
        response.status == 200
        response.text.contains '"second new name"'
    }

    void "test retrieving person after manual bind"() {
        when:
        request.addHeader 'Accept', 'application/json'
        params.id = 1
        controller.show()

        then:
        response.status == 200
        response.text.contains '"second new name"'
    }

    void "test manual bind read only"() {
        when:
        request.addHeader 'Accept', 'application/json'
        request.method = 'PUT'
        request.json = '{"name":"third new name"}'
        params.id = 1
        controller.manualBindReadOnly()

        then:
        response.status == 200
        response.text.contains '"third new name"'
    }

    void "test retrieving person after manual bind read only"() {
        when:
        request.addHeader 'Accept', 'application/json'
        params.id = 1
        controller.show()

        then:
        response.status == 200
        response.text.contains '"second new name"'
    }

    void "test auto bind read only"() {
        when:
        request.addHeader 'Accept', 'application/json'
        request.method = 'PUT'
        request.json = '{"name":"fourth new name"}'
        params.id = 1
        controller.autoBindReadOnly()

        then:
        response.status == 200
        response.text.contains '"fourth new name"'
    }

    void "test retrieving person after auto bind read only"() {
        when:
        request.addHeader 'Accept', 'application/json'
        params.id = 1
        controller.show()

        then:
        response.status == 200
        response.text.contains '"second new name"'
    }
}

We will figure out why this behaves differently for neo4j.

[jeffscottbrown]

I thought the issue here might be the fact that the query was happening in the no-arg method that we generate at compile time and then passing that object into the method that is defined in the source code. I have tested with a version of our code that moves the query into the original method, and I am seeing the same behavior:

neo4j-app master $ curl http://localhost:8080/neo4j-app/clubs/-6663955238840057856
{"class":"app.Club","id":-6663955238840057856,"country":null,"dateCreated":"2016-02-24T19:10:37Z","lastUpdated":"2016-02-24T19:10:37Z","league":{"class":"app.League","id":-6663955238840066048},"name":"Bayer 04 Leverkusen","players":[{"class":"app.Player","id":-6663955238840057855},{"class":"app.Player","id":-6663955238840057854},{"class":"app.Player","id":-6663955238840057853}]}neo4j-app master $ 
neo4j-app master $ 
neo4j-app master $ 
neo4j-app master $ curl -X PUT -H "Content-Type: application/json" -d '{"name":"First Update"}' http://localhost:8080/neo4j-app/clubs/-6663955238840057856/validateManualBinding
{"class":"app.Club","id":-6663955238840057856,"country":null,"dateCreated":"2016-02-24T19:10:37Z","lastUpdated":"2016-02-24T19:10:37Z","league":{"class":"app.League","id":-6663955238840066048},"name":"First Update","players":[{"class":"app.Player","id":-6663955238840057855},{"class":"app.Player","id":-6663955238840057854},{"class":"app.Player","id":-6663955238840057853}]}neo4j-app master $ 
neo4j-app master $ 
neo4j-app master $ curl http://localhost:8080/neo4j-app/clubs/-6663955238840057856
{"class":"app.Club","id":-6663955238840057856,"country":null,"dateCreated":"2016-02-24T19:10:37Z","lastUpdated":"2016-02-24T19:10:37Z","league":{"class":"app.League","id":-6663955238840066048},"name":"Bayer 04 Leverkusen","players":[{"class":"app.Player","id":-6663955238840057855},{"class":"app.Player","id":-6663955238840057854},{"class":"app.Player","id":-6663955238840057853}]}neo4j-app master $ 
neo4j-app master $ 
neo4j-app master $ curl -X PUT -H "Content-Type: application/json" -d '{"name":"Second Update"}' http://localhost:8080/neo4j-app/clubs/-6663955238840057856/validate
{"class":"app.Club","id":-6663955238840057856,"country":null,"dateCreated":"2016-02-24T19:10:37Z","lastUpdated":"2016-02-24T19:10:37Z","league":{"class":"app.League","id":-6663955238840066048},"name":"Second Update","players":[{"class":"app.Player","id":-6663955238840057855},{"class":"app.Player","id":-6663955238840057853},{"class":"app.Player","id":-6663955238840057854}]}neo4j-app master $ 
neo4j-app master $ 
neo4j-app master $ curl http://localhost:8080/neo4j-app/clubs/-6663955238840057856
{"class":"app.Club","id":-6663955238840057856,"country":null,"dateCreated":"2016-02-24T19:10:37Z","lastUpdated":"2016-02-24T19:10:37Z","league":{"class":"app.League","id":-6663955238840066048},"name":"Second Update","players":[{"class":"app.Player","id":-6663955238840057855},{"class":"app.Player","id":-6663955238840057853},{"class":"app.Player","id":-6663955238840057854}]}

Still investigating.

[jeffscottbrown]

I think I see the issue now. Will work toward a solution.

[jeffscottbrown]

@mburak This may be resolved in the latest 2.5.4.BUILD-SNAPSHOT. Are you setup to be able to test that and provide feedback?