[Fix #2831] Add xref integration (#3026)

xref.el is an Emacs built-in package that was introduced in Emacs 25.1.

Author: jiacai2050

CHANGELOG.md

@@ -4,6 +4,7 @@
 
 ### New features
 
+* [#2831](https://github.com/clojure-emacs/cider/issues/2831): Add xref integration.
 * [#3017](https://github.com/clojure-emacs/cider/issues/3017): Annotate company completion kinds.
 
 ### Bugs fixed

cider-find.el

@@ -32,6 +32,13 @@
 
 (require 'thingatpt)
 
+(defcustom cider-use-xref t
+  "Enable xref integration."
+  :type 'boolean
+  :safe #'booleanp
+  :group 'cider
+  :version '(cider . "1.2.0"))
+
 (defun cider--find-var-other-window (var &optional line)
   "Find the definition of VAR, optionally at a specific LINE.
 
@@ -226,5 +233,71 @@ thing at point."
     (cider--find-ns kw-ns arg)
     (search-forward-regexp kw-to-find nil 'noerror)))
 
+(defun cider--xref-backend ()
+  "Used for xref integration."
+  'cider)
+
+(cl-defmethod xref-backend-identifier-at-point ((_backend (eql cider)))
+  "Return the relevant identifier at point."
+  (cider-symbol-at-point 'look-back))
+
+(defun cider--var-to-xref-location (var)
+  "Get location of definition of VAR."
+  (when-let* ((info (cider-var-info var))
+              (line (nrepl-dict-get info "line"))
+              (file (nrepl-dict-get info "file"))
+              (buf (cider--find-buffer-for-file file)))
+    (xref-make-buffer-location
+     buf
+     (with-current-buffer buf
+       (save-excursion
+         (goto-char 0)
+         (forward-line (1- line))
+         (back-to-indentation)
+         (point))))))
+
+(cl-defmethod xref-backend-definitions ((_backend (eql cider)) var)
+  "Find definitions of VAR."
+  (cider-ensure-connected)
+  (cider-ensure-op-supported "ns-path")
+  (when-let* ((loc (cider--var-to-xref-location var)))
+    (list (xref-make var loc))))
+
+(cl-defmethod xref-backend-identifier-completion-table ((_backend (eql cider)))
+  "Return the completion table for identifiers."
+  (cider-ensure-connected)
+  (when-let* ((ns (cider-current-ns))
+              (results (cider-sync-request:ns-vars ns)))
+    results))
+
+(cl-defmethod xref-backend-references ((_backend (eql cider)) var)
+  "Find references of VAR."
+  (cider-ensure-connected)
+  (cider-ensure-op-supported "fn-refs")
+  (when-let* ((ns (cider-current-ns))
+              (results (cider-sync-request:fn-refs ns var)))
+    (mapcar (lambda (info)
+              (let* ((filename (nrepl-dict-get info "file"))
+                     (column (nrepl-dict-get info "column"))
+                     (line (nrepl-dict-get info "line"))
+                     (loc (xref-make-file-location filename line column)))
+                (xref-make filename loc)))
+            results)))
+
+(cl-defmethod xref-backend-apropos ((_backend (eql cider)) pattern)
+  "Find all symbols that match regexp PATTERN."
+  (cider-ensure-connected)
+  (cider-ensure-op-supported "apropos")
+  (when-let* ((ns (cider-current-ns))
+              (results (cider-sync-request:apropos pattern ns t t completion-ignore-case)))
+    (mapcar (lambda (info)
+              (let* ((symbol (nrepl-dict-get info "name"))
+                     (loc (cider--var-to-xref-location symbol))
+                     (type (nrepl-dict-get info "type"))
+                     (doc (nrepl-dict-get info "doc")))
+                (xref-make (format "[%s] %s\n  %s" (propertize symbol 'face 'bold) (capitalize type) doc)
+                           loc)))
+            results)))
+
 (provide 'cider-find)
 ;;; cider-find.el ends here

cider-mode.el

@@ -40,6 +40,7 @@
 (require 'cider-profile) ; required only for the menu
 (require 'cider-completion)
 (require 'cider-inspector)
+(require 'cider-find)
 (require 'subr-x)
 (require 'cider-compat)
 
@@ -478,12 +479,13 @@ As it stands Emacs fires these events on <mouse-8> and <mouse-9> on 'x' and
 (defconst cider-mode-map
   (let ((map (make-sparse-keymap)))
     (define-key map (kbd "C-c C-d") 'cider-doc-map)
-    (define-key map (kbd "M-.") #'cider-find-var)
+    (unless cider-use-xref
+      (define-key map (kbd "M-.") #'cider-find-var)
+      (define-key map (kbd "M-,") #'cider-pop-back))
     (define-key map (kbd (if cider--has-many-mouse-buttons "<mouse-8>" "<mouse-4>")) #'xref-pop-marker-stack)
     (define-key map (kbd (if cider--has-many-mouse-buttons "<mouse-9>" "<mouse-5>")) #'cider-find-dwim-at-mouse)
     (define-key map (kbd "C-c C-.") #'cider-find-ns)
     (define-key map (kbd "C-c C-:") #'cider-find-keyword)
-    (define-key map (kbd "M-,") #'cider-pop-back)
     (define-key map (kbd "C-c M-.") #'cider-find-resource)
     (define-key map (kbd "M-TAB") #'complete-symbol)
     (define-key map (kbd "C-M-x")   #'cider-eval-defun-at-point)
@@ -1053,13 +1055,17 @@ property."
         (when cider-dynamic-indentation
           (setq-local clojure-get-indent-function #'cider--get-symbol-indent))
         (setq-local clojure-expected-ns-function #'cider-expected-ns)
+        (when cider-use-xref
+          (add-hook 'xref-backend-functions #'cider--xref-backend nil 'local))
         (setq next-error-function #'cider-jump-to-compilation-error))
     ;; Mode cleanup
     (mapc #'kill-local-variable '(completion-at-point-functions
                                   next-error-function
                                   x-gtk-use-system-tooltips
                                   font-lock-fontify-region-function
                                   clojure-get-indent-function))
+    (when cider-use-xref
+      (remove-hook 'xref-backend-functions #'cider--xref-backend 'local))
     (remove-hook 'font-lock-mode-hook #'cider-refresh-dynamic-font-lock 'local)
     (font-lock-add-keywords nil cider--reader-conditionals-font-lock-keywords)
     (font-lock-remove-keywords nil cider--dynamic-font-lock-keywords)

doc/modules/ROOT/pages/usage/misc_features.adoc

@@ -343,3 +343,12 @@ to format EDN using `clojure.tools.reader.edn`. The following commands are provi
 * `cider-format-edn-defun`
 * `cider-format-edn-region`
 * `cider-format-edn-buffer`
+
+== https://www.gnu.org/software/emacs/manual/html_node/emacs/Xref.html[Xref] integration
+
+Beginning with version 1.2.0, cider support Emacs built-in xref, which means `M-.` (xref-find-definitions) will just work as expected. You can disable it with:
+
+[source,lisp]
+----
+(setq cider-user-xref nil)
+----