Skip to content

HTTPS clone URL

Subversion checkout URL

You can clone with
or
.
Download ZIP
Browse files

Make IOR get its version from a META file.

  • Loading branch information...
commit 01c91e45d3b8f363a53eebcbcea74980c73517c5 1 parent 44ae2f1
@morrone morrone authored
View
3  META
@@ -0,0 +1,3 @@
+Name: ior
+Version: 2.90.0
+Release: 0
View
112 config/x_ac_meta.m4
@@ -0,0 +1,112 @@
+##*****************************************************************************
+## $Id: x_ac_meta.m4 525 2006-07-13 19:30:13Z dun $
+##*****************************************************************************
+# AUTHOR:
+# Chris Dunlap <cdunlap@llnl.gov>
+#
+# SYNOPSIS:
+# X_AC_META
+#
+# DESCRIPTION:
+# Read metadata from the META file.
+##*****************************************************************************
+
+AC_DEFUN([X_AC_META], [
+ AC_MSG_CHECKING([metadata])
+
+ META="$srcdir/META"
+ _x_ac_meta_got_file=no
+ if test -f "$META"; then
+ _x_ac_meta_got_file=yes
+
+ META_NAME=_X_AC_META_GETVAL([(?:NAME|PROJECT|PACKAGE)]);
+ if test -n "$META_NAME"; then
+ AC_DEFINE_UNQUOTED([META_NAME], ["$META_NAME"],
+ [Define the project name.]
+ )
+ AC_SUBST([META_NAME])
+ fi
+
+ META_VERSION=_X_AC_META_GETVAL([VERSION]);
+ if test -n "$META_VERSION"; then
+ AC_DEFINE_UNQUOTED([META_VERSION], ["$META_VERSION"],
+ [Define the project version.]
+ )
+ AC_SUBST([META_VERSION])
+ fi
+
+ META_RELEASE=_X_AC_META_GETVAL([RELEASE]);
+ if test -n "$META_RELEASE"; then
+ AC_DEFINE_UNQUOTED([META_RELEASE], ["$META_RELEASE"],
+ [Define the project release.]
+ )
+ AC_SUBST([META_RELEASE])
+ fi
+
+ if test -n "$META_NAME" -a -n "$META_VERSION"; then
+ META_ALIAS="$META_NAME-$META_VERSION"
+ test -n "$META_RELEASE" -a "$META_RELEASE" != "1" \
+ && META_ALIAS="$META_ALIAS-$META_RELEASE"
+ AC_DEFINE_UNQUOTED([META_ALIAS], ["$META_ALIAS"],
+ [Define the project alias string (name-ver or name-ver-rel).]
+ )
+ AC_SUBST([META_ALIAS])
+ fi
+
+ META_DATE=_X_AC_META_GETVAL([DATE]);
+ if test -n "$META_DATE"; then
+ AC_DEFINE_UNQUOTED([META_DATE], ["$META_DATE"],
+ [Define the project release date.]
+ )
+ AC_SUBST([META_DATE])
+ fi
+
+ META_AUTHOR=_X_AC_META_GETVAL([AUTHOR]);
+ if test -n "$META_AUTHOR"; then
+ AC_DEFINE_UNQUOTED([META_AUTHOR], ["$META_AUTHOR"],
+ [Define the project author.]
+ )
+ AC_SUBST([META_AUTHOR])
+ fi
+
+ m4_pattern_allow([^LT_(CURRENT|REVISION|AGE)$])
+ META_LT_CURRENT=_X_AC_META_GETVAL([LT_CURRENT]);
+ META_LT_REVISION=_X_AC_META_GETVAL([LT_REVISION]);
+ META_LT_AGE=_X_AC_META_GETVAL([LT_AGE]);
+ if test -n "$META_LT_CURRENT" \
+ -o -n "$META_LT_REVISION" \
+ -o -n "$META_LT_AGE"; then
+ test -n "$META_LT_CURRENT" || META_LT_CURRENT="0"
+ test -n "$META_LT_REVISION" || META_LT_REVISION="0"
+ test -n "$META_LT_AGE" || META_LT_AGE="0"
+ AC_DEFINE_UNQUOTED([META_LT_CURRENT], ["$META_LT_CURRENT"],
+ [Define the libtool library 'current' version information.]
+ )
+ AC_DEFINE_UNQUOTED([META_LT_REVISION], ["$META_LT_REVISION"],
+ [Define the libtool library 'revision' version information.]
+ )
+ AC_DEFINE_UNQUOTED([META_LT_AGE], ["$META_LT_AGE"],
+ [Define the libtool library 'age' version information.]
+ )
+ AC_SUBST([META_LT_CURRENT])
+ AC_SUBST([META_LT_REVISION])
+ AC_SUBST([META_LT_AGE])
+ fi
+ fi
+
+ AC_MSG_RESULT([$_x_ac_meta_got_file])
+ ]
+)
+
+AC_DEFUN([_X_AC_META_GETVAL],
+ [`perl -n\
+ -e "BEGIN { \\$key=shift @ARGV; }"\
+ -e "next unless s/^\s*\\$key@<:@:=@:>@//i;"\
+ -e "s/^((?:@<:@^'\"#@:>@*(?:(@<:@'\"@:>@)@<:@^\2@:>@*\2)*)*)#.*/\\@S|@1/;"\
+ -e "s/^\s+//;"\
+ -e "s/\s+$//;"\
+ -e "s/^(@<:@'\"@:>@)(.*)\1/\\@S|@2/;"\
+ -e "\\$val=\\$_;"\
+ -e "END { print \\$val if defined \\$val; }"\
+ '$1' $META`]dnl
+)
View
6 configure.ac
@@ -1,11 +1,11 @@
# -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.
-AC_PREREQ([2.67])
-AC_INIT()
+AC_INIT
+X_AC_META
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_SRCDIR([src/ior.c])
-AC_CONFIG_HEADERS([config.h])
+AC_CONFIG_HEADER([src/config.h])
AC_CANONICAL_HOST
View
3  src/ior.c
@@ -1407,8 +1407,7 @@ ShowInfo(int argc, char **argv, IOR_param_t *test)
int i;
struct utsname unamebuf;
- fprintf(stdout, "%s: MPI Coordinated Test of Parallel I/O\n\n",
- IOR_RELEASE);
+ fprintf(stdout, "IOR-"META_VERSION": MPI Coordinated Test of Parallel I/O\n\n");
fprintf(stdout, "Run began: %s", CurrentTimeString());
#if USE_UNDOC_OPT /* NFS */
View
2  src/iordef.h
@@ -56,8 +56,6 @@ extern int numTasks, /* MPI variables */
/*************************** D E F I N I T I O N S ****************************/
-#define IOR_RELEASE "IOR-2.10.3"
-
#ifndef FALSE
# define FALSE 0
#endif /* not FALSE */
Please sign in to comment.
Something went wrong with that request. Please try again.