## **实验三** 步进电机原理及应用

21200903

1. **原理总结**

步进电机是一种将电脉冲信号转换成相应角位移或线位移的电动机。每输入一个脉冲信号，转子就转动一个角度或前进一步，其输出的角位移或线位移与输入的脉冲数成正比，转速与脉冲频率成正比。因此，步进电动机又称脉冲电动机。

步进电机又称为脉冲电机，基于最基本的电磁铁原理，它是一种可以自由回转的电磁铁，其动作原理是依靠气隙磁导的变化来产生电磁转矩。其原始模型是起源于1830年至1860年间。1870年前后开始以控制为目的的尝试，应用于氢弧灯的电极输送机构中。这被认为是最初的步进电机。二十世纪初，在电话自动交换机中广泛使用了步进电机。由于西方资本主义列强争夺殖民地，步进电机在缺乏交流电源的船舶和飞机等独立系统中得到了广泛的使用。二十世纪五十年代后期晶体管的发明也逐渐应用在步进电机上，对于数字化的控制变得更为容易。到了八十年代后，由于廉价的微型计算机以多功能的姿态出现，步进电机的控制方式更加灵活多样。

步进电机相对于其它控制用途电机的最大区别是，它接收数字控制信号（电脉冲信号）并转化成与之相对应的角位移或直线位移，它本身就是一个完成数字模式转化的执行元件。而且它可开环位置控制，输入一个脉冲信号就得到一个规定的位置增量，这样的所谓增量位置控制系统与传统的直流控制系统相比,其成本明显减低，几乎不必进行系统调整。步进电机的角位移量与输入的脉冲个数严格成正比，而且在时间上与脉冲同步。因而只要控制脉冲的数量、频率和电机绕组的相序,即可获得所需的转角、速度和方向。

我国的步进电机在二十世纪七十年代初开始起步，七十年代中期至八十年代中期为成品发展阶段，新品种和高性能电机不断开发，目前，随着科学技术的发展，特别是永磁材料、半导体技术、计算机技术的发展，使步进电机在众多领域得到了广泛应用。

控制原理：

步进电机由定子和转子组成。定子上有磁极，转子上有齿。

以三相步进电机为例，定子按 A→B→C→A相轮流通电，则磁场沿A、B、C方向转动360°角，而转子沿ABC方向转动了一个齿距的位置。改变定子绕组的通电顺序，将改变转子旋转方向。

1）控制输入给步进电机的脉冲数目可以控制步进电机的角位移：∅=Nθ

2）控制输入给步进电机脉冲频率可以控制步进电机的转速:n=60fθ/360°=60f/mZ\*C

3）控制步进电机定子绕组的通电顺序可以控制步进电机的转动方向

1. **程序分析**
2. 代码

ORG 0000H

LJMP START

ORG 000BH ;定时器中断程序起始地址

LJMP EINT0

ORG 0040H

START:

P4 EQU 0C0H ;P4地址

P4SW EQU 0BBH ;P4SW地址

CLK EQU P4.4 ;CLK地址

DAT EQU P4.5 ;DAT地址

SW EQU P3.6 ;SW地址

MOV P4SW,#70H ;寄存器p4sw对应位设置为1

MOV DPTR,#TABLE ;段码表table首址送入DPTR

SLIST:

MOV R3,#0 ;数码管个位

MOV R4,#0 ;数码管十位

MOV R5,#0 ;数码管百位

MOV TMOD,#01H ;TOMD为定时器/计数器工作方式寄存器，此时选择了mode1

MOV IE,#82H ;IE为中断允许寄存器，中断总体允许控制位EA置1，定时器溢出中断允许控制位置1

ORL IP,#02H ;IP为优先级寄存器，此处设置定时器优先级高

MOV R2,#00H ;4步为一个序列，存放每次转动需要多少个序列

;要求1：以40转每分钟的速度正转5周，等待S1按下

;得到每步之间的时间间隔为0.0625s，一共需要转动120步

STEP1:

MOV R0,#01111000B ;转动序列，使得步进电机顺时针旋转

MOV 20H,R0 ;将序列存入地址中，方便读取

MOV R2,#30 ;24\*5/4=30，表示循环30个序列

L10:

MOV R1,#4 ;4步为一个序列

MOV R0,20H ;从20H中取出步进电机脉冲时序

L11:

MOV A,R0 ;A中存放转序列

CLR P1.1 ;清除CE1端口的值

CLR P1.4 ;清除CE2端口的值

RLC A ;将A循环左移值高位存入C

MOV P3.2,C ;将脉冲的高一位送入步进电机驱动芯片与单片机P3.2相连的IN1中

RLC A ;将A循环左移值高位存入C

MOV P1.0,C ;将脉冲的高一位送入步进电机驱动芯片与单片机P1.0相连的IN2中

SETB P1.1 ;将输出控制端CE1置高 (即置1)

SETB P1.4 ;将输出控制端CE2置高 (即置1)

MOV R0,A ;将累加器A循环左移两次的结果保存到R0中

LCALL NUM ;调用LED显示器的子程序，显示步进电机已转动的次数

