临界交易系统通达信公式实现

临界交易系统概述

临界交易系统是一个趋势交易系统。这个系统的设计者吴国宾先生早年提出了“价格自组织临界理论” （PRICE SELF- ORGANIZED CRITICALITY），认为，金融市场价格运动存在自组织临界性。价格会自行运动产生临界状态，临界状态是一种必然会被打破的平衡。当价格处于临界状态，最终将产生具有连续性的方向运动，即价格主干运动......临界是金融市场价格高度随机波动中的秩序。

那么如何捕捉这样的价格主干运动呢，在股票市场上，吴先生提出如下量化交易指标

1. 在一个较长的时间点内，价格处于一个较小的波动区间内，上下运动的幅度小于某个阈值，即处于自组织状态
2. 当前的5 日 10日20 日60日均线的乖离率小于一定的阈值，并呈现多头排列的状态
3. 当前成交量大于5日成交量均线
4. 当前价格上涨，且呈现明显的突破。

基于这样的交易思想和量化指标，在通达信软件内部，实现如下交易信号检测系统

参数：

N ： 临界自组织时间

D ：5 10 20日乖离率阈值（单位为一个百分点）

D2 ：60日乖离率阈值（单位为一个百分点）

HH ： 临界自组织箱体宽度（单位为一个百分点）

P ：价格突破阈值（单位为一个百分点）

A1:=(MA(CLOSE, 5)-MA(CLOSE,10)) / MA(CLOSE, 10) \* 100; // 5日均线10 日均线乖离率

B1:=(MA(CLOSE, 5)-MA(CLOSE,20)) / MA(CLOSE, 20) \* 100; //5日均线20日均线乖离率

C1:=(MA(CLOSE, 5)-MA(CLOSE,60)) / MA(CLOSE, 60) \* 100; //5日均线60日均线乖离率

D1:=(MA(CLOSE,10)-MA(CLOSE,20)) / MA(CLOSE, 20) \* 100; //10日均线20日均线乖离率

E1:=(MA(CLOSE,10)-MA(CLOSE,60)) / MA(CLOSE, 60) \* 100; //10日均线60日均线乖离率

F1:=(MA(CLOSE,20)-MA(CLOSE,60)) / MA(CLOSE, 60) \* 100; //20日均线60日均线乖离率

MABIAS\_5\_10\_20:=A1 <= D AND A1 >=0 AND B1 <= D AND B1 >= 0 AND D1 <= D AND D1 >= 0;//5日均线10日均线20日均线乖离率小于阈值

MABIAS\_60:=C1 <= D2 AND C1 >=0 AND E1 <= D2 AND E1 >= 0 AND F1 <= D2 AND F1 >= 0; //60日均线乖离率小于阈值

VOLBIG:=VOL > MA(VOL, 5); //价格放量

HL:=(HHV(CLOSE,N) - LLV(CLOSE, N)) / LLV(CLOSE, N) \*100; //自组织时间内的价格最高点和最低点的差值相对于最低点的比率。

HLBOX:=REF(HL, 1) < HH; //自组织时间内的比率小于箱体宽度阈值

PRICE\_UP:=(CLOSE / REF(CLOSE, 1) -1) \*100 > P; 价格突破阈值

LJ:HLBOX AND PRICE\_UP AND VOLBIG AND MABIAS\_5\_10\_20 AND MABIAS\_60;

备注：股市为单边市场，只考虑做多信号。