`company-capf` incorrectly completes when Eshell is in the command position

[ethan-leba]

Describe the issue

When completing in the command position of Eshell, the completions will only list the most current segment of the path, but selecting the completion will replace the entire path.

Steps to reproduce

1. Open eshell
2. Type in /bin/ki
3. Press RET to company-complete it

Expected behavior

Expected completion to replace only the current segment of path.

M-x company-diag output

Emacs 28.1 (aarch64-apple-darwin21.3.0) of 2022-04-10 on MacBook-Pro.attlocal.net
Company 0.9.13

company-backends: (company-capf)

Used backend: company-capf
Value of c-a-p-f: (pcomplete-completions-at-point t)
Major mode: eshell-mode
Prefix: "/bin/ki"
Completions:
  #("kill" 0 4 (face (completions-common-part)))

Screenshots

[minad]

I believe this is a bug of the pcomplete backend used by Eshell since it also occurs if you use default completion or Corfu. I remember that I read about this bug somewhere before, either on the Emacs bug tracker or on the Company bug tracker but I don't find the issues right now. Maybe @dgutov knows more?

[dgutov]

Yes. Looks like it happens with the default completion at well.

C-M-i is bound to a different command in eshell-mode, but if you type /bin/ in eshell, follow it with M-x completion-at-point twice and then pick a completion in the displayed buffer, you will see the same result.

The next step is M-x report-emacs-bug. 🤷

[minad]

Found it! The issue was actually reported to Swiper a while ago.

Swiper issue: abo-abo/swiper#2879
Emacs upstream issue: https://debbugs.gnu.org/cgi/bugreport.cgi?bug=48995

[dgutov]

Thanks! I pinged the bug report. Though that's no guarantee of seeing it fixed, of course.

[minad]

It seems that this is an Emacs 28 regression, so it should be fixed even on that branch.

[dgutov]

Seems so. Though it's rather late for Emacs 28.1.

[ethan-leba]

Thanks for pinging the bug report! For anyone else running into this issue who's looking for a short term fix, putting the following in your config will do the trick, which is essentially reverting the commit which introduced the bug:

(defun eshell--complete-commands-list ()
  "Generate list of applicable, visible commands."
  (let ((filename (pcomplete-arg)) glob-name)
    (if (file-name-directory filename)
        (if eshell-force-execution
            (pcomplete-dirs-or-entries nil #'file-readable-p)
          (pcomplete-executables))
      (if (and (> (length filename) 0)
               (eq (aref filename 0) eshell-explicit-command-char))
          (setq filename (substring filename 1)
                pcomplete-stub filename
                glob-name t))
      (let* ((paths (eshell-get-path))
             (cwd (file-name-as-directory
                   (expand-file-name default-directory)))
             (path "") (comps-in-path ())
             (file "") (filepath "") (completions ()))
        ;; Go thru each path in the search path, finding completions.
        (while paths
          (setq path (file-name-as-directory
                      (expand-file-name (or (car paths) ".")))
                comps-in-path
                (and (file-accessible-directory-p path)
                     (file-name-all-completions filename path)))
          ;; Go thru each completion found, to see whether it should
          ;; be used.
          (while comps-in-path
            (setq file (car comps-in-path)
                  filepath (concat path file))
            (if (and (not (member file completions)) ;
                     (or (string-equal path cwd)
                         (not (file-directory-p filepath)))
                     (if eshell-force-execution
                         (file-readable-p filepath)
                       (file-executable-p filepath)))
                (setq completions (cons file completions)))
            (setq comps-in-path (cdr comps-in-path)))
          (setq paths (cdr paths)))
        ;; Add aliases which are currently visible, and Lisp functions.
        (pcomplete-uniquify-list
         (if glob-name
             completions
           (setq completions
                 (append (if (fboundp 'eshell-alias-completions)
                             (eshell-alias-completions filename))
                         (eshell-winnow-list
                          (mapcar
                           (lambda (name)
                             (substring name 7))
                           (all-completions (concat "eshell/" filename)
                                            obarray #'functionp))
                          nil '(eshell-find-alias-function))
                         completions))
           (append (and (or eshell-show-lisp-completions
                            (and eshell-show-lisp-alternatives
                                 (null completions)))
                        (all-completions filename obarray #'functionp))
                   completions)))))))

[mpereira]

@ethan-leba works great, thank you! This has been bugging me for so long.

[stardiviner]

@ethan-leba It works for me too. Thanks

[dgutov]

Looks like it's fixed in Emacs 29.