Integration with EmonCMS Input REST API

[chaveiro]

I'm requesting the option to have a Tasmota driver to POST data directly to an EmonCMS server via the REST API, without needing a MQTT server.

It will be useful for instance for converting energy meter devices (like DDS238) to Tasmota and talk to emoncms directly.
Devicekey , server and post interval (30secs default) would be the only settings needed to configure at the device,.
All the variables that the device has available are sent as JSON to EmonCMS input API for further processing on the EmonCMS platform.

Example API format:
https://server/input/post.json?devicekey=SECRET&node=MACADDRESS&json={"var1":100,"var2":200,"var3":300}

Could this be an easy accomplishment?

Edit: done see below.
Further discussion here https://community.openenergymonitor.org/t/tasmota-integration-with-emoncms-input-rest-api/16997/3

[barbudor]

Https is unlikely to be supported on Esp8266 due to the limited capacities of the processor
http can already be performed with Websend command.
Have you tried it?

[sfromis]

Since MQTT support seems to exist for EmonCMS, this would be the better method for connecting.

[chaveiro]

Http is fine. This would be an alternative option to mqtt as mqtt server is optional for emoncms.

[barbudor]

So everything is already there. Just add some rules 👍

[chaveiro]

Answering my self, this is how i've archived posting directly to EmonCMS on a Hiking DDS238-2 WIFI:

Basic settings:

{"NAME":"Hiking DDS238-2 WIFI","GPIO":[0,2272,0,2304,0,0,0,0,0,0,320,0,32,0],"FLAG":0,"BASE":54}

Backlog TuyaMCU 33,20; TuyaMCU 32,18; TuyaMCU 31,19;  TuyaMCU 37,101;
Backlog SetOption72 1; VoltRes 1; WattRes 1;

Rule1 
  ON System#Init DO backlog tuyasend1 1,1; RuleTimer1 5 ENDON 
  ON Rules#Timer=1 DO backlog TuyaSend8; RuleTimer1 5 ENDON

Rule2 
ON energy#power DO Var3 %value% ENDON
ON energy#voltage DO Var1 %value% ENDON
ON energy#total DO Var4 %value% ENDON
ON energy#apparentpower DO Var5 %value% ENDON
ON energy#reactivepower DO Var6 %value% ENDON
ON energy#Factor DO Var7 %value% ENDON
ON energy#Today DO Var8 %value% ENDON
ON energy#Yesterday DO Var9 %value% ENDON
ON energy#current DO Var2 %value% ENDON
ON Wifi#Connected DO backlog buzzer 2,1,1; RuleTimer2 5 ENDON 
ON Wifi#Disconnected DO backlog buzzer 1,3,1; RuleTimer2 0 ENDON 
ON Rules#Timer=2 DO backlog event SENDEMON; RuleTimer2 5 ENDON
ON event#SENDEMON DO WEBSEND [emon.server.com:80] /input/post.json?node=PowemeterLago&json={P:%Var3%,I:%Var2%,V:%Var1%,S:%Var5%,Q:%Var6%,Pf:%Var7%,Total:%Var4%,Today:%Var8%,Yesterday:%Var9%}&devicekey=YOURKEY ENDON

Backlog Rule1 1; Rule2 1;

restart 1

Advanced settings:

This resets the Today, Yesterday and Total kWh counter to the hardware value (cant reset the total hardware value);
Backlog EnergyReset1 0; EnergyReset2 0; EnergyReset3 0

Disables send state and sensor message interval (s):
TelePeriod 0

Security options:

WebPassword new_password
WifiConfig 4

Update rule 1 to disable the power off of the main relay, so that it's not possible to shutdown the building power by accident:

Rule1 
  ON System#Init DO backlog PowerOnState 4; tuyasend1 1,1; RuleTimer1 5; ENDON 
  ON Rules#Timer=1 DO backlog TuyaSend8; RuleTimer1 5 ENDON

Add a Buzzer to GPIO15

{"NAME":"Hiking DDS238-2 WIFI","GPIO":[0,2272,0,2304,0,0,0,0,0,0,320,480,32,0],"FLAG":0,"BASE":54}

Triger buzzer when current is higher that 20A:

Rule3
  ON energy#current>20 DO buzzer -1,1,30 ENDON
  ON energy#current<20 DO buzzer 2,1,1 ENDON

Backlog Rule3 1; Rule3 5;

[barbudor]

Cool,
Note that you don't need backlog when there is only 1 command in the rule.

[chaveiro]

I tried without backlog but only one value was assigned to the variable at each energy update. Eg the other ON rules did't catch up all at once, only in sequence. Strange, could be some issue but with the backlog it works.

[barbudor]

Good to know

[sfromis]

Possibly related.... Just today an issue (introduced earlier this month) was fixed, which caused multiple triggers for the same JSON payload to fail, only having the first one fire. Should work again with a very fresh binary, if you're using one from this month.

[chaveiro]

Confirm that it was an issue and solved by updating to latest dev branch. Backlog not required anymore. Updated the sample on the first post.