Permalink
Browse files

Add generation of DCMTKConfig.cmake

For both install and build tree, the files:

  DCMTKConfig.cmake
  DCMTKConfigVersion.cmake
  DCMTKTargets.cmake

will be configured into:

   <prefix>/share/dcmtk

It means the following option have to be passed when build a project
depending on python:

   -DDCMTK_DIR:PATH=/path/to/<prefix>/lib/cmake/dcmtk

Since CMake 2.6,  a new signature for find_package is supported:
   find_package(<package_name> NO_MODULE)

NO_MODULE tells CMake to skip loading the Find<package>.cmake to locate a
package and use it. With the current implemtantion of DCMTKConfig.cmake,
CMake will be able to depends on DCMTK without relying on FindDCMTK.cmake.

Since CMake 2.8.8, there is convenient module named "CMakePackageConfigHelpers"
that provided the helper macros "configure_package_config_file" and
"write_basic_package_version_file" allowing to easily configure
relocatable packages.
See http://www.cmake.org/cmake/help/v2.8.8/cmake.html#module:CMakePackageConfigHelpers

To avoid upgrading the minimum requirement version of CMake, the
generation of 'DCMTKConfig.cmake' is done only if possible. To display
message with the macro are not available, a convenient
macro named "check_cmake_command_exists" has also been added.

To allow find_package to work with both a build and install tree, the macro
"configure_package_config_file" is called twice with different value for
the variables:

  DCMTK_CMKDIR_CONFIG
  DCMTK_config_INCLUDE_DIR_CONFIG
  DCMTK_<module>_INCLUDE_DIR_CONFIG

Then, within DCMTKConfig.cmake, the following variables are set:
  DCMTK_MODULES
  DCMTK_LIBRARIES
  DCMTK_TARGETS
  DCMTK_INCLUDE_DIRS
  DCMTK_INCLUDE_DIR # Deprecated

Finally, the DCMTKConfigVersion file is automatically generated with the
help of "write_basic_package_version_file" and is identical for both the
build and the install tree.
  • Loading branch information...
1 parent 57698d0 commit f461865d1759854db56e4c840991c81c77e45bb9 @jcfr jcfr committed Mar 29, 2013
View
13 CMake/CheckCMakeCommandExists.cmake
@@ -0,0 +1,13 @@
+
+macro(check_cmake_command_exists commandname)
+ message(STATUS "Looking for CMake command ${commandname}")
+ string(TOUPPER ${commandname} commandname_upper)
+ if(COMMAND ${commandname})
+ set(HAVE_${commandname_upper} TRUE)
+ message(STATUS "Looking for CMake command ${commandname} - found")
+ else()
+ set(HAVE_${commandname_upper} FALSE)
+ message(STATUS "Looking for CMake command ${commandname} - not found")
+ endif()
+endmacro()
+
View
46 CMake/DCMTKConfig.cmake.in
@@ -2,10 +2,16 @@
# DCMTKConfig.cmake - DCMTK CMake configuration file for external projects
#
+@PACKAGE_INIT@
+
# Basic version information
-SET(DCMTK_MAJOR_VERSION @DCMTK_MAJOR_VERSION@)
-SET(DCMTK_MINOR_VERSION @DCMTK_MINOR_VERSION@)
-SET(DCMTK_BUILD_VERSION @DCMTK_BUILD_VERSION@)
+SET(DCMTK_MAJOR_VERSION ${DCMTK_VERSION_MAJOR})
+SET(DCMTK_MINOR_VERSION ${DCMTK_VERSION_MINOR})
+SET(DCMTK_BUILD_VERSION ${DCMTK_VERSION_PATCH})
+
+# DCMTK libraries and modules
+SET(DCMTK_MODULES "@DCMTK_MODULES@")
+SET(DCMTK_LIBRARIES "@DCMTK_LIBRARY_TARGETS@")
# DCMTK build options
SET(DCMTK_WITH_TIFF @DCMTK_WITH_TIFF@)
@@ -26,3 +32,37 @@ SET(DCMTK_SINGLE_SHARED_LIBRARY @BUILD_SINGLE_SHARED_LIBRARY@)
SET(DCMTK_OVERWRITE_WIN32_COMPILER_FLAGS @DCMTK_OVERWRITE_WIN32_COMPILER_FLAGS@)
SET(DCMTK_WIDE_CHAR_FILE_IO_FUNCTIONS @DCMTK_WIDE_CHAR_FILE_IO_FUNCTIONS@)
SET(DCMTK_WIDE_CHAR_MAIN_FUNCTION @DCMTK_WIDE_CHAR_MAIN_FUNCTION@)
+
+set_and_check(DCMTK_config_INCLUDE_DIR "@PACKAGE_DCMTK_config_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_ofstd_INCLUDE_DIR "@PACKAGE_DCMTK_ofstd_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_oflog_INCLUDE_DIR "@PACKAGE_DCMTK_oflog_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmdata_INCLUDE_DIR "@PACKAGE_DCMTK_dcmdata_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmimgle_INCLUDE_DIR "@PACKAGE_DCMTK_dcmimgle_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmimage_INCLUDE_DIR "@PACKAGE_DCMTK_dcmimage_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmjpeg_INCLUDE_DIR "@PACKAGE_DCMTK_dcmjpeg_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmjpls_INCLUDE_DIR "@PACKAGE_DCMTK_dcmjpls_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmtls_INCLUDE_DIR "@PACKAGE_DCMTK_dcmtls_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmnet_INCLUDE_DIR "@PACKAGE_DCMTK_dcmnet_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmsr_INCLUDE_DIR "@PACKAGE_DCMTK_dcmsr_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmsign_INCLUDE_DIR "@PACKAGE_DCMTK_dcmsign_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmwlm_INCLUDE_DIR "@PACKAGE_DCMTK_dcmwlm_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmqrdb_INCLUDE_DIR "@PACKAGE_DCMTK_dcmqrdb_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmpstat_INCLUDE_DIR "@PACKAGE_DCMTK_dcmpstat_INCLUDE_DIR_CONFIG@")
+set_and_check(DCMTK_dcmrt_INCLUDE_DIR "@PACKAGE_DCMTK_dcmrt_INCLUDE_DIR_CONFIG@")
+
+set_and_check(DCMTK_TARGETS "@PACKAGE_DCMTK_CMKDIR_CONFIG@/DCMTKTargets.cmake")
+
+SET(DCMTK_INCLUDE_DIRS "")
+FOREACH(module config ${DCMTK_MODULES})
+ LIST(APPEND DCMTK_INCLUDE_DIRS ${DCMTK_${module}_INCLUDE_DIR})
+ENDFOREACH(module)
+
+@DCMTK_CONFIG_CODE@
+
+# Compatibility: This variable is deprecated
+SET(DCMTK_INCLUDE_DIR ${DCMTK_INCLUDE_DIRS})
+
+IF(NOT DCMTK_TARGETS_IMPORTED)
+ SET(DCMTK_TARGETS_IMPORTED 1)
+ INCLUDE(${DCMTK_TARGETS})
+ENDIF(NOT DCMTK_TARGETS_IMPORTED)
View
4 CMake/dcmtkAfterModules.cmake
@@ -14,8 +14,12 @@ IF(BUILD_SINGLE_SHARED_LIBRARY)
TARGET_LINK_LIBRARIES(dcmtk ${DCMTK_LIBRARY_DEPENDENCIES})
SET_TARGET_PROPERTIES(dcmtk PROPERTIES ${DCMTK_LIBRARY_PROPERTIES})
+ # Export target for build tree
+ SET_PROPERTY(GLOBAL APPEND PROPERTY DCMTK_TARGETS dcmtk)
+
# Declare installation files
INSTALL(TARGETS dcmtk
+ EXPORT DCMTKTargets
COMPONENT lib
RUNTIME DESTINATION ${DCMTK_INSTALL_BINDIR}
LIBRARY DESTINATION ${DCMTK_INSTALL_LIBDIR}
View
15 CMake/dcmtkMacros.cmake
@@ -32,8 +32,12 @@ MACRO(DCMTK_ADD_EXECUTABLE PROGRAM)
SET_TARGET_PROPERTIES(${PROGRAM} PROPERTIES LINK_FLAGS ${WIN32_STD_OBJECTS})
ENDIF(WIN32 AND NOT MINGW)
+ # Export target for build tree
+ SET_PROPERTY(GLOBAL APPEND PROPERTY DCMTK_EXECUTABLE_TARGETS ${PROGRAM})
+
# declare installation files
INSTALL(TARGETS ${PROGRAM}
+ EXPORT DCMTKTargets
COMPONENT bin
DESTINATION ${DCMTK_INSTALL_BINDIR})
ENDIF(BUILD_APPS)
@@ -60,12 +64,15 @@ MACRO(DCMTK_ADD_LIBRARY LIBRARY)
ENDIF(BUILD_SHARED_LIBS AND NOT BUILD_SINGLE_SHARED_LIBRARY)
IF(NOT BUILD_SINGLE_SHARED_LIBRARY)
+ # Export target for build tree
+ SET_PROPERTY(GLOBAL APPEND PROPERTY DCMTK_LIBRARY_TARGETS ${LIBRARY}${DCMTK_LIBRARY_SUFFIX})
+
# Declare installation files
INSTALL(TARGETS ${LIBRARY}${DCMTK_LIBRARY_SUFFIX}
- COMPONENT lib
- RUNTIME DESTINATION ${DCMTK_INSTALL_BINDIR}
- LIBRARY DESTINATION ${DCMTK_INSTALL_LIBDIR}
- ARCHIVE DESTINATION ${DCMTK_INSTALL_LIBDIR})
+ EXPORT DCMTKTargets
+ RUNTIME DESTINATION ${DCMTK_INSTALL_BINDIR} COMPONENT bin
+ LIBRARY DESTINATION ${DCMTK_INSTALL_LIBDIR} COMPONENT shlib
+ ARCHIVE DESTINATION ${DCMTK_INSTALL_LIBDIR} COMPONENT lib)
ENDIF(NOT BUILD_SINGLE_SHARED_LIBRARY)
ENDMACRO(DCMTK_ADD_LIBRARY)
View
25 CMake/dcmtkPrepare.cmake
@@ -93,14 +93,30 @@ ENABLE_TESTING()
SET(DCMTK_INSTALL_BINDIR "bin" CACHE STRING "Installation sub-directory for binary executables.")
SET(DCMTK_INSTALL_INCDIR "include" CACHE STRING "Installation sub-directory for header files.")
SET(DCMTK_INSTALL_LIBDIR "lib" CACHE STRING "Installation sub-directory for object code libraries.")
+IF(UNIX)
+ SET(DCMTK_INSTALL_CMKDIR "lib/cmake/dcmtk" CACHE STRING "Installation sub-directory for CMake files.")
+ELSEIF(WIN32)
+ SET(DCMTK_INSTALL_CMKDIR "cmake" CACHE STRING "Installation sub-directory for CMake files.")
+ENDIF(UNIX)
SET(DCMTK_INSTALL_ETCDIR "etc/dcmtk" CACHE STRING "Installation sub-directory for configuration files.")
SET(DCMTK_INSTALL_DATDIR "share/dcmtk" CACHE STRING "Installation sub-directory for sample files and the like.")
SET(DCMTK_INSTALL_DOCDIR "share/doc/dcmtk" CACHE STRING "Installation sub-directory for general documentation.")
SET(DCMTK_INSTALL_HTMDIR "share/doc/dcmtk/html" CACHE STRING "Installation sub-directory for HTML documentation.")
SET(DCMTK_INSTALL_MANDIR "share/man" CACHE STRING "Installation sub-directory for man pages.")
-MARK_AS_ADVANCED(DCMTK_INSTALL_BINDIR DCMTK_INSTALL_INCDIR DCMTK_INSTALL_LIBDIR DCMTK_INSTALL_ETCDIR
- DCMTK_INSTALL_DATDIR DCMTK_INSTALL_DOCDIR DCMTK_INSTALL_HTMDIR DCMTK_INSTALL_MANDIR)
+MARK_AS_ADVANCED(DCMTK_INSTALL_BINDIR DCMTK_INSTALL_INCDIR DCMTK_INSTALL_LIBDIR DCMTK_INSTALL_CMKDIR
+ DCMTK_INSTALL_ETCDIR DCMTK_INSTALL_DATDIR DCMTK_INSTALL_DOCDIR DCMTK_INSTALL_HTMDIR
+ DCMTK_INSTALL_MANDIR)
+
+#-----------------------------------------------------------------------------
+# Build directories
+#-----------------------------------------------------------------------------
+SET(DCMTK_BUILD_CMKDIR ${CMAKE_BINARY_DIR})
+
+#-----------------------------------------------------------------------------
+# Clear DCMTKTargets.cmake
+#-----------------------------------------------------------------------------
+file(WRITE ${DCMTK_BUILD_CMKDIR}/DCMTKTargets.cmake "")
#-----------------------------------------------------------------------------
# Platform-independent settings
@@ -131,6 +147,11 @@ SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
+INCLUDE(CMake/CheckCMakeCommandExists.cmake)
+INCLUDE(CMakePackageConfigHelpers OPTIONAL)
+check_cmake_command_exists("configure_package_config_file")
+check_cmake_command_exists("write_basic_package_version_file")
+
#-----------------------------------------------------------------------------
# Platform-specific settings
#-----------------------------------------------------------------------------
View
114 CMakeLists.txt
@@ -12,57 +12,33 @@ INCLUDE(CMake/dcmtkPrepare.cmake NO_POLICY_SCOPE)
#-----------------------------------------------------------------------------
# Modules to be built
-SET(DCMTK_MODULES config ofstd oflog dcmdata dcmimgle dcmimage dcmjpeg dcmjpls dcmtls dcmnet dcmsr dcmsign dcmwlm dcmqrdb dcmpstat dcmrt doxygen
- CACHE STRING "List of modules that should be built.")
-MARK_AS_ADVANCED(DCMTK_MODULES)
+SET(DCMTK_MODULES ofstd oflog dcmdata dcmimgle
+ dcmimage dcmjpeg dcmjpls dcmtls dcmnet dcmsr
+ dcmsign dcmwlm dcmqrdb dcmpstat dcmrt)
#-----------------------------------------------------------------------------
# Include directories
#-----------------------------------------------------------------------------
+SET(DCMTK_INCLUDE_DIR ${DCMTK_BINARY_DIR}/config/include)
+FOREACH(inc ${DCMTK_MODULES})
+ LIST(APPEND DCMTK_INCLUDE_DIR ${DCMTK_SOURCE_DIR}/${inc}/include)
+ENDFOREACH(inc)
-SET(DCMTK_INCLUDE_DIR
- ${DCMTK_BINARY_DIR}/config/include
- ${DCMTK_SOURCE_DIR}/ofstd/include
- ${DCMTK_SOURCE_DIR}/oflog/include
- ${DCMTK_SOURCE_DIR}/dcmdata/include
- ${DCMTK_SOURCE_DIR}/dcmimgle/include
- ${DCMTK_SOURCE_DIR}/dcmimage/include
- ${DCMTK_SOURCE_DIR}/dcmjpeg/libijg8
- ${DCMTK_SOURCE_DIR}/dcmjpeg/libijg12
- ${DCMTK_SOURCE_DIR}/dcmjpeg/libijg16
- ${DCMTK_SOURCE_DIR}/dcmjpeg/include
- ${DCMTK_SOURCE_DIR}/dcmjpls/include
- ${DCMTK_SOURCE_DIR}/dcmnet/include
- ${DCMTK_SOURCE_DIR}/dcmpstat/include
- ${DCMTK_SOURCE_DIR}/dcmqrdb/include
- ${DCMTK_SOURCE_DIR}/dcmsign/include
- ${DCMTK_SOURCE_DIR}/dcmsr/include
- ${DCMTK_SOURCE_DIR}/dcmtls/include
- ${DCMTK_SOURCE_DIR}/dcmwlm/include
-)
INCLUDE_DIRECTORIES(${DCMTK_INCLUDE_DIR})
#-----------------------------------------------------------------------------
# Prepare osconfig.h
#-----------------------------------------------------------------------------
-# add the osconfig.h.in file
CONFIGURE_FILE(${DCMTK_SOURCE_DIR}/CMake/osconfig.h.in
- ${DCMTK_BINARY_DIR}/config/include/dcmtk/config/osconfig.h)
-
-#-----------------------------------------------------------------------------
-# Write current configuration to file (for external projects)
-#-----------------------------------------------------------------------------
-
-CONFIGURE_FILE(${DCMTK_SOURCE_DIR}/CMake/DCMTKConfig.cmake.in
- ${DCMTK_BINARY_DIR}/DCMTKConfig.cmake @ONLY)
+ ${DCMTK_BINARY_DIR}/config/include/dcmtk/config/osconfig.h)
#-----------------------------------------------------------------------------
# Start actual compilation tasks
#-----------------------------------------------------------------------------
# Recurse into subdirectories
-FOREACH(module ${DCMTK_MODULES})
+FOREACH(module config doxygen ${DCMTK_MODULES})
ADD_SUBDIRECTORY(${module})
ENDFOREACH(module)
INCLUDE(CMake/dcmtkAfterModules.cmake NO_POLICY_SCOPE)
@@ -81,7 +57,71 @@ INSTALL(FILES ANNOUNCE.${DCMTK_PACKAGE_VERSION_NUMBER} CHANGES.${DCMTK_PACKAGE_V
DESTINATION ${DCMTK_INSTALL_DOCDIR}
COMPONENT doc)
-# Install DCMTK's CMake configuration file
-INSTALL(FILES ${DCMTK_BINARY_DIR}/DCMTKConfig.cmake
- DESTINATION ${DCMTK_INSTALL_DATDIR}
- COMPONENT data)
+
+#-----------------------------------------------------------------------------
+# DCMTKConfig generation tasks
+#-----------------------------------------------------------------------------
+
+IF(HAVE_CONFIGURE_PACKAGE_CONFIG_FILE AND HAVE_WRITE_BASIC_PACKAGE_VERSION_FILE)
+
+# Configure 'DCMTKTargets.cmake' and 'DCMTKConfigVersion.cmake
+GET_PROPERTY(DCMTK_EXECUTABLE_TARGETS GLOBAL PROPERTY DCMTK_EXECUTABLE_TARGETS)
+EXPORT(TARGETS ${DCMTK_EXECUTABLE_TARGETS} APPEND FILE ${DCMTK_BUILD_CMKDIR}/DCMTKTargets.cmake)
+GET_PROPERTY(DCMTK_LIBRARY_TARGETS GLOBAL PROPERTY DCMTK_LIBRARY_TARGETS)
+EXPORT(TARGETS ${DCMTK_LIBRARY_TARGETS} APPEND FILE ${DCMTK_BUILD_CMKDIR}/DCMTKTargets.cmake)
+
+SET(dcmtk_config_version ${DCMTK_BUILD_CMKDIR}/DCMTKConfigVersion.cmake)
+write_basic_package_version_file(
+ ${dcmtk_config_version}
+ VERSION ${DCMTK_MAJOR_VERSION}.${DCMTK_MINOR_VERSION}.${DCMTK_BUILD_VERSION}
+ COMPATIBILITY SameMajorVersion)
+
+# Configure 'DCMTKConfig.cmake' for a build tree
+SET(DCMTK_CMKDIR_CONFIG ${DCMTK_BUILD_CMKDIR})
+SET(DCMTK_config_INCLUDE_DIR_CONFIG ${DCMTK_BINARY_DIR}/config/include/dcmtk/config)
+SET(INCLUDE_PATH_VARS DCMTK_config_INCLUDE_DIR_CONFIG)
+FOREACH(module ${DCMTK_MODULES})
+ SET(DCMTK_${module}_INCLUDE_DIR_CONFIG ${DCMTK_SOURCE_DIR}/${module}/include/dcmtk/${module})
+ list(APPEND INCLUDE_PATH_VARS DCMTK_${module}_INCLUDE_DIR_CONFIG)
+ENDFOREACH(module)
+SET(DCMTK_CONFIG_CODE "####### Expanded from \@DCMTK_CONFIG_CODE\@ #######\n")
+SET(DCMTK_CONFIG_CODE "${DCMTK_CONFIG_CODE}list(APPEND DCMTK_INCLUDE_DIRS \"${DCMTK_BINARY_DIR}/config/include\")\n")
+FOREACH(module ${DCMTK_MODULES})
+ SET(DCMTK_CONFIG_CODE "${DCMTK_CONFIG_CODE}list(APPEND DCMTK_INCLUDE_DIRS \"${DCMTK_SOURCE_DIR}/${module}/include\")\n")
+ENDFOREACH(module)
+SET(DCMTK_CONFIG_CODE "${DCMTK_CONFIG_CODE}##################################################")
+SET(dcmtk_config ${DCMTK_BUILD_CMKDIR}/DCMTKConfig.cmake)
+configure_package_config_file(
+ CMake/DCMTKConfig.cmake.in
+ ${dcmtk_config}
+ INSTALL_DESTINATION ${CMAKE_BINARY_DIR}
+ PATH_VARS DCMTK_CMKDIR_CONFIG ${INCLUDE_PATH_VARS}
+ NO_CHECK_REQUIRED_COMPONENTS_MACRO)
+
+# Configure 'DCMTKConfig.cmake' for an install tree
+SET(DCMTK_CMKDIR_CONFIG ${DCMTK_INSTALL_CMKDIR})
+SET(DCMTK_config_INCLUDE_DIR_CONFIG ${DCMTK_INSTALL_INCDIR}/dcmtk/config)
+SET(INCLUDE_PATH_VARS DCMTK_config_INCLUDE_DIR_CONFIG)
+FOREACH(module ${DCMTK_MODULES})
+ SET(DCMTK_${module}_INCLUDE_DIR_CONFIG ${DCMTK_INSTALL_INCDIR}/dcmtk/${module})
+ list(APPEND INCLUDE_PATH_VARS DCMTK_${module}_INCLUDE_DIR_CONFIG)
+ENDFOREACH(module)
+SET(DCMTK_CONFIG_CODE "####### Expanded from \@DCMTK_CONFIG_CODE\@ #######\n")
+SET(DCMTK_CONFIG_CODE "${DCMTK_CONFIG_CODE}list(APPEND DCMTK_INCLUDE_DIRS \"\${PACKAGE_PREFIX_DIR}/include\")\n")
+SET(DCMTK_CONFIG_CODE "${DCMTK_CONFIG_CODE}##################################################")
+SET(dcmtk_install_config ${CMAKE_BINARY_DIR}/CMakeFiles/DCMTKConfig.cmake)
+configure_package_config_file(
+ CMake/DCMTKConfig.cmake.in
+ ${dcmtk_install_config}
+ INSTALL_DESTINATION ${CMAKE_INSTALL_PREFIX}/${DCMTK_INSTALL_CMKDIR}
+ PATH_VARS DCMTK_CMKDIR_CONFIG ${INCLUDE_PATH_VARS}
+ NO_CHECK_REQUIRED_COMPONENTS_MACRO)
+
+# Install 'DCMTKTargets.cmake', 'DCMTKConfig.cmake' and 'DCMTKConfigVersion.cmake
+INSTALL(EXPORT DCMTKTargets FILE DCMTKTargets.cmake
+ DESTINATION ${DCMTK_INSTALL_CMKDIR} COMPONENT cmake)
+
+INSTALL(FILES ${dcmtk_install_config} ${dcmtk_config_version}
+ DESTINATION ${DCMTK_INSTALL_CMKDIR} COMPONENT cmake)
+
+ENDIF(HAVE_CONFIGURE_PACKAGE_CONFIG_FILE AND HAVE_WRITE_BASIC_PACKAGE_VERSION_FILE)

0 comments on commit f461865

Please sign in to comment.