Skip to content
This repository
branch: master
Fetching contributors…

Cannot retrieve contributors at this time

file 468 lines (361 sloc) 10.97 kb
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468
if module isnt undefined
  { Anchor
    Content
    Group
    Block
    ScriptBlock
    If
    Else
    For
    While
    DoWhile
    Func
    Parameters
    Value
    Member
    Access
    Invoke
  } = require './tags'
  { Success
    success
    Failure
    failure
    NoMatch
  } = require './validation'

class Tokenizer

  WHITESPACE = /^[^\n\S]+/
  TRAILING_SPACES = /\s+$/

  ANCHOR = /^@/
  PARAMETERS = /^!\(/
  IF = /^if\s*\(/
  ELSE = /^\s*else\s*/
  FOR = /^for\s*\(/
  WHILE = /^while\s*\(/
  DO = /^do\s*\{/
  DO_WHILE = /^\s*while\s*\(/
  FUNC = /^function(?:\s+([$A-Za-z_\x7f-\uffff][$\w\x7f-\uffff]*))?\s*\(/
  GROUP = /^\s*\(/
  BLOCK = /^\s*\{/
  IDENTIFIER = /^[$A-Za-z_\x7f-\uffff][$\w\x7f-\uffff]*/
  MEMBER = /^\s*\./
  ACCESS = /^\s*\[/
  INVOKE = /^\s*\(/
  COMMENT = /^\*/

  
  tokenize: (source,options) ->
    source = "\n#{source}" if WHITESPACE.test source
    source = source.replace(/\r/g, '').replace(TRAILING_SPACES, '')
    @replace source, '@', @Anchor.bind(@)
  
  replace: (source, token, callback) ->
    results = []
    while (index = source.indexOf token) >= 0
      if index > 0
        results.push source[..index-1]
      source = source[index..]
      result = callback(source)
      if result?
        if result.success
          offset = result.offset
          source = source[offset..]
          results.push result.get()
        else
          throw result
    if source.length > 0
      results.push source
    results


  pair: (str,left,right) ->
    pairs = 0
    start = 0
    for c,i in str
      switch c
        when left
          pairs++
        when right
          pairs--
          if pairs == 0
            return i+1
    return 0

  
  Anchor: (chunk) ->
    return NoMatch unless chunk[0] == '@'
    
    start = 1
    chunk = chunk[start..]
    
    result =
      @Comment(chunk) or
      @Parameters(chunk) or
      @Escape(chunk) or
      @If(chunk) or
      @For(chunk) or
      @While(chunk) or
      @DoWhile(chunk) or
      @Func(chunk) or
      @Group(chunk) or
      @ScriptBlock(chunk) or
      @Value(chunk)
    
    if result?.success
      offset = start + result.offset
      value = new Anchor result.get()
      return success offset, value
    else
      return success 1, new Content('@')
    
    return result
  
  Comment: (chunk) ->
      return NoMatch unless match = COMMENT.exec chunk

      start = match[0].length
      match = chunk[start..].match /\*\@\s*/

      if not match?
        offset = start
        error = 'malformed comment'
        return failure offset, error
      
      offset = start + match.index + match[0].length
      value = new Content('')
      return success offset, value
  

  Parameters: (chunk) ->
    return NoMatch unless match = PARAMETERS.exec chunk

    start = match[0].length-1
    chunk = chunk[start...]
    end = @pair chunk, '(', ')'

    if end
      parameters = chunk[1...end-1].split(',').map (p)->p.trim()
      offset = start + end
      value = new Parameters parameters
      return success offset, value
    else
      offset = start
      error = 'malformed parameters'
      return failure offset, error

  Escape: (chunk) ->
    return NoMatch unless match = ANCHOR.exec chunk
    return success 1, new Content '@'
  
  
  Group: (chunk) ->
    return NoMatch unless match = GROUP.exec chunk

    start = match[0].length-1
    chunk = chunk[start...]
    end = @pair chunk, '(', ')'

    if not end
      offset = start
      error = 'malformed group'
      return failure offset, error

    offset = start + end
    value = new Group chunk[1...end-1]
    return success offset, value
  
  
  Block: (chunk) ->
    return NoMatch unless match = BLOCK.exec chunk

    start = match[0].length-1
    chunk = chunk[start...]
    end = @pair chunk, '{', '}'

    if not end
      offset = start
      error = 'malformed block'
      return failure offset, error
  
    chunk = chunk[1...end-1]
    results = @tokenize chunk
    
    content = []
    for result in results
      if not result or result.failure
        return result
      else if result.value?
        content.push result.value
      else
        content.push result
    
    offset = start+end
    value = new Block content
    return success offset, value
  

  ScriptBlock: (chunk) ->
    return NoMatch unless match = BLOCK.exec chunk

    start = match[0].length-1
    chunk = chunk[start...]
    end = @pair chunk, '{', '}'

    if not end
      offset = start
      error = 'malformed block'
      return failure offset, error

    offset = start+end
    value = new ScriptBlock chunk[1...end-1]
    return success offset, value
    
  
  Else: (chunk) ->
    return NoMatch unless match = ELSE.exec chunk

    start = match[0].length
    chunk = chunk[start..]
    block = @Block chunk
    
    if not block
      stmt = @If chunk
      if not stmt
        offset = start
        error = 'malformed else statement'
        return failure offset, error
      else if stmt.error
        return stmt.error
      else
        offset = start + stmt.offset
        value = new Else stmt.get()
        return success offset, value
    else
      offset = start + block.offset
      value = new Else block.get()
      return success offset, value
  

  If: (chunk) ->
    return NoMatch unless match = IF.exec chunk

    start = match[0].length-1
    chunk = chunk[start..]
    test = @Group chunk

    if not test or test.error
      offset = start
      error = 'malformed if condition'
      return failure offset, error, test
    
    chunk = chunk[test.offset..]
    block = @Block chunk
    
    if not block or block.error
      offset = start + test.offset
      error = 'malformed if block'
      return failure offset, error, block

    chunk = chunk[block.offset..]
    ifElse = @Else chunk

    if not ifElse
      offset = start + test.offset + block.offset
      value = new If test.get(), block.get()
      return success offset, value
    
    if ifElse.error
      offset = start + test.offset + block.offset + ifElse.offset
      error = ifElse.error
      return failure offset, error, ifElse
    
    offset = start + test.offset + block.offset + ifElse.offset
    value = new If test.get(), block.get(), ifElse.get()
    return success offset, value


  For: (chunk) ->
    return NoMatch unless match = FOR.exec chunk

    start = match[0].length-1
    chunk = chunk[start..]
    test = @Group(chunk)

    if not test or test.error
      offset = start
      error = 'malformed for condition'
      return failure offset, error, test
    
    chunk = chunk[test.offset..]
    block = @Block(chunk)

    if not block or block.error
      offset = start + test.offset
      error = 'malformed while block'
      return failure offset, error, block
    
    offset = start + test.offset + block.offset
    value = new For test.get(), block.get()
    return success offset, value
  

  While: (chunk) ->
    return NoMatch unless match = WHILE.exec chunk

    start = match[0].length-1
    chunk = chunk[start..]
    test = @Group chunk

    if not test or test.error
      offset = start
      error = 'malformed while condition'
      return failure offset, error, test
    
    chunk = chunk[test.offset..]
    block = @Block chunk

    if not block or block.error
      offset = start + test.offset
      error = 'malformed while block'
      return failure offset, error, block
    
    offset = start + test.offset + block.offset
    value = new While test.get(), block.get()
    return success offset, value
  

  DoWhile: (chunk) ->
    return NoMatch unless match = DO.exec chunk

    start = match[0].length-1
    chunk = chunk[start..]
    block = @Block chunk

    if not block or block.error
      offset = start
      error = 'malformed do block'
      return failure offset, error, block
    
    chunk = chunk[block.offset..]

    test =
      if whileMatch = DO_WHILE.exec chunk
        whileStart = whileMatch[0].length-1
        chunk = chunk[whileStart..]
        @Group chunk
      else
        NoMatch

    if not test or test.error
      offset = start + block.offset
      error = 'malformed do while condition'
      return failure offset, error, test
    
    offset = start + block.offset + whileStart + test.offset
    value = new DoWhile block.get(), test.get()
    return success offset, value
  
  
  Func: (chunk) ->
    return NoMatch unless match = FUNC.exec chunk

    start = match[0].length-1
    name = match[1]
    chunk = chunk[start..]
    args = @Group chunk

    if not args or args.error
      offset = start
      error = 'malformed function arguments'
      return failure offset, error, args
    
    chunk = chunk[args.offset..]
    block = @Block chunk

    if not block or block.error
      offset = start + args.offset
      error = 'malformed function block'
      return failure offset, error, block
    
    offset = start + args.offset + block.offset
    value = new Func name, args.get(), block.get()
    return success offset, value
  
  
  Value: (chunk) ->
    return NoMatch unless match = IDENTIFIER.exec chunk

    start = match[0].length
    chunk = chunk[start..]

    result =
      @Member(chunk) or
      @Access(chunk) or
      @Invoke(chunk)
    
    if not result
      offset = start
      value = new Value match[0]
      return success offset, value
    else if result.failure
      offset = start
      error = 'malformed value'
      return failure offset, error, result
    else
      offset = start + result.offset
      value = new Value match[0], result.get()
      return success offset, value
  

  Member: (chunk) ->
    return NoMatch unless match = MEMBER.exec chunk

    start = match[0].length
    chunk = chunk[start..]
    result = @Value(chunk)

    if not result or result.failure
      offset = start
      error = 'malformed member access'
      return failure offset, error, result
    
    offset = start + result.offset
    value = new Member result.get()
    return success offset, value


  Access: (chunk) ->
    return NoMatch unless match = ACCESS.exec chunk

    start = match[0].length-1
    chunk = chunk[start...]
    end = @pair chunk, '[', ']'

    if not end
      offset = start
      error = 'malformed array access'
      return failure offset, error
    
    results = @replace chunk[start+1...end-1], 'function', @Func.bind(@)
    
    offset = start + end
    value = new Access results
    return success offset, value
  

  Invoke: (chunk) ->
    return NoMatch unless match = INVOKE.exec chunk

    start = match[0].length-1
    chunk = chunk[start...]
    end = @pair chunk, '(', ')'

    if not end
      offset = start
      error = 'malformed group'
      return failure offset, error

    results = @replace chunk[start+1...end-1], 'function', @Func.bind(@)
    
    offset = start + end
    value = new Invoke results
    return success offset, value


if module isnt undefined
  module.exports = Tokenizer
Something went wrong with that request. Please try again.