LCALL TIMEHIGH ;调用定时器子程序

DJNZ R1,L11 ;R1先减1,若不等于0,则跳转,否则顺次执行下一条，执行一个4步组成序列

DJNZ R2,L10 ;R2先减1,若不等于0,则跳转,否则顺次执行下一条，执行30个序列

LCALL WAIT1 ;重新判断开关是否按下，这是一个死循环

;要求2：以25转每分钟的速度反转转10周，等待S1按下

;得到每步之间的时间间隔为0.1s，一共需要转动240步

SETP2:

MOV R0,#00101101B ;转动序列，使得步进电机逆时针旋转

MOV 20H,R0 ;将序列存入地址中，方便读取

MOV R2,#60 ;240\*5/4=60，表示循环60个序列

L20:

MOV R1,#4 ;4步为一个序列

MOV R0,20H ;从20H中取出步进电机脉冲时序

L21:

MOV A,R0 ;A中存放转序列

CLR P1.1 ;清除CE1端口的值

CLR P1.4 ;清除CE2端口的值

RLC A ;将A循环左移值高位存入C

MOV P3.2,C ;将脉冲的高一位送入步进电机驱动芯片与单片机P3.2相连的IN1中

RLC A ;将A循环左移值高位存入C

MOV P1.0,C ;将脉冲的高一位送入步进电机驱动芯片与单片机P1.0相连的IN2中

SETB P1.1 ;将输出控制端CE1置高 (即置1)

SETB P1.4 ;将输出控制端CE2置高 (即置1)

MOV R0,A ;将累加器A循环左移两次的结果保存到R0中

LCALL NUM ;调用LED显示器的子程序，显示步进电机已转动的次数

LCALL TIMEMID ;调用定时器子程序

DJNZ R1,L21 ;R1先减1,若不等于0,则跳转,否则顺次执行下一条，执行一个4步组成序列

DJNZ R2,L20 ;R2先减1,若不等于0,则跳转,否则顺次执行下一条，执行60个序列

LCALL WAIT1 ;重新判断开关是否按下，这是一个死循环

;要求2：以10转每分钟的速度持续正转，按下开关S2时暂停旋转

;得到每步之间的时间间隔为0.25s

STEP3:

MOV R0,#01111000B ;转动序列，使得步进电机顺时针旋转

MOV 20H,R0 ;将序列存入地址中，方便读取

L30:

MOV R1,#4 ;4步为一个序列

MOV R0,20H ;从20H中取出步进电机脉冲时序

L31:

JNB P3.7,L31 ;判断S2是否被按下，按下则循环等待，不旋转。

MOV A,R0 ;A中存放转序列

CLR P1.1 ;清除CE1端口的值

CLR P1.4 ;清除CE2端口的值

RLC A ;将A循环左移值高位存入C

MOV P3.2,C ;将脉冲的高一位送入步进电机驱动芯片与单片机P3.2相连的IN1中

RLC A ;将A循环左移值高位存入C

MOV P1.0,C ;将脉冲的高一位送入步进电机驱动芯片与单片机P1.0相连的IN2中

SETB P1.1 ;将输出控制端CE1置高 (即置1)

SETB P1.4 ;将输出控制端CE2置高 (即置1)

MOV R0,A ;将累加器A循环左移两次的结果保存到R0中

LCALL NUM ;调用LED显示器的子程序，显示步进电机已转动的次数

LCALL TIMELOW ;调用定时器子程序

DJNZ R1,L31 ;R1先减1,若不等于0,则跳转,否则顺次执行下一条，执行一个4步组成序列

LJMP L30 ;死循环，一直执行L30子程序，使得步进电机一直旋转

;转速最慢的定时器程序，定时0.25s

TIMELOW:

MOV R6,#5 ;5个周期

LOW10:

;定时50ms

MOV TH0,#3CH ;定时器初值高八位3C

MOV TL0,#0B0H ;定时器初值低八位为B0

SETB TR0 ;将TR0置高 (即置1)，定时器0启动，定时器启动跳转到中断地址

MOV R7,#00H ;R7为判断中断标志，置0

LOW11:

CJNE R7,#01H,LOW11 ;R7若不等于1则跳转,等待定时器中断产生;为1顺次执行

DJNZ R6,LOW10 ;R6自减，并进行循环

RET ;返回主程序

;转速第二的定时器程序，定时0.1s

TIMEMID:

MOV R6,#2 ;2个周期

MIDDLE10:

;定时50ms

MOV TH0,#3CH ;定时器初值高八位3C

MOV TL0,#0B0H ;定时器初值低八位为B0

SETB TR0 ;将TR0置高 (即置1)，定时器0启动，定时器启动跳转到中断地址

MOV R7,#00H ;R7为判断中断标志，置0

MIDDLE11:

CJNE R7,#01H,MIDDLE11 ;R7若不等于1则跳转,等待定时器中断产生;为1顺次执行

DJNZ R6,MIDDLE10 ;R6自减，并进行循环

RET ;返回主程序

;转速最快的定时器程序，定时0.0625

TIMEHIGH:

MOV R6,#125 ;125个周期

HIGH10:

;定时500us

MOV TH0,#0FEH ;定时器初值高八位FE

MOV TL0,#0CH ;定时器初值低八位为0C

SETB TR0 ;将TR0置高 (即置1)，定时器0启动，定时器启动跳转到中断地址

MOV R7,#00H ;R7为判断中断标志，置0

HIGH11:

CJNE R7,#01H,HIGH11 ;R7若不等于1则跳转,等待定时器中断产生;为1顺次执行

DJNZ R6,HIGH10 ;R6自减，并进行循环

RET ;返回主程序

;定时器0中断处理

EINT0:

MOV R7,#1 ;中断标志置1

RETI ;中断返回

;调用LED显示子程序，显示步进电机已转动次数

NUM:

S0:

CJNE R3,#9,S1 ;R3表示个位若等于9，表示要进位，则顺次执行下一条指令，否则跳转

MOV R3,#0 ;个位清零

CJNE R4,#9,S2 ;R4表示十位若等于9，表示要进位，则顺次执行下一条指令，否则跳转

MOV R4,#0 ;十位清零

CJNE R5,#9,S3 ;R5表示百位若等于9，表示要进位，则顺次执行下一条指令，否则跳转

MOV R5,#0 ;百位清零

S1:

INC R3 ;R3自增

LJMP OUT1 ;长转移指令，下一条指令无条件跳转到OUT1

S2:

INC R4 ;R4自增

LJMP OUT1 ;长转移指令，下一条指令无条件跳转到OUT1

S3:

INC R5 ;R5自增

LJMP OUT1 ;长转移指令，下一条指令无条件跳转到OUT1

OUT1:

MOV A,R3 ;将R3表示的个位传给累加器A

CALL EXP ;调用数码管显示子程序，显示个位

MOV A,R4 ;将R4表示的十位传给累加器A

CALL EXP ;调用数码管显示子程序，显示十位

MOV A,R5 ;将R5表示的百位传给累加器A

CALL EXP ;调用数码管显示子程序，显示百位

OUT2:

RET ;返回主程序

;等待S1按下

WAIT1:

JB P3.6,WAIT1 ;判断S1是否被按下，等待S1按下后返回主程序


RET ;返回主程序

;数码管显示子程序

EXP:

MOV 21H,R0 ;相当于压栈，保存调用该子程序前R0的值，防止修改R0的值

MOVC A,@A+DPTR ;变址寻址方式，将累加器（变址寄存器）与数据指针寄存器（基址寄存器）保存的数相加，将该数的内容传给累加器A，得到要显示在某一发光管的字码段

**** MOV R0,#8 ;设置8次循环，从高位向低位依次向移位寄存器输出8比特

LOOP1:

CLR CLK ;CLR清0,移位寄存器时钟给低电平

RLC A ;累加器A逻辑左移，C进位位置0或1

MOV DAT,C ;P4.5位,将C表示的0或1送入移位寄存器（给相应字码段低电平或高电平，即相应数码管亮或不亮）

SETB CLK ;P4.4位置1,即时钟给高电平，产生上升沿，移位寄存器向低位右移一位（当8位都输出后，74HC164并行输出到相应数码管）

DJNZ R0,LOOP1 ;R0先减1,若不等于0，则跳转

MOV R0,21H ;相当于出栈，还原R0原来的值

RET ;返回主程序

;段码表，存放0-9的数码管对应取值

TABLE: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H;

END

1. 流程图
2. **思考题**
3. 如采用单四拍工作模式，每次步进角度是多少，程序要如何修改？

15度。IN1和 IN2 脉冲顺序改为 01→10→00→00→01， CE1 和 CE2 脉冲顺序改为 10→01→10→01。修改程序时将除了了改变相位值之外， 还应控制 CE 端信号。

1. 如采用单双八拍工作模式，每次步进角度是多少，程序要如何修改？

7.5度。IN1 和 IN2 脉冲顺序改为 01→11→10→10→00→00→00→01→01， CE1 和 CE2 脉冲顺序改为10→11→01→11→10。 修改程序时由于定时器器定时周期变了了， 故需修改定时初始值为 44703；相位值和 CE 端信号也需改变， 还有循环次数。

3. 步进电机的转速取决于那些因素？有没有上、下限？

取决于脉冲频率和工作模式，转速下限为0，上限根据电机的不同而不同

4.如何改变步进电机的转向？

调换脉冲顺序即可

5.步进电机有那些规格参数，如何根据需要选择型号？

功率、马力、电流、转速、效率、功率因数、额定转矩、额定电流、重量、空起频率等

a.选择需要的额定转矩：通常根据需要的转矩⼤小通常根据需要的转矩⼤小来选择机器。

b．选择合适的转速：电机的输出转矩，与转速成反比。

c．“空起频率”的选择：步进电机空载起动频率的选择步进电机空载起动频率， 通常称为“空起频率”。

d．考虑使用环境：特种步进电机能够防水、防油，用于某些特殊场合。

1. **实验过程中遇到的问题**

实验过程中，由于实验工具使用不熟练，导致软件加载错误，在仔细阅读相关资料后，正确连接安装调整软件，完成实验。