**Supporting material for**

**“Species interactions: estimating per individual interaction strength and covariates before simplifying data into per species ecological networks”**

Konstans Wells, Robert B. O’Hara

**Appendix S1**: Model code for BUGS software (e.g. OpenBUGS as freely available at <http://openbugs.info/w/>) for an agent-based interaction model. Per individual interaction strength “lambda[i,j]” is estimated between a hypothetical set of resource and consumer species through a multi-species zero-inflated Poisson generalized linear model.

model

{

for(i in 1: total.resind ){ # total number of resource individuals (all species)

for(j in 1: total.consind ){ # total number of consumer individuals (all species)

# log-link process model of individual-level interaction strength, based on species-level mean; covariates on species- or individual-level can be added here

log(lambda[i,j]) <- v.lambda.sp[Ident.resspec[i], Ident.consspec[j]]

lambda.obs[i,j, 1] <- 0

lambda.obs[i,j, 2] <- lambda[i,j]

for(k in 1: n.rep ){

# Poisson model accounting for zero-inflation through species-level indicator

obs[i,j,k] ~ dpois(lambda.obs[i,j, w.ind[Ident.resspec[i], Ident.consspec[j]] ]) I(,100)

}

}

}

# Output of the estimated total number of pair-wise species associations

w.sum <- sum(w[,])

# Specification of the term "v.lambda.sp" in the process model

for(r in 1: n.resspec){

rho.star[r] <- rho[r] - mean(rho[])

rho[r] ~ dnorm(mu.rho, tau.rho)

for(c in 1: n.consspec){

v.lambda.sp[r,c] <- w[r,c] \* (alpha + rho[r] + chi[c] + eta[r,c])

+ (1- w[r,c]) \* v.lambda.sp.pseudo[r,c]

v.lambda.sp.pseudo[r,c] ~ dgamma(1,100)

# Prior for eta inlcuding pseudo priors if species-level indicator w[r,c] = 0

eta[r,c] <- eta.ind[r,c, w.ind[r,c] ]

eta.ind[r,c,1] ~ dgamma(1,100)

eta.ind[r,c,2] ~ dnorm(mu.eta, tau.eta)

# Output for lambda

lambda.out[r,c] <- w[r,c] \* exp(v.lambda.sp[r,c])

}

}

for(c in 1: n.consspec){

chi.star[c] <- chi[c] - mean(chi[])

chi[c] ~ dnorm(mu.chi, tau.chi)

}

# Indicator function of presence-absence of interactions on species-level

for(r in 1: n.resspec){

om.Res.star[r] <- om.Res[r] - mean(om.Res[])

om.Res[r] ~ dnorm(0,1)

for(c in 1: n.consspec){

w[r,c] ~ dbern(omega[r,c])

w.ind[r,c] <- w[r,c] + 1

logit(omega[r,c]) <- om.Res[r] + om.Cons[c] + omResCons[r,c]

omResCons[r,c] ~ dnorm(0,1)

}

}

for(c in 1: n.consspec){

om.Cons.star[c] <- om.Cons[c] - mean(om.Cons[])

om.Cons[c] ~ dnorm(0, 1)

}

alpha ~dnorm(mu.alpha, tau.alpha)

# Prior definitons

mu.alpha ~ dnorm(0,1)

mu.rho ~ dnorm(0,1)

mu.chi ~ dnorm(0,1)

mu.eta ~ dnorm(0,1)

mu.res.p ~ dnorm(0,1)

mu.cons.p ~ dnorm(0,1)

tau.alpha <- pow(sd.alpha, -2); sd.alpha ~ dunif(0,10)

tau.rho <- pow(sd.rho, -2); sd.rho ~ dunif(0,10)

tau.chi <- pow(sd.chi, -2); sd.chi ~ dunif(0,10)

tau.eta <- pow(sd.eta, -2); sd.eta ~ dunif(0,10)

tau.res.p <- pow(sd.res.p, -2); sd.res.p ~ dunif(0,10)

tau.cons.p <- pow(sd.cons.p, -2); sd.cons.p ~ dunif(0,10)

}