-
Notifications
You must be signed in to change notification settings - Fork 16
/
V3Oracle.sol
502 lines (434 loc) · 19.9 KB
/
V3Oracle.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.0;
import "v3-core/interfaces/IUniswapV3Factory.sol";
import "v3-core/interfaces/IUniswapV3Pool.sol";
import "v3-core/libraries/TickMath.sol";
import "v3-periphery/libraries/PoolAddress.sol";
import "v3-periphery/libraries/LiquidityAmounts.sol";
import "v3-periphery/interfaces/INonfungiblePositionManager.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "../lib/AggregatorV3Interface.sol";
import "./interfaces/IV3Oracle.sol";
import "./interfaces/IErrors.sol";
/// @title V3Oracle to be used in V3Vault to calculate position values
/// @notice It uses both chainlink and uniswap v3 TWAP and provides emergency fallback mode
contract V3Oracle is IV3Oracle, Ownable, IErrors {
uint16 public constant MIN_PRICE_DIFFERENCE = 200; //2%
uint256 private constant Q96 = 2 ** 96;
uint256 private constant Q128 = 2 ** 128;
event TokenConfigUpdated(address indexed token, TokenConfig config);
event OracleModeUpdated(address indexed token, Mode mode);
event SetMaxPoolPriceDifference(uint16 maxPoolPriceDifference);
event SetEmergencyAdmin(address emergencyAdmin);
enum Mode {
NOT_SET,
CHAINLINK_TWAP_VERIFY, // using chainlink for price and TWAP to verify
TWAP_CHAINLINK_VERIFY, // using TWAP for price and chainlink to verify
CHAINLINK, // using only chainlink directly
TWAP // using TWAP directly
}
struct TokenConfig {
AggregatorV3Interface feed; // chainlink feed
uint32 maxFeedAge;
uint8 feedDecimals;
uint8 tokenDecimals;
IUniswapV3Pool pool; // reference pool
bool isToken0;
uint32 twapSeconds;
Mode mode;
uint16 maxDifference; // max price difference x10000
}
// token => config mapping
mapping(address => TokenConfig) public feedConfigs;
address public immutable factory;
INonfungiblePositionManager public immutable nonfungiblePositionManager;
// common token which is used in TWAP pools
address public immutable referenceToken;
uint8 public immutable referenceTokenDecimals;
uint16 public maxPoolPriceDifference = MIN_PRICE_DIFFERENCE; // max price difference between oracle derived price and pool price x10000
// common token which is used in chainlink feeds as "pair" (address(0) if USD or another non-token reference)
address public immutable chainlinkReferenceToken;
// address which can call special emergency actions without timelock
address public emergencyAdmin;
// constructor: sets owner of contract
constructor(
INonfungiblePositionManager _nonfungiblePositionManager,
address _referenceToken,
address _chainlinkReferenceToken
) {
nonfungiblePositionManager = _nonfungiblePositionManager;
factory = _nonfungiblePositionManager.factory();
referenceToken = _referenceToken;
referenceTokenDecimals = IERC20Metadata(_referenceToken).decimals();
chainlinkReferenceToken = _chainlinkReferenceToken;
}
/// @notice Gets value and prices of a uniswap v3 lp position in specified token
/// @dev uses configured oracles and verfies price on second oracle - if fails - reverts
/// @dev all involved tokens must be configured in oracle - otherwise reverts
/// @param tokenId tokenId of position
/// @param token address of token in which value and prices should be given
/// @return value value of complete position at current prices
/// @return feeValue value of positions fees only at current prices
/// @return price0X96 price of token0
/// @return price1X96 price of token1
function getValue(uint256 tokenId, address token)
external
view
override
returns (uint256 value, uint256 feeValue, uint256 price0X96, uint256 price1X96)
{
(address token0, address token1, uint24 fee,, uint256 amount0, uint256 amount1, uint256 fees0, uint256 fees1) =
getPositionBreakdown(tokenId);
uint256 cachedChainlinkReferencePriceX96;
(price0X96, cachedChainlinkReferencePriceX96) =
_getReferenceTokenPriceX96(token0, cachedChainlinkReferencePriceX96);
(price1X96, cachedChainlinkReferencePriceX96) =
_getReferenceTokenPriceX96(token1, cachedChainlinkReferencePriceX96);
uint256 priceTokenX96;
if (token0 == token) {
priceTokenX96 = price0X96;
} else if (token1 == token) {
priceTokenX96 = price1X96;
} else {
(priceTokenX96,) = _getReferenceTokenPriceX96(token, cachedChainlinkReferencePriceX96);
}
value = (price0X96 * (amount0 + fees0) / Q96 + price1X96 * (amount1 + fees1) / Q96) * Q96 / priceTokenX96;
feeValue = (price0X96 * fees0 / Q96 + price1X96 * fees1 / Q96) * Q96 / priceTokenX96;
price0X96 = price0X96 * Q96 / priceTokenX96;
price1X96 = price1X96 * Q96 / priceTokenX96;
// checks derived pool price for price manipulation attacks
// this prevents manipulations of pool to get distorted proportions of collateral tokens - for borrowing
// when a pool is in this state, liquidations will be disabled - but arbitrageurs (or liquidator himself)
// will move price back to reasonable range and enable liquidation
uint256 derivedPoolPriceX96 = price0X96 * Q96 / price1X96;
_checkPoolPrice(token0, token1, fee, derivedPoolPriceX96);
}
function _checkPoolPrice(address token0, address token1, uint24 fee, uint256 derivedPoolPriceX96) internal view {
IUniswapV3Pool pool = _getPool(token0, token1, fee);
uint256 priceX96 = _getReferencePoolPriceX96(pool, 0);
_requireMaxDifference(priceX96, derivedPoolPriceX96, maxPoolPriceDifference);
}
function _requireMaxDifference(uint256 priceX96, uint256 verifyPriceX96, uint256 maxDifferenceX10000)
internal
pure
{
uint256 differenceX10000 = priceX96 > verifyPriceX96
? (priceX96 - verifyPriceX96) * 10000 / priceX96
: (verifyPriceX96 - priceX96) * 10000 / verifyPriceX96;
// if too big difference - revert
if (differenceX10000 >= maxDifferenceX10000) {
revert PriceDifferenceExceeded();
}
}
/// @notice Gets breakdown of a uniswap v3 position (tokens and fee tier, liquidity, current liquidity amounts, uncollected fees)
/// @param tokenId tokenId of position
/// @return token0 token0 of position
/// @return token1 token1 of position
/// @return fee fee tier of position
/// @return liquidity liquidity of position
/// @return amount0 current amount token0
/// @return amount1 current amount token1
/// @return fees0 current token0 fees of position
/// @return fees1 current token1 fees of position
function getPositionBreakdown(uint256 tokenId)
public
view
override
returns (
address token0,
address token1,
uint24 fee,
uint128 liquidity,
uint256 amount0,
uint256 amount1,
uint128 fees0,
uint128 fees1
)
{
PositionState memory state = _initializeState(tokenId);
(token0, token1, fee) = (state.token0, state.token1, state.fee);
(amount0, amount1, fees0, fees1) = _getAmounts(state);
liquidity = state.liquidity;
}
/// @notice Sets the max pool difference parameter (onlyOwner)
/// @param _maxPoolPriceDifference Set max allowable difference between pool price and derived oracle pool price
function setMaxPoolPriceDifference(uint16 _maxPoolPriceDifference) external onlyOwner {
if (_maxPoolPriceDifference < MIN_PRICE_DIFFERENCE) {
revert InvalidConfig();
}
maxPoolPriceDifference = _maxPoolPriceDifference;
emit SetMaxPoolPriceDifference(_maxPoolPriceDifference);
}
/// @notice Sets or updates the feed configuration for a token (onlyOwner)
/// @param token Token to configure
/// @param feed Chainlink feed to this token (matching chainlinkReferenceToken)
/// @param maxFeedAge Max allowable chainlink feed age
/// @param pool TWAP reference pool (matching referenceToken)
/// @param twapSeconds TWAP period to use
/// @param mode Mode how both oracle should be used
/// @param maxDifference Max allowable difference between both oracle prices
function setTokenConfig(
address token,
AggregatorV3Interface feed,
uint32 maxFeedAge,
IUniswapV3Pool pool,
uint32 twapSeconds,
Mode mode,
uint16 maxDifference
) external onlyOwner {
// can not be unset
if (mode == Mode.NOT_SET) {
revert InvalidConfig();
}
uint8 feedDecimals = feed.decimals();
uint8 tokenDecimals = IERC20Metadata(token).decimals();
TokenConfig memory config;
if (token != referenceToken) {
if (maxDifference < MIN_PRICE_DIFFERENCE) {
revert InvalidConfig();
}
address token0 = pool.token0();
address token1 = pool.token1();
if (!(token0 == token && token1 == referenceToken || token0 == referenceToken && token1 == token)) {
revert InvalidPool();
}
bool isToken0 = token0 == token;
config = TokenConfig(
feed, maxFeedAge, feedDecimals, tokenDecimals, pool, isToken0, twapSeconds, mode, maxDifference
);
} else {
config = TokenConfig(
feed, maxFeedAge, feedDecimals, tokenDecimals, IUniswapV3Pool(address(0)), false, 0, Mode.CHAINLINK, 0
);
}
feedConfigs[token] = config;
emit TokenConfigUpdated(token, config);
emit OracleModeUpdated(token, mode);
}
/// @notice Updates the oracle mode for a given token - this method can be called by owner OR emergencyAdmin
/// @param token Token to configure
/// @param mode Mode to set
function setOracleMode(address token, Mode mode) external {
if (msg.sender != emergencyAdmin && msg.sender != owner()) {
revert Unauthorized();
}
// can not be unset
if (mode == Mode.NOT_SET) {
revert InvalidConfig();
}
feedConfigs[token].mode = mode;
emit OracleModeUpdated(token, mode);
}
/// @notice Updates emergency admin address (onlyOwner)
/// @param admin Emergency admin address
function setEmergencyAdmin(address admin) external onlyOwner {
emergencyAdmin = admin;
emit SetEmergencyAdmin(admin);
}
// Returns the price for a token using the selected oracle mode given as reference token value
// The price is calculated using Chainlink, Uniswap v3 TWAP, or both based on the mode
function _getReferenceTokenPriceX96(address token, uint256 cachedChainlinkReferencePriceX96)
internal
view
returns (uint256 priceX96, uint256 chainlinkReferencePriceX96)
{
if (token == referenceToken) {
return (Q96, chainlinkReferencePriceX96);
}
TokenConfig memory feedConfig = feedConfigs[token];
if (feedConfig.mode == Mode.NOT_SET) {
revert NotConfigured();
}
uint256 verifyPriceX96;
bool usesChainlink = (
feedConfig.mode == Mode.CHAINLINK_TWAP_VERIFY || feedConfig.mode == Mode.TWAP_CHAINLINK_VERIFY
|| feedConfig.mode == Mode.CHAINLINK
);
bool usesTWAP = (
feedConfig.mode == Mode.CHAINLINK_TWAP_VERIFY || feedConfig.mode == Mode.TWAP_CHAINLINK_VERIFY
|| feedConfig.mode == Mode.TWAP
);
if (usesChainlink) {
uint256 chainlinkPriceX96 = _getChainlinkPriceX96(token);
chainlinkReferencePriceX96 = cachedChainlinkReferencePriceX96 == 0
? _getChainlinkPriceX96(referenceToken)
: cachedChainlinkReferencePriceX96;
chainlinkPriceX96 = (10 ** referenceTokenDecimals) * chainlinkPriceX96 * Q96 / chainlinkReferencePriceX96
/ (10 ** feedConfig.tokenDecimals);
if (feedConfig.mode == Mode.TWAP_CHAINLINK_VERIFY) {
verifyPriceX96 = chainlinkPriceX96;
} else {
priceX96 = chainlinkPriceX96;
}
}
if (usesTWAP) {
uint256 twapPriceX96 = _getTWAPPriceX96(feedConfig);
if (feedConfig.mode == Mode.CHAINLINK_TWAP_VERIFY) {
verifyPriceX96 = twapPriceX96;
} else {
priceX96 = twapPriceX96;
}
}
if (feedConfig.mode == Mode.CHAINLINK_TWAP_VERIFY || feedConfig.mode == Mode.TWAP_CHAINLINK_VERIFY) {
_requireMaxDifference(priceX96, verifyPriceX96, feedConfig.maxDifference);
}
}
// calculates chainlink price given feedConfig
function _getChainlinkPriceX96(address token) internal view returns (uint256) {
if (token == chainlinkReferenceToken) {
return Q96;
}
TokenConfig memory feedConfig = feedConfigs[token];
// if stale data - revert
(, int256 answer,, uint256 updatedAt,) = feedConfig.feed.latestRoundData();
if (updatedAt + feedConfig.maxFeedAge < block.timestamp || answer < 0) {
revert ChainlinkPriceError();
}
return uint256(answer) * Q96 / (10 ** feedConfig.feedDecimals);
}
// calculates TWAP price given feedConfig
function _getTWAPPriceX96(TokenConfig memory feedConfig) internal view returns (uint256 poolTWAPPriceX96) {
// get reference pool price
uint256 priceX96 = _getReferencePoolPriceX96(feedConfig.pool, feedConfig.twapSeconds);
if (feedConfig.isToken0) {
poolTWAPPriceX96 = priceX96;
} else {
poolTWAPPriceX96 = Q96 * Q96 / priceX96;
}
}
// Calculates the reference pool price with scaling factor of 2^96
// It uses either the latest slot price or TWAP based on twapSeconds
function _getReferencePoolPriceX96(IUniswapV3Pool pool, uint32 twapSeconds) internal view returns (uint256) {
uint160 sqrtPriceX96;
// if twap seconds set to 0 just use pool price
if (twapSeconds == 0) {
(sqrtPriceX96,,,,,,) = pool.slot0();
} else {
uint32[] memory secondsAgos = new uint32[](2);
secondsAgos[0] = 0; // from (before)
secondsAgos[1] = twapSeconds; // from (before)
(int56[] memory tickCumulatives,) = pool.observe(secondsAgos); // pool observe may fail when there is not enough history available (only use pool with enough history!)
int24 tick = int24((tickCumulatives[0] - tickCumulatives[1]) / int56(uint56(twapSeconds)));
sqrtPriceX96 = TickMath.getSqrtRatioAtTick(tick);
}
return FullMath.mulDiv(sqrtPriceX96, sqrtPriceX96, Q96);
}
struct PositionState {
uint256 tokenId;
address token0;
address token1;
uint24 fee;
int24 tickLower;
int24 tickUpper;
uint128 liquidity;
uint256 feeGrowthInside0LastX128;
uint256 feeGrowthInside1LastX128;
uint128 tokensOwed0;
uint128 tokensOwed1;
IUniswapV3Pool pool;
uint160 sqrtPriceX96;
int24 tick;
uint160 sqrtPriceX96Lower;
uint160 sqrtPriceX96Upper;
}
function _initializeState(uint256 tokenId) internal view returns (PositionState memory state) {
(
,
,
address token0,
address token1,
uint24 fee,
int24 tickLower,
int24 tickUpper,
uint128 liquidity,
uint256 feeGrowthInside0LastX128,
uint256 feeGrowthInside1LastX128,
uint128 tokensOwed0,
uint128 tokensOwed1
) = nonfungiblePositionManager.positions(tokenId);
state.tokenId = tokenId;
state.token0 = token0;
state.token1 = token1;
state.fee = fee;
state.tickLower = tickLower;
state.tickUpper = tickUpper;
state.liquidity = liquidity;
state.feeGrowthInside0LastX128 = feeGrowthInside0LastX128;
state.feeGrowthInside1LastX128 = feeGrowthInside1LastX128;
state.tokensOwed0 = tokensOwed0;
state.tokensOwed1 = tokensOwed1;
state.pool = _getPool(token0, token1, fee);
(state.sqrtPriceX96, state.tick,,,,,) = state.pool.slot0();
}
// calculate position amounts given current price/tick
function _getAmounts(PositionState memory state)
internal
view
returns (uint256 amount0, uint256 amount1, uint128 fees0, uint128 fees1)
{
if (state.liquidity > 0) {
state.sqrtPriceX96Lower = TickMath.getSqrtRatioAtTick(state.tickLower);
state.sqrtPriceX96Upper = TickMath.getSqrtRatioAtTick(state.tickUpper);
(amount0, amount1) = LiquidityAmounts.getAmountsForLiquidity(
state.sqrtPriceX96, state.sqrtPriceX96Lower, state.sqrtPriceX96Upper, state.liquidity
);
}
(fees0, fees1) = _getUncollectedFees(state, state.tick);
fees0 += state.tokensOwed0;
fees1 += state.tokensOwed1;
}
// calculate uncollected fees
function _getUncollectedFees(PositionState memory position, int24 tick)
internal
view
returns (uint128 fees0, uint128 fees1)
{
(uint256 feeGrowthInside0LastX128, uint256 feeGrowthInside1LastX128) = _getFeeGrowthInside(
position.pool,
position.tickLower,
position.tickUpper,
tick,
position.pool.feeGrowthGlobal0X128(),
position.pool.feeGrowthGlobal1X128()
);
// allow overflow - this is as designed by uniswap - see PositionValue library (for solidity < 0.8)
uint256 feeGrowth0;
uint256 feeGrowth1;
unchecked {
feeGrowth0 = feeGrowthInside0LastX128 - position.feeGrowthInside0LastX128;
feeGrowth1 = feeGrowthInside1LastX128 - position.feeGrowthInside1LastX128;
}
fees0 = uint128(FullMath.mulDiv(feeGrowth0, position.liquidity, Q128));
fees1 = uint128(FullMath.mulDiv(feeGrowth1, position.liquidity, Q128));
}
// calculate fee growth for uncollected fees calculation
function _getFeeGrowthInside(
IUniswapV3Pool pool,
int24 tickLower,
int24 tickUpper,
int24 tickCurrent,
uint256 feeGrowthGlobal0X128,
uint256 feeGrowthGlobal1X128
) internal view returns (uint256 feeGrowthInside0X128, uint256 feeGrowthInside1X128) {
(,, uint256 lowerFeeGrowthOutside0X128, uint256 lowerFeeGrowthOutside1X128,,,,) = pool.ticks(tickLower);
(,, uint256 upperFeeGrowthOutside0X128, uint256 upperFeeGrowthOutside1X128,,,,) = pool.ticks(tickUpper);
// allow overflow - this is as designed by uniswap - see PositionValue library (for solidity < 0.8)
unchecked {
if (tickCurrent < tickLower) {
feeGrowthInside0X128 = lowerFeeGrowthOutside0X128 - upperFeeGrowthOutside0X128;
feeGrowthInside1X128 = lowerFeeGrowthOutside1X128 - upperFeeGrowthOutside1X128;
} else if (tickCurrent < tickUpper) {
feeGrowthInside0X128 = feeGrowthGlobal0X128 - lowerFeeGrowthOutside0X128 - upperFeeGrowthOutside0X128;
feeGrowthInside1X128 = feeGrowthGlobal1X128 - lowerFeeGrowthOutside1X128 - upperFeeGrowthOutside1X128;
} else {
feeGrowthInside0X128 = upperFeeGrowthOutside0X128 - lowerFeeGrowthOutside0X128;
feeGrowthInside1X128 = upperFeeGrowthOutside1X128 - lowerFeeGrowthOutside1X128;
}
}
}
// helper method to get pool for token
function _getPool(address tokenA, address tokenB, uint24 fee) internal view returns (IUniswapV3Pool) {
return IUniswapV3Pool(PoolAddress.computeAddress(factory, PoolAddress.getPoolKey(tokenA, tokenB, fee)));
}
}