company-yasnippet and returning "" for prefix

[jojojames]

(defun company-yasnippet (command &optional arg &rest ignore)
  "`company-mode' backend for `yasnippet'."
  (interactive (list 'interactive))
  (cl-case command
    (interactive (company-begin-backend 'company-yasnippet))
    (prefix
     ;; Should probably use `yas--current-key', but that's bound to be slower.
     ;; How many trigger keys start with non-symbol characters anyway?
     (and (bound-and-true-p yas-minor-mode)
          (company-grab-symbol)))
    (annotation
     (concat
      (unless company-tooltip-align-annotations " -> ")
      (get-text-property 0 'yas-annotation arg)))
    (candidates (company-yasnippet--candidates arg))
    (no-cache t)
    (post-completion
     (let ((template (get-text-property 0 'yas-template arg))
           (prefix-offset (get-text-property 0 'yas-prefix-offset arg)))
       (yas-expand-snippet (yas--template-content template)
                           (- (point) (length arg) prefix-offset)
                           (point)
                           (yas--template-expand-env template))))))

It looks like for 'prefix case, company-yasnippet always returns at least "".

This is somewhat painful when setting minimum-prefix-length to 1 and after something like "." completion.

this.| triggers company-yasnippet because the prefix will be "" but I'm not sure I'll ever want yasnippet to trigger in that case.

Changing the function to be,

  (defun company-yasnippet (command &optional arg &rest ignore)
    "`company-mode' backend for `yasnippet'."
    (interactive (list 'interactive))
    (cl-case command
      (interactive (company-begin-backend 'company-yasnippet))
      (prefix
       ;; Should probably use `yas--current-key', but that's bound to be slower.
       ;; How many trigger keys start with non-symbol characters anyway?
       (and (bound-and-true-p yas-minor-mode)
            (let ((company-symbol (company-grab-symbol)))
              (if (string-equal company-symbol "")
                  nil
                company-symbol))))
      (annotation
       (concat
        (unless company-tooltip-align-annotations " -> ")
        (get-text-property 0 'yas-annotation arg)))
      (candidates (company-yasnippet--candidates arg))
      (no-cache t)
      (post-completion
       (let ((template (get-text-property 0 'yas-template arg))
             (prefix-offset (get-text-property 0 'yas-prefix-offset arg)))
         (yas-expand-snippet (yas--template-content template)
                             (- (point) (length arg) prefix-offset)
                             (point)
                             (yas--template-expand-env template))))))

lets me not see any yasnippet completions for the 'this.' case.

I'm not sure if this is a good approach though since I don't use manual completion and there may be a chance we want the "" prefix back from yasnippet?

This is, at the very least, a feature request to make this behavior configurable. I can do a pull request if this approach is acceptable.

[dgutov]

setting minimum-prefix-length to 1

this.| triggers company-yasnippet because the prefix will be ""

Why does this happen? The length of "" is 0, and that's lower than 1.

[jojojames]

I think completion triggers after typing the "." but it's not included in the prefix.

[dgutov]

That's probably because you have another backend in the same group that triggers it.

[jojojames]

Yup! It's part of a grouped backend.

[dgutov]

We could somehow filter out backends that don't report a long enough prefix inside company--multi-backend-adapter-candidates, but that would require maintaining separate caches for all backends in the group. Or getting rid of the cache altogether, leaving it up for each individual backend.

That would solve the problem in a general way.

As far as your proposed change goes, it's too personal, I think. You can just as well add an advice to it.

[jojojames]

Thanks! I'll go with the advice then.

[dgutov]

Check out the latest master, the behavior should be improved.