Permalink
Switch branches/tags
Nothing to show
Find file Copy path
Fetching contributors…
Cannot retrieve contributors at this time
72 lines (60 sloc) 1.96 KB
# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Eric Bélanger <eric@archlinux.org>
# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
# - do not use LLINT assembly for v5/v6
highmem=1
pkgname=webkit2gtk
pkgver=2.20.3
pkgrel=1
pkgdesc="GTK+ Web content engine library"
arch=(x86_64)
url="https://webkitgtk.org/"
license=(custom)
depends=(libxt libxslt enchant geoclue2 gst-plugins-base-libs
libsecret libwebp harfbuzz-icu gtk3 libnotify hyphen woff2)
makedepends=(gtk2 gperf gobject-introspection ruby gtk-doc cmake python python2 ninja)
optdepends=('gtk2: Netscape plugin support'
'gst-plugins-base: free media decoding'
'gst-plugins-good: media decoding'
'gst-libav: nonfree media decoding')
source=(https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz{,.asc})
sha256sums=('579b307d78fa16a73f112790178022166d7ad17d4147492ced9b9fba48f20dd8'
'SKIP')
validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3')
prepare() {
mkdir build
cd webkitgtk-$pkgver
sed -i '1s/python$/&2/' Tools/gtk/generate-gtkdoc
}
build() {
cd build
# do not use LLINT assembly for v5/v6
[[ $CARCH == "arm" || $CARCH == "armv6h" ]] && CONFIG="-DENABLE_JIT=OFF"
cmake ../webkitgtk-$pkgver -G Ninja \
-DPORT=GTK \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_SKIP_RPATH=ON \
-DENABLE_GTKDOC=ON \
-DLIBEXEC_INSTALL_DIR=/usr/lib \
-DLIB_INSTALL_DIR=/usr/lib \
-DPYTHON_EXECUTABLE=/usr/bin/python2 \
$CONFIG
cmake --build .
}
check() {
: # cmake --build build --target tests
}
package() {
DESTDIR="$pkgdir" cmake --build build --target install
cd webkitgtk-$pkgver
find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
while IFS= read -d $'\0' -r _f; do
echo "### $_f ###"
cat "$_f"
echo
done |
install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set sw=2 et: