data oysters;

input Trt Rep Initial Final;

cards;

1 1 27.2 32.6

1 2 32.0 36.6

1 3 33.0 37.7

1 4 26.8 31.0

2 1 28.6 33.8

2 2 26.8 31.7

2 3 26.5 30.7

2 4 26.8 30.4

3 1 28.6 35.2

3 2 22.4 29.1

3 3 23.2 28.9

3 4 24.4 30.2

4 1 29.3 35.0

4 2 21.8 27.0

4 3 30.3 36.4

4 4 24.3 30.5

5 1 20.4 24.6

5 2 19.6 23.4

5 3 25.1 30.3

5 4 18.1 21.8

run;

proc print data=oysters;

run;

proc plot data=oysters;

plot final\*initial = trt;

run;

proc glm data=oysters;

/\* ANOVA Model \*/

class trt;

model final=trt;

run;

proc glm data=oysters;

/\* Regression Model \*/

model final=initial;

run;

proc glm data=oysters;

/\* ANCOVA Model \*/

class trt;

model final=trt initial trt\*initial /\* initial\*initial , testing for linearity\*/ /solution;

contrast "Control vs Treatment" trt 1 1 1 1 -4;

contrast "Bottom vs Top" trt 1 -1 1 -1 0;

contrast "Cool vs Hot" trt 1 1 -1 -1 0;

contrast "Hot vs Control" trt 0 0 1 1 -2;

output out=resids r=res;

run;

proc univariate normal plot data = resids;

var res;

run;

data oyster\_adj; set oysters;

/\* Ad-hoc Levene's test \*/

final\_adj = final - 1.08\*(initial - 25.76);

/\* new = old - cov\*(val - GrandCovMean) \*/

run;

proc glm data=oyster\_adj;

class trt;

model final\_adj=trt;

means trt / hovtest = levene;

run;

/\* To get the means for initial weight, 25.76, written above \*/

proc means data=oysters;

var initial;

run;

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| Contrast | DF | Contrast SS | Mean Square | F Value | Pr > F |
| Control vs Treatment | 1 | 0.52000411 | 0.52000411 | 1.72 | **0.2103** |
| Bottom vs Top | 1 | 0.33879074 | 0.33879074 | 1.12 | **0.3071** |
| Cool vs Hot | 1 | 8.59108077 | 8.59108077 | 28.49 | **0.0001** |
| Hot vs Control | 1 | 3.50704696 | 3.50704696 | 11.63 | **0.0042** |

No (statistically significant) differences between control and treatment

No (statistically significant) differences between bottom and top

There are (statistically significant) differences between cool and hot

There are (statistically significant) differences between hot and control

|  |  |  |  |
| --- | --- | --- | --- |
| Model/SS | ANOVA | Regression | ANCOVA |
| Treatment | 198 |  | 12.1 |
| Initial Weight |  | 342.4 | 156 |
| Error | 160.3 | 16.3 | 4.2 |
| SS Total | 358.6695 | 358.6695 | 358.6695 |

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| Levene's Test for Homogeneity of final\_adj Variance  ANOVA of Squared Deviations from Group Means | | | | | |
| Source | DF | Sum of Squares | Mean Square | F Value | Pr > F |
| Trt | 4 | 0.1192 | 0.0298 | 0.52 | **0.7219** |
| Error | 15 | 0.8585 | 0.0572 |  |  |