|  |
| --- |
| Title: LOON –  Line Oriented Object Notation |

**Contents**

1. LOON – Line Oriented Object Notation 1

1.1. String values 4

|  |
| --- |
|  |

# LOON – Line Oriented Object Notation

LOON is a simple file format for configuration data. It is intended to be easy for both humans and machines to read and write. It is a stripped-down form of JSON, that ends up looking similar to the format used by HTTP, SMTP etc.

An example LOON message is as follows:

# Some details about me

com.codalogic.aboutme {

Name: Pete

Height: 178

DoB: 1969-04-18

Children [

{

Name: Sarah

Height: 170

}

{

Name: Jenny

Height: 144

}

]

Grades [

A

B

C

]

History << END

Born a long time again

in a galaxy far, far away.

END

}

The ABNF is as follows (note that LOON is encoded in UTF-8 or US-ASCII. This ABNF is written in terms of bytes, not Unicode codepoints):

loon = [ object-body ] [ eol ]

object-body = object-line \*( eol object-line )

object-line = comment / directive / object-member

comment = ows "#" \*not-eol

directive = ows "!" \*not-eol

object-member = ows full-name ows value

full-name = [ realm "." ] name

realm = name \*( "." name )

name = ALPHA \*( ALPHA / DIGIT / "-" / "\_" )

value = object / array / primitive-spec

object = "{" eol [ object-body eol ] ows "}"

array = "[" eol [ array-body eol ] ows "]"

array-body = array-line \*( eol array-line )

array-line = array-member ; Comments not allowed

array-member = ows value

primitive-spec = ":" ows primitive

primitive = null / true / false / number / string

null = null-kw

true = true-kw

false = false-kw

; From RFC7159

number = [ minus ] int [ frac ] [ exp ]

decimal-point = %x2E ; .

digit1-9 = %x31-39 ; 1-9

e = %x65 / %x45 ; e E

exp = e [ minus / plus ] 1\*DIGIT

frac = decimal-point 1\*DIGIT

int = zero / ( digit1-9 \*DIGIT )

minus = %x2D ; -

plus = %x2B ; +

zero = %x30 ; 0

string = multiline-string / simple-string

multiline-string = "<<" ows name eol

\*( \*not-eol eol )

ows name

simple-string = \*char

char = unescaped / escaped

unescaped = %x20-5B / %x5D-FF ; not controls or "\"

escaped = escape (

escape / ; \ i.e.: \\ -> \

%x6E / ; n i.e.: \n -> line feed

%x72 / ; r i.e.: \r -> carriage return

%x74 / ; t i.e.: \t -> tab

"#" / ; \# -> #

"{" / ; \{ -> {

"[" / ; \[ -> [

"]" / ; \] -> ]

"<" / ; \< -> <

WSP / ; \<space> -> <space>

%x78 2HEXDIG ) ; x e.g.: \xc2\xa3

escape = %x5C ; \

eol = ows ( CR [ LF ] / LF )

not-eol = HTAB / %x20-FF

ows = \*WSP ; Optional white space

;; Keywords

null-kw = %x6E.75.6C.6C ; "null"

true-kw = %x74.72.75.65 ; "true"

false-kw = %x66.61.6C.73.65 ; "false"

;; Referenced RFC 5234 Core Rules

ALPHA = %x41-5A / %x61-7A ; A-Z / a-z

CR = %x0D ; carriage return

DIGIT = %x30-39 ; 0-9

HEXDIG = DIGIT / "A" / "B" / "C" / "D" / "E" / "F"

HTAB = %x09 ; horizontal tab

LF = %x0A ; linefeed

SP = %x20 ; space

WSP = SP / HTAB ; white space

## String values

LOON string values need special treatment.

Whitespace to the left of a string value will be automatically removed on parsing. If that whitespace is significant, precede the string by a backslash ('\'), e.g.:

Description: \ A string with leading whitespace

A string MUST be preceded by a `\` escape character if, after removing any whitespace from both ends of the string, any of the following apply:

* The string is a value in an array and consists solely of a single '{', '[' or ']' character
* The string is a value in an array and begins with a '<' character and matches the ABNF ("<<" ows name)

For example:

# An array start

Example1 {

}

# A string consisting only of '{'

Example2: {

# A string because it has characters after the '{'

Example3: { A string, not an object start

# The string "["

Example4: [

# A string because it has characters after the '['

Example5: [ A string, not an array start

Example6 [

# A string. Comments are not allowed in arrays

] A string, not an array end

\]

]

# Not an array end. It is an object-member value

Example7: ]

Example8: << A simple-string, not a multiline-string

A multiline string begins with the "<<" HEREDOC marker followed by a name used to mark the end of the multiline string, e.g.:

LongMessage << END

A message

that is long

goes here.

END

Note that if a value starts with '<' but doesn't not match the ABNF ("<<" ows name ows), it is treated as a regular simple-string rather than a multiline-string.

|  |
| --- |
|  |

**History**

|  |  |  |
| --- | --- | --- |
| Issue | Date | Change |
| A | 2 May 19 | Creation |
|  |  |  |
|  |  |  |