
***BERK BAYRAKTARGİL FİNAL ÖDEVİ – ŞİŞE DOLUM TAKİP SİSTEMİ***

Açıklama ve Çalışma Mantığı:

Cihazda bir mekanik bant bulunmaktadır. Bu bant iki silindir arasına gerilen bir şeritten oluşuyor. Motor silindiri çevirdiği zaman bant hareket ederek üzerine konulan şişeleri taşımaktadır. Bant motorunu PIC16F877A kontrol etmektedir.

Bant dönerken sensör önüne gelince sensörün kızıl ötesi ışığını engeller. Tam karşı pozisyona yerleştirilen alıcı sinyalin kesilmesi ile beraber bant motorunu durdurarak şişeyi sabitler. Ardından pompa motorunu çalıştırarak şişeyi doldurmaya başlar. Şişe sıvı seviyesi belli bir seviyeye geldiği zaman ikinci sensörün karşı alıcıya yolladığı kızıl ötesi ışığı keser ve pompa motoru durur. Bant tekrar çalışmaya ve ikinci şişeyi doluma almaya başlar.




1-) Bant motoru dönmeye başlar. “YENİ ŞİŞE ALINIYOR” yazar,

2-) Sensör, motorun şişeyi ne zaman durdurduğunu algılar. Ekran “DOLDURULMAYA HAZIRLANIYOR.” Yarım saniyeliğine.

3-) Motorlu su şişesi. Ekranda “ ŞİŞE DOLUYOR” yazar. Diğer sensör su seviyesinin yeterince olup olmadığını algılar.  Motor “DOLDURMA”da durur. Sayacın doldurulması 1 artar.

4-) 2 saniye bekler, ardından şişe Dolu'yu yeniden başlatır. " YENİ ŞİŞE ALINIYOR ", motorun çalıştığını yazar ve döngü tekrar eder.

***PROTEUS EKRAN GÖRÜNTÜSÜ***



***PİCBASİC KODLARI***

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'\* Name : ŞİŞE DOLUM TAKİP SİSTEMİ \*

'\* Author : [BERK BAYRAKTARGİL] \*

'\* Date : 28.06.2021 \*

'\* Notes : FİNAL ÖDEVİ \*

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

DEFINE LCD\_DREG PORTB ; lcd data pinleri port tanımlaması

DEFINE LCD\_DBIT 4 ; lcd data pinlerinin 4 tanesi kullanılacak

DEFINE LCD\_RSREG PORTB ; lcd rs pini port tanımlaması

DEFINE LCD\_RSBIT 0 ; lcd rs pini pin out tanımlaması

DEFINE LCD\_EREG PORTB ; lcd e pini port tanımlaması

DEFINE LCD\_EBIT 1 ; lcd e pini pin out tanımlaması

ADCON1=7 ; analaog pinler devre dışı bırakıldı

TRISA=0 ; porta çıkış olarak ayarlandı

TRISB=0 ; portb çıkış olarak ayarlandı

TRISC=1 ; portc giriş olarak ayarlandı

TRISD=0 ; portd çıkış olarak ayarlandı

TRISE=0 ; porte çıkış olarak ayarlandı

dolum var byte ; dolum adında register tanımlandı

bant\_motor VAR PORTD.7 ; bant motoru çıkışı portdnin 7. bitine atandı

su\_pompasi VAR PORTD.6 ; su pompası çıkışı portdnin 6. bitine atandı

adet\_sayici VAR PORTD.4 ; adet sayıcı çıkışı portdnin 4. bitine atandı

sise\_sens var PORTC.2 ; şişe sens inputu portcnin 2. bitine atandı

dolum\_sens var PORTC.1 ; dolum sens inputu portcnin 1. bitine atandı

depo\_sens var PORTC.0 ; depo sens inputu portcnin 0. bitine atandı

low bant\_motor ; bant motoru sıfıra çekildi (kapatıldı)

low su\_pompasi ; su pompası sıfıra çekildi (kapatıldı)

low adet\_sayici ; adet sayıcı sıfıra çekildi (kapatıldı)

dolum = 0 ; dolum registerine 0 yazıldı

PAUSE 500 ; lcdnin açılması için 500ms bekleme

ana\_dongu: ; program ana döngü etiketi

if depo\_sens = 0 then ; depo seviye sensörü 0 sa ( su deposu doluysa)

LCDOUT $FE,1," YENi SiSE ALINIYOR " ; lcdnin 1. satırına "yeni şişe alınıyor" yazıldı

LCDOUT $FE,$C0,1," DOLUM = ",dec dolum ; lcdnin 2. satırına "dolum" ve dolum registerindeki değer yazıldı

high bant\_motor ; bant motoru çalıştırıldı

gosub doluma\_hazirlaniyor ; program dolum\_hazirlaniyor etiketine dallandırıldı

gosub sise\_doluyor ; program sise\_doluyor etiketine dallandırıldı

pause 2000 ; 2000 ms hiçbir işlem yapmadan bekle

else ; depo seviye sensörü 1 se ( su deposu boşsa)

low bant\_motor ; bant motoru durduruldu

low su\_pompasi ; su pompası motoru durduruldu

low adet\_sayici ; adet sayıcı çıkışı durduruldu

LCDOUT $FE,1," SU DEPOSU BOS " ; lcdnin 1. satırına "su deposu boş " yazıldı

LCDOUT $FE,$C0,1," DOLUM = ",dec dolum ; lcdnin 2. satırına "dolum" ve dolum registerindeki değer yazıldı

endif

pause 100 ; 100ms bekleme

goto ana\_dongu ; programı ana\_gongu etiketine gönderdi

doluma\_hazirlaniyor: ; doluma\_hazirlaniyor etiketi

if sise\_sens = 1 then ;sise sens inputu 1 olduysa( sensör yeni şişeyi gördüyse )

low bant\_motor ; bant motoru durduruldu

LCDOUT $FE,1,"DOLUMA HAZIRLANIYOR " ; lcdnin 1. satırına "doluma hazırlanıyor" yazıldı

LCDOUT $FE,$C0,1," DOLUM = ",dec dolum ; lcdnin 2. satırına "dolum" ve dolum registerindeki değer yazıldı

pause 500 ; 500ms bekleme

return ; program dallandırıldığı adrese geri gönderildi

endif

PAUSE 100 ; 100ms bekleme

goto doluma\_hazirlaniyor ; programı doluma\_hazirlaniyor etiketine gönderdi

sise\_doluyor: ; sise\_doluyor etiketi

high su\_pompasi ; su pompası motoru çalıştırıldı

LCDOUT $FE,1," SiSE DOLUYOR " ; lcdnin 1. satırına "şişe doluyor" yazıldı

LCDOUT $FE,$C0,1," DOLUM = ",dec dolum ; lcdnin 2. satırına "dolum" ve dolum registerindeki değer yazıldı

if dolum\_sens = 1 then ; dolum sens 1 olduysa ( şişe dolduysa)

low su\_pompasi ; su pompası durduruldu

dolum = dolum + 1 ; dolum registeri 1 arttırıldı ( dolum sayıcısı 1 arttı)

LCDOUT $FE,1," DOLUM BASARILI " ; lcdnin 1. satırına "dolum başarılı" yazıldı

LCDOUT $FE,$C0,1," DOLUM = ",dec dolum ; lcdnin 2. satırına "dolum" ve dolum registerindeki değer yazıldı

high adet\_sayici ; adet sayıcı çıkışi 1 yapıldı ( harici sayıcı bağlanılmak isterse )

pause 500 ; 500ms bekle

low adet\_sayici ; adet sayıcı çıkışı 0 yapıldı

return ; program dallandırıldığı adrese geri gönderildi

endif

pause 100 ; 100ms bekleme

goto sise\_doluyor ; programı sise\_doluyor etiketine gönderdi

**SON**