;ÖDEV 7 (EEPROM)  
 list p=16F877A  
 include "p16F877A.inc"

Sayac0 equ 0x20 ;Genel   
 Sayac1 equ 0x21 ;Değişkenler  
 Sayac2 equ 0x22 ;Tanımlandı.  
 Sayac\_yazma\_adres equ 0x23  
 ORG 0   
 clrf PCLATH   
 goto ana\_program   
 ORG 4

Kesme  
 Retfie

ADC\_Oku  
 Banksel ADCON0 ;ADCON0 için BANK0'a geç.  
 bsf ADCON0, 2 ;Dönüşümü başlat.  
 movlw d'1'   
 call Delay

ADC\_j1  
 btfsc ADCON0, 2 ;Dönüştürme tamamlanana kadar bekle.  
 goto ADC\_j1  
 bsf STATUS,RP0   
 movf ADRESL,w ;En degersiz 8 biti workinge at.  
 bcf STATUS,RP0   
 movwf PORTB ;Onemsiz 8 biti PORTB de Goster.   
 movf ADRESH,w ;Degerli bitleri workinge at.  
 movwf PORTC ;Onemli 2 biti PORTC de Goster.  
 movlw d'15' ;Gecik.  
 call Delay  
 call Yazma\_Ayari ;Yazma alt programına dallan.  
 call Okuma\_Ayari ;Okuma alt programına dallan.  
 incfsz Sayac\_yazma\_adres,f ;EEPROM dolana kadar bunu tekrarla.  
 goto ADC\_Oku

Sadece\_Okuma ;EEPROM dolunca sadece okuma kısmı.  
 Banksel PORTC   
 bsf PORTC,7 ;PORTC nin 7.bitini yak (Okuma var).  
 movlw d'15' ;Gecik.  
 call Delay   
 call Okuma\_Ayari ;Okuma alt programına dallan.  
 Banksel PORTC  
 bcf PORTC,7 ;Okuma bitti Ledi Sondur.  
 incfsz Sayac\_yazma\_adres,f ;EEPROM daki tüm degerler okunana kadar tekrarla.  
 goto Sadece\_Okuma

Sonsuzluk ;EEPROM daki tüm degerler donduyse sozsuz donguye gir.  
 nop  
 goto Sonsuzluk

Yazma\_Ayari  
 movf Sayac\_yazma\_adres,w  
 banksel EEADR   
 movwf EEADR ;Adres bilgisi yüklendi.  
 banksel ADRESL  
 movf ADRESL,w ;Adresl'yi oku.  
 banksel EEDATA  
 movwf EEDATA ;EEDATA ya yani EEPROM a yazılacak veri   
 ;ADC De dönüştürülen en değersiz 8 bit.  
 banksel EECON1   
 bcf EECON1,EEPGD ;Veri belleğine erişim izni.  
 bcf INTCON, GIE ;Genel kesmeler pasif. (Yazmada işlem akışı bozulmamalı.)  
 bsf EECON1, WREN ;Yazma etkinleştirme bit’i set edildi.  
 movlw 0x55 ;Yazma için buradan itibaren 5 satır aynen korunmalı.   
 movwf EECON2  
 movlw 0xAA  
 movwf EECON2  
 bsf EECON1, WR ;Yaz komutu verildi.   
 Banksel PORTC   
 bsf PORTC,6 ;Yazma esnasında PORTC nin 6. Ledini yak.  
 Banksel EECON1

dahili\_ee\_j1  
 btfsc EECON1, WR ;Yazma işlemi tamamlanana kadar bekle (WR=0 olana kadar).  
 goto dahili\_ee\_j1  
 bcf EECON1, WREN ;Yazma izni kaldırıldı.  
 Banksel PORTC  
 bcf PORTC,6 ;Yazma bittiyse PORTC nin 6. Ledini Sondur  
 return

Okuma\_Ayari  
 movf Sayac\_yazma\_adres,w  
 banksel EEADR   
 movwf EEADR ;Adres bilgisi yüklendi.  
 banksel EECON1  
 bcf EECON1,EEPGD ;Veri belleğine erişim izni.  
 bsf EECON1, RD ;EEPROM Okuma modunda.  
 banksel EEDATA  
 movf EEDATA, W  
 banksel PORTD   
 movwf PORTD ;EEDATA daki değer PORTD ye gönderiliyor.  
 return

ana\_program  
 movlw D'255' ;TRISA için yönlendirme bilgisİ W'ye yükleniyor.  
 Banksel TRISA   
 movwf TRISA ;PORTA girişe yönlendirildi.  
 clrf TRISB ;PORTB çıkışa yönlendirildi.  
 clrf TRISC ;PORTC çıkışa yönlendirildi.  
 clrf TRISD ;PORTD çıkışa yönlendirildi.  
 movlw 0x80  
 bsf STATUS, RP0   
 movwf ADCON1 ;ADCON1 Ayarları (Girişler Analog, Dahili RC Osilatör)  
 bcf STATUS, RP0   
 clrf PORTB   
 clrf PORTD  
 clrf Sayac\_yazma\_adres  
 movlw 0xD1  
 movwf ADCON0 ;ADCON0 Ayarları (AN2 Seciliyor, ADC Aç, Frekans Sec)  
 movlw d'1'   
 call Delay   
 goto ADC\_Oku ;ADC Baslat.

Delay ;Gecikme Programı  
 movwf Sayac0   
Dongu1   
 movlw d'8'   
 movwf Sayac1   
Dongu2   
 clrf Sayac2   
Dongu3:   
 incfsz Sayac2,f   
 goto Dongu3   
 decfsz Sayac1,f   
 goto Dongu2   
 decfsz Sayac0,f   
 goto Dongu1   
 return

END

