Add clojure.core/update, like update-in but takes a single key

Signed-off-by: Stuart Halloway <stu@cognitect.com>

Author: frenchy64

src/clj/clojure/core.clj

@@ -5830,6 +5830,23 @@
      (assoc m k (apply update-in (get m k) ks f args))
      (assoc m k (apply f (get m k) args)))))
 
+(defn update
+  "'Updates' a value in an associative structure, where k is a
+  key and f is a function that will take the old value
+  and any supplied args and return the new value, and returns a new
+  structure.  If the key does not exist, nil is passed as the old value."
+  {:added "1.7"
+   :static true}
+  ([m k f]
+   (assoc m k (f (get m k))))
+  ([m k f x]
+   (assoc m k (f (get m k) x)))
+  ([m k f x y]
+   (assoc m k (f (get m k) x y)))
+  ([m k f x y z]
+   (assoc m k (f (get m k) x y z)))
+  ([m k f x y z & more]
+   (assoc m k (apply f (get m k) x y z more))))
 
 (defn empty?
   "Returns true if coll has no items - same as (not (seq coll)).
@@ -6269,7 +6286,7 @@
   (let [buckets (loop [m {} ks tests vs thens]
                   (if (and ks vs)
                     (recur
-                      (update-in m [(clojure.lang.Util/hash (first ks))] (fnil conj []) [(first ks) (first vs)])
+                      (update m (clojure.lang.Util/hash (first ks)) (fnil conj []) [(first ks) (first vs)])
                       (next ks) (next vs))
                     m))
         assoc-multi (fn [m h bucket]

src/clj/clojure/reflect/java.clj

@@ -224,7 +224,7 @@ the kinds of objects to which they can apply."}
           (visitSource [name debug])
           (visitInnerClass [name outerName innerName access])
           (visitField [access name desc signature value]
-                      (swap! result update-in [:members] (fnil conj #{})
+                      (swap! result update :members (fnil conj #{})
                              (Field. (symbol name)
                                      (field-descriptor->class-symbol desc)
                                      class-symbol
@@ -233,7 +233,7 @@ the kinds of objects to which they can apply."}
           (visitMethod [access name desc signature exceptions]
                        (when-not (= name "<clinit>")
                          (let [constructor? (= name "<init>")]
-                           (swap! result update-in [:members] (fnil conj #{})
+                           (swap! result update :members (fnil conj #{})
                                   (let [{:keys [parameter-types return-type]} (parse-method-descriptor desc)
                                         flags (parse-flags access :method)]
                                     (if constructor?

test/clojure/test_clojure/other_functions.clj

@@ -335,3 +335,21 @@
 ; Regex Support
 ; re-matcher re-find re-matches re-groups re-seq
 
+; update
+
+(deftest test-update
+  (are [result expr] (= result expr)
+    {:a [1 2]}   (update {:a [1]} :a conj 2)
+    [1]          (update [0] 0 inc)
+    ;; higher-order usage
+    {:a {:b 2}}  (update-in {:a {:b 1}} [:a] update :b inc)
+    ;; missing field = nil
+    {:a 1 :b nil} (update {:a 1} :b identity)
+    ;; 4 hard-coded arities
+    {:a 1} (update {:a 1} :a +)
+    {:a 2} (update {:a 1} :a + 1)
+    {:a 3} (update {:a 1} :a + 1 1)
+    {:a 4} (update {:a 1} :a + 1 1 1)
+    ;; rest arity
+    {:a 5} (update {:a 1} :a + 1 1 1 1)
+    {:a 6} (update {:a 1} :a + 1 1 1 1 1)))