**WARNING: MISSING/INVALID REQUIRED DATA**

The below conditional formatting rules will be highlighted yellow with a dotted pattern to warn users of any missing or invalid data.



**TICKET**

Rule: If cell(s) [A:N] has data AND Ticket [A] is empty, then highlight Ticket [A]  
Formula: =AND(OR($A2:$N2<>""),$A2="")  
Applies to: =$A$2:$A$5000

**RECEIVED**

Rule: If cell(s) [A:N] has data AND Received [B] is empty, then highlight Received [B]  
Formula: =AND(OR($A2:$N2<>""),$B2="")  
Applies to: =$B$2:$B$5000

**PRIORITY**

Rule: If cell(s) [A:N] has data AND Priority [C] is empty, then highlight Priority [C]  
Formula: =AND(OR($A2:$N2<>""),$C2="")  
Applies to: =$C$2:$C$5000

**SOURCE**

Rule: If cell(s) [A:N] has data AND Source [D] is empty, then highlight Source [D]  
Formula: =AND(OR($A2:$N2<>""),$D2="")  
Applies to: =$D$2:$D$5000

**COMPLAINANT**

Rule: If cell(s) [A:N] has data AND Complainant [E] is empty, then highlight Complainant [E]  
Formula: =AND(OR($A2:$N2<>""),$E2="")  
Applies to: =$E$2:$E$5000

**INDIVIDUAL(S)**

Rule: If cell(s) [A:N] has data AND Individual(s) [F] is empty, then highlight Individual(s) [F]  
Formula: =AND(OR($A2:$N2<>""),$F2="")  
Applies to: =$F$2:$F$5000

**BENEFIT PLAN**

Rule: If cell(s) [A:N] has data AND Benefit Plan [G] is empty, then highlight Benefit Plan [G]  
Formula: =AND(OR($A2:$N2<>""),$G2="")  
Applies to: =$G$2:$G$5000

**REASON**

Rule: If cell(s) [A:N] has data AND Reason [H] is empty, then highlight Reason [H]  
Formula: =AND(OR($A2:$N2<>""),$H2="")  
Applies to: =$H$2:$H$5000

**NOTES**

Rule: If cell(s) [A:N] has data AND Notes [J] is empty, then highlight Notes [J]  
Formula: =AND(OR($A2:$N2<>""),$J2="")  
Applies to: =$J$2:$J$5000

**STATUS**

Rule: If cell(s) [A:N] has data AND Status [K] is empty; OR if Started [L] has data AND Status [K] is “New”; OR if Completed [M] has data AND Status [K] is “New” OR “Pending”, then highlight Status [K]  
Formula: =OR((AND(OR($A2:$N2<>""),$K2="")),AND($L2<>"",$K2="New"),AND($M2<>"",OR($K2="New",$K2="Pending")))  
Applies to: =$K$2:$K$5000

**COMPLETED**

Rule: If Status [K] is “Resolved”, “Closed”, OR “Referred” AND Completed [M] is blank, then highlight Completed [M]  
Formula: =AND(OR($K2="Resolved",$K2="Closed",$K2="Referred"),$M2="")  
Applies to: =$M$2:$M$5000

**ASSIGNED**

Rule: If Status [K] is NOT blank AND NOT “New” OR cell(s) [L:N] has data; AND Assigned [I] is blank, then highlight Assigned [I]   
Formula: =AND(OR(AND($K2<>"",$K2<>"New"),$L2:$N2<>""),$I2="")  
Applies to: =$I$2:$I$5000

**LAST ACTION**

Rule: If Last Action [N] is blank AND cell(s) [L:M] has data, then highlight Last Action [N]  
Formula: =AND($N2="",OR($L2:$M2<>""))Applies to: =$N$2:$N$5000

**STARTED**

Rule: If Completed [M] has data AND Started [L] is blank; OR Started [L] is blank AND Status [K] is NOT “New” AND NOT blank, then highlight Started [L]  
Formula: =OR(AND($M2<>"",$L2=""),AND($L2="",$K2<>"New",$K2<>""))  
Applies to: =$L$2:$L$5000

**WARNING: DUPLICATES**

The below conditional formatting rules will be highlighted gray with a dotted pattern and purple text to warn users of duplicate data.



**TICKET**

Rule: If Ticket [A] is NOT “NEI”, count number of identical values in Ticket [A] then highlight Ticket [A] if greater than 1  
Formula: =AND($A2<>"NEI",COUNTIFS(A:A,A2)>1)  
Applies to: =$A$2:$A$5000

**INDICATOR: PAST DUE**

The below conditional formatting rules will be highlighted red with a diagonal lines pattern and white text to warn users of grievances past due for action.



**LAST ACTION – NEW GRIEVANCES**

Rule: If Received [B] is more than 30 days from today AND Received [B] is NOT blank AND Status [K] is NOT “Resolved”, “Referred”, and “Closed” AND Last Action [N] is blank, then highlight Last Action [N]  
Formula: =AND($B2<TODAY()-30, $B2<>"",$K2<>"Resolved",$K2<>"Referred",$K2<>"Closed",$N2="")  
Applies to: =$N$2:$N$5000

**LAST ACTION – PENDING GRIEVANCES**

Rule: If Last Action [N] is more than 30 days from today AND Status [K] is NOT “Resolved”, “Referred”, and “Closed” AND Last Action [N] is NOT blank, then highlight Last Action [N]  
Formula: =AND($N2<TODAY()-30, $K2<>"Resolved",$K2<>"Referred",$K2<>"Closed",$N2<>"")  
Applies to: =$N$2:$N$5000

**LAST ACTION – HIGH PRIORITY GRIEVANCES**

Rule: If Last Action [N] is more than 14 days from today AND Status [K] is NOT “Resolved”, “Referred”, and “Closed” AND Last Action [N] is NOT blank AND Priority [C] is “High”, then highlight Last Action [N]  
Formula: =AND($N2<TODAY()-14, $K2<>"Resolved",$K2<>"Referred",$K2<>"Closed",$N2<>"",$C2="High")  
Applies to: =$N$2:$N$5000

**CLASSIFICATION: PRIORITY**

The below conditional formatting rules will be highlighted red with white text for Urgent priority grievances or yellow with black text for High priority grievances.



**HIGH PRIORITY**

Rule: If Priority [C] is “High” AND Status [K] is “New” OR “Pending”, then highlight Priority [C]  
Formula: =AND($C2="High", OR($K2="New",$K2="Pending"))  
Applies to: =$C$2:$C$5000

**URGENT PRIORITY**

Rule: If Priority [C] is “Urgent” AND Status [K] is “New” OR “Pending”, then highlight Priority [C]  
Formula: =AND($C2="Urgent", OR($K2="New",$K2="Pending"))  
Applies to: =$C$2:$C$5000

**CLASSIFICATION: STATUS**

The below conditional formatting rules will be highlighted dark gray with black text for closed or resolved grievances and a lighter gray with black text for referred grievances.

 

**RESOLVED/CLOSED**

Rule: If Status [K] is “Resolved” OR “Closed”, then highlight the entire row  
Formula: =OR($K2="Resolved",$K2="Closed")  
Applies to: =$A$2:$N$5000

**REFERRED**

Rule: If Status [K] is “Referred”, then highlight the entire row  
Formula: =($K2="Referred")  
Applies to: =$A$2:$N$5000

**CLASSIFICATION: OWNERSHIP**

The below conditional formatting rules will be highlighted a variety of different colors (set of 10) to distinguish which workers grievances are assigned to. Colors are pink, purple, light blue, blue, light green, green, tan, brown, peach, and orange.

         

**WORKER 1**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “1” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(1,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 2**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “2” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(2,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 3**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “3” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(3,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 4**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “4” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(4,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 5**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “5” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(5,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 6**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “6” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(6,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 7**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “7” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(7,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 8**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “8” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(8,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 9**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “9” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(9,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000

**WORKER 10**

Rule: If Assigned [I] is NOT blank then perform VALUE LOOKUP “10” in # [B] within [Sheet: Dashboard] [Range: B5 to C14] and RETURN associated Name [C], then highlight Assigned [I]  
Formula: =IF(($I2<>""),$I2=VLOOKUP(10,Dashboard!$B$5:$C$14,2,0))  
Applies to: =$A$2:$N$5000