CMake Error using lib/cmake/CURL/CURLConfig.cmake when statically linked with nghttp2, libssh2

[val-ms]

I did this

I built libcurl like this:

          cmake .. \
            -D CMAKE_BUILD_TYPE=Release \
            -D BUILD_LIBCURL_DOCS=OFF \
            -D CMAKE_POSITION_INDEPENDENT_CODE=ON \
            -D CURL_USE_OPENSSL=ON \
            -D OPENSSL_INCLUDE_DIR="{includes}" \
            -D OPENSSL_LIBRARIES="{libs}" \
            -D OPENSSL_CRYPTO_LIBRARY="{libs}/libcrypto.a" \
            -D OPENSSL_SSL_LIBRARY="{libs}/libssl.a" \
            -D ZLIB_INCLUDE_DIR="{includes}" \
            -D ZLIB_LIBRARY_RELEASE="{libs}/libz.a" \
            -D LIBSSH2_INCLUDE_DIR="{includes}" \
            -D LIBSSH2_LIBRARY="{libs}/libssh2.a" \
            -D USE_NGHTTP2=ON \
            -D NGHTTP2_INCLUDE_DIR="{includes}" \
            -D NGHTTP2_LIBRARY="{libs}/libnghttp2.a" \
            -D CMAKE_INSTALL_PREFIX="{install}" \
            -D BUILD_SHARED_LIBS=OFF \
            -D CMAKE_INSTALL_LIBDIR=lib \
            -D USE_LIBIDN2=OFF \
            -D CURL_USE_LIBPSL=OFF -D CURL_BROTLI=OFF -D CURL_ZSTD=OFF \
            -D BUILD_CURL_EXE=OFF

Please excuse the weird {libs} and {includes} variables. It's from my script. But you get the idea. Insert the prefix path for where I'm staging binaries.

I tried to build my software, allowing CMake's find_package(CURL) to use the CURLConfig.cmake file to gather dependencies.

I observe the following error from the find_package(CURL) call:

CMake Error at /Users/val/.mussels/install/host-static/lib/cmake/CURL/CURLConfig.cmake:190 (get_target_property):
  get_target_property() called with non-existent target "CURL::libssh2".
Call Stack (most recent call first):
  CMakeLists.txt:550 (find_package)


CMake Error at /Users/val/.mussels/install/host-static/lib/cmake/CURL/CURLConfig.cmake:190 (get_target_property):
  get_target_property() called with non-existent target "CURL::nghttp2".
Call Stack (most recent call first):
  CMakeLists.txt:550 (find_package)

I tried adding these arguments, but it didn't help, because finding the static libs isn't the issue. Some CMake code is trying to use CURL::libssh2 and CURL::nghttp2 which aren't defined because they're statically linked into CURL::libcurl.

I expected the following

The same build worked okay when using Curl 8.17.0.

curl/libcurl version

curl 8.18.0

operating system

Darwin VALSNYDE-M-X7VX 25.3.0 Darwin Kernel Version 25.3.0: Wed Jan 28 20:48:41 PST 2026; root:xnu-12377.81.4~5/RELEASE_ARM64_T6041 arm64

Linux DESKTOP-N3L21K2 6.6.87.2-microsoft-standard-WSL2 #1 SMP PREEMPT_DYNAMIC Thu Jun 5 18:30:46 UTC 2025 x86_64 x86_64 x86_64 GNU/Linux

Strangely, I only observed the issue with libssh2 on Ubuntu, but I see it with both libssh2 and libnghttp2 on macOS.

[vszakats]

Thanks for your report. Can you post the content of
/Users/.../install/host-static/lib/cmake/CURL/CURLConfig.cmake?

(edit: if my assumption below sounds accurate, this isn't necessary)

[vszakats]

I have a faint guess of what may be happening: since these dependencies
are manually configured at curl-build time, cmake-config may not be auto-detecting
them at consumption time, hence the error.

One solution is to rely on auto-detection at curl-build time, which should also
work at consumption time.

Or, keep building curl the same way, but include the manual libssh2, nghttp2
configuration settings at consumption time also.

edit: The latter may already be the requirement for OpenSSL and ZLIB in
8.17.0 and earlier. With 8.18.0, all the dependencies work like those.

[vszakats]

@val-ms Do you see a change/improvement in the error message with this patch applied?: #20737

[val-ms]

@vszakats thank you for the fast reply and fast work. It took me a bit to figure out how to get my build tooling to pull your branch, and then build my project using that. But I got it. It failed a little later at the end of the cmake configure step instead of immediately when it calls find_package(CURL). The error was:

-- Configuring done (28.2s)
CMake Error at /Users/val/.mussels/install/host-static/lib/cmake/CURL/CURLTargets.cmake:61 (set_target_properties):
  The link interface of target "CURL::libcurl_static" contains:

    CURL::libssh2

  but the target was not found.  Possible reasons include:

    * There is a typo in the target name.
    * A find_package call is missing for an IMPORTED target.
    * An ALIAS target is missing.

Call Stack (most recent call first):
  /Users/val/.mussels/install/host-static/lib/cmake/CURL/CURLConfig.cmake:183 (include)
  CMakeLists.txt:550 (find_package)

As requested, the original CURLConfig.cmake file (before your PR) contained:

#***************************************************************************
#                                  _   _ ____  _
#  Project                     ___| | | |  _ \| |
#                             / __| | | | |_) | |
#                            | (__| |_| |  _ <| |___
#                             \___|\___/|_| \_\_____|
#
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
#
# This software is licensed as described in the file COPYING, which
# you should have received as part of this distribution. The terms
# are also available at https://curl.se/docs/copyright.html.
#
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
# copies of the Software, and permit persons to whom the Software is
# furnished to do so, under the terms of the COPYING file.
#
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
# KIND, either express or implied.
#
# SPDX-License-Identifier: curl
#
###########################################################################

####### Expanded from @PACKAGE_INIT@ by configure_package_config_file() #######
####### Any changes to this file will be overwritten by the next CMake run ####
####### The input file was curl-config.in.cmake                            ########

get_filename_component(PACKAGE_PREFIX_DIR "${CMAKE_CURRENT_LIST_DIR}/../../../" ABSOLUTE)

macro(set_and_check _var _file)
  set(${_var} "${_file}")
  if(NOT EXISTS "${_file}")
    message(FATAL_ERROR "File or directory ${_file} referenced by variable ${_var} does not exist !")
  endif()
endmacro()

macro(check_required_components _NAME)
  foreach(comp ${${_NAME}_FIND_COMPONENTS})
    if(NOT ${_NAME}_${comp}_FOUND)
      if(${_NAME}_FIND_REQUIRED_${comp})
        set(${_NAME}_FOUND FALSE)
      endif()
    endif()
  endforeach()
endmacro()

####################################################################################

option(CURL_USE_PKGCONFIG "Enable pkg-config to detect CURL dependencies. Default: ON"
  "ON")

if(CMAKE_VERSION VERSION_LESS 3.7)
  message(STATUS "CURL: CURL-specific Find modules require "
    "CMake 3.7 or upper, found: ${CMAKE_VERSION}.")
endif()

include(CMakeFindDependencyMacro)

if("ON")
  if("3")
    find_dependency(OpenSSL "3")
  else()
    find_dependency(OpenSSL)
  endif()
endif()
if("ON")
  find_dependency(ZLIB "1")
endif()

set(_curl_cmake_module_path_save ${CMAKE_MODULE_PATH})
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR} ${CMAKE_MODULE_PATH})

set(_curl_libs "")

if("OFF")
  find_dependency(Brotli)
  list(APPEND _curl_libs CURL::brotli)
endif()
if("")
  find_dependency(Cares)
  list(APPEND _curl_libs CURL::cares)
endif()
if("")
  find_dependency(GSS)
  list(APPEND _curl_libs CURL::gss)
endif()
if("")
  find_dependency(Libbacktrace)
  list(APPEND _curl_libs CURL::libbacktrace)
endif()
if("")
  find_dependency(Libgsasl)
  list(APPEND _curl_libs CURL::libgsasl)
endif()
if(NOT "" AND NOT "OFF")
  find_dependency(LDAP)
  list(APPEND _curl_libs CURL::ldap)
endif()
if("OFF")
  find_dependency(Libidn2)
  list(APPEND _curl_libs CURL::libidn2)
endif()
if("OFF")
  find_dependency(Libpsl)
  list(APPEND _curl_libs CURL::libpsl)
endif()
if("OFF")
  find_dependency(Librtmp)
  list(APPEND _curl_libs CURL::librtmp)
endif()
if("")
  find_dependency(Libssh)
  list(APPEND _curl_libs CURL::libssh)
endif()
if("ON")
  find_dependency(Libssh2)
  list(APPEND _curl_libs CURL::libssh2)
endif()
if("")
  find_dependency(Libuv)
  list(APPEND _curl_libs CURL::libuv)
endif()
if("")
  find_dependency(MbedTLS)
  list(APPEND _curl_libs CURL::mbedtls)
endif()
if("ON")
  find_dependency(NGHTTP2)
  list(APPEND _curl_libs CURL::nghttp2)
endif()
if("")
  find_dependency(NGHTTP3)
  list(APPEND _curl_libs CURL::nghttp3)
endif()
if("OFF")
  find_dependency(NGTCP2)
  list(APPEND _curl_libs CURL::ngtcp2)
endif()
if("")
  find_dependency(GnuTLS)
  list(APPEND _curl_libs CURL::gnutls)
  find_dependency(Nettle)
  list(APPEND _curl_libs CURL::nettle)
endif()
if("OFF")
  find_dependency(Quiche)
  list(APPEND _curl_libs CURL::quiche)
endif()
if("")
  find_dependency(Rustls)
  list(APPEND _curl_libs CURL::rustls)
endif()
if("")
  find_dependency(WolfSSL)
  list(APPEND _curl_libs CURL::wolfssl)
endif()
if("OFF")
  find_dependency(Zstd)
  list(APPEND _curl_libs CURL::zstd)
endif()

set(CMAKE_MODULE_PATH ${_curl_cmake_module_path_save})

if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND WIN32 AND NOT TARGET CURL::win32_winsock)
  add_library(CURL::win32_winsock INTERFACE IMPORTED)
  set_target_properties(CURL::win32_winsock PROPERTIES INTERFACE_LINK_LIBRARIES "ws2_32")
endif()

include("${CMAKE_CURRENT_LIST_DIR}/CURLTargets.cmake")

# Alias for either shared or static library
if(NOT TARGET CURL::libcurl)
  if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.11 AND CMAKE_VERSION VERSION_LESS 3.18)
    set_target_properties(CURL::libcurl_static PROPERTIES IMPORTED_GLOBAL TRUE)
  endif()
  add_library(CURL::libcurl ALIAS CURL::libcurl_static)
endif()

if(TARGET CURL::libcurl_static)
  # CMake before CMP0099 (CMake 3.17 2020-03-20) did not propagate libdirs to
  # targets. It expected libs to have an absolute filename. As a workaround,
  # manually apply dependency libdirs, for CMake consumers without this policy.
  if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.17)
    cmake_policy(GET CMP0099 _has_CMP0099)  # https://cmake.org/cmake/help/latest/policy/CMP0099.html
  endif()
  if(NOT _has_CMP0099 AND CMAKE_VERSION VERSION_GREATER_EQUAL 3.13 AND _curl_libs)
    set(_curl_libdirs "")
    foreach(_curl_lib IN LISTS _curl_libs)
      get_target_property(_curl_libdir "${_curl_lib}" INTERFACE_LINK_DIRECTORIES)
      if(_curl_libdir)
        list(APPEND _curl_libdirs "${_curl_libdir}")
      endif()
    endforeach()
    if(_curl_libdirs)
      target_link_directories(CURL::libcurl_static INTERFACE ${_curl_libdirs})
    endif()
  endif()
endif()

# For compatibility with CMake's FindCURL.cmake
set(CURL_VERSION_STRING "8.18.0")
set(CURL_LIBRARIES CURL::libcurl)
set(CURL_LIBRARIES_PRIVATE "/Users/val/.mussels/install/host-static/lib/libssh2.a;/Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX26.0.sdk/usr/lib/libldap.tbd;/Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX26.0.sdk/usr/lib/liblber.tbd;-framework SystemConfiguration;-framework CoreFoundation;-framework CoreServices;/Users/val/.mussels/install/host-static/lib/libssl.a;/Users/val/.mussels/install/host-static/lib/libcrypto.a;/Users/val/.mussels/install/host-static/lib/libz.a;/Users/val/.mussels/install/host-static/lib/libnghttp2.a")
set_and_check(CURL_INCLUDE_DIRS "${PACKAGE_PREFIX_DIR}/include")

set(CURL_SUPPORTED_PROTOCOLS "DICT;FILE;FTP;FTPS;GOPHER;GOPHERS;HTTP;HTTPS;IMAP;IMAPS;IPFS;IPNS;LDAP;LDAPS;MQTT;POP3;POP3S;RTSP;SCP;SFTP;SMB;SMBS;SMTP;SMTPS;TELNET;TFTP;WS;WSS")
set(CURL_SUPPORTED_FEATURES "alt-svc;AsynchDNS;HSTS;HTTP2;HTTPS-proxy;IPv6;Largefile;libz;NTLM;SSL;threadsafe;TLS-SRP;UnixSockets")

foreach(_curl_item IN LISTS CURL_SUPPORTED_PROTOCOLS CURL_SUPPORTED_FEATURES)
  set(CURL_SUPPORTS_${_curl_item} TRUE)
endforeach()

set(_curl_missing_req "")
foreach(_curl_item IN LISTS CURL_FIND_COMPONENTS)
  if(CURL_SUPPORTS_${_curl_item})
    set(CURL_${_curl_item}_FOUND TRUE)
  elseif(CURL_FIND_REQUIRED_${_curl_item})
    list(APPEND _curl_missing_req ${_curl_item})
  endif()
endforeach()

if(_curl_missing_req)
  string(REPLACE ";" " " _curl_missing_req "${_curl_missing_req}")
  if(CURL_FIND_REQUIRED)
    message(FATAL_ERROR "CURL: missing required components: ${_curl_missing_req}")
  endif()
  unset(_curl_missing_req)
endif()

check_required_components("CURL")

The same file after your PR looks like this:

#***************************************************************************
#                                  _   _ ____  _
#  Project                     ___| | | |  _ \| |
#                             / __| | | | |_) | |
#                            | (__| |_| |  _ <| |___
#                             \___|\___/|_| \_\_____|
#
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
#
# This software is licensed as described in the file COPYING, which
# you should have received as part of this distribution. The terms
# are also available at https://curl.se/docs/copyright.html.
#
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
# copies of the Software, and permit persons to whom the Software is
# furnished to do so, under the terms of the COPYING file.
#
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
# KIND, either express or implied.
#
# SPDX-License-Identifier: curl
#
###########################################################################

####### Expanded from @PACKAGE_INIT@ by configure_package_config_file() #######
####### Any changes to this file will be overwritten by the next CMake run ####
####### The input file was curl-config.in.cmake                            ########

get_filename_component(PACKAGE_PREFIX_DIR "${CMAKE_CURRENT_LIST_DIR}/../../../" ABSOLUTE)

macro(set_and_check _var _file)
  set(${_var} "${_file}")
  if(NOT EXISTS "${_file}")
    message(FATAL_ERROR "File or directory ${_file} referenced by variable ${_var} does not exist !")
  endif()
endmacro()

macro(check_required_components _NAME)
  foreach(comp ${${_NAME}_FIND_COMPONENTS})
    if(NOT ${_NAME}_${comp}_FOUND)
      if(${_NAME}_FIND_REQUIRED_${comp})
        set(${_NAME}_FOUND FALSE)
      endif()
    endif()
  endforeach()
endmacro()

####################################################################################

option(CURL_USE_PKGCONFIG "Enable pkg-config to detect CURL dependencies. Default: ON"
  "ON")

if(CMAKE_VERSION VERSION_LESS 3.7)
  message(STATUS "CURL: CURL-specific Find modules require "
    "CMake 3.7 or upper, found: ${CMAKE_VERSION}.")
endif()

include(CMakeFindDependencyMacro)

if("ON")
  if("3")
    find_dependency(OpenSSL "3")
  else()
    find_dependency(OpenSSL)
  endif()
  # Define lib duplicate to fixup lib order for GCC binutils ld in static builds
  if(TARGET OpenSSL::Crypto AND NOT TARGET CURL::OpenSSL_Crypto)
    add_library(CURL::OpenSSL_Crypto INTERFACE IMPORTED)
    get_target_property(_curl_libname OpenSSL::Crypto LOCATION)
    set_target_properties(CURL::OpenSSL_Crypto PROPERTIES INTERFACE_LINK_LIBRARIES "${_curl_libname}")
  endif()
endif()
if("ON")
  find_dependency(ZLIB "1")
  # Define lib duplicate to fixup lib order for GCC binutils ld in static builds
  if(TARGET ZLIB::ZLIB AND NOT TARGET CURL::ZLIB)
    add_library(CURL::ZLIB INTERFACE IMPORTED)
    get_target_property(_curl_libname ZLIB::ZLIB LOCATION)
    set_target_properties(CURL::ZLIB PROPERTIES INTERFACE_LINK_LIBRARIES "${_curl_libname}")
  endif()
endif()

set(_curl_cmake_module_path_save ${CMAKE_MODULE_PATH})
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR} ${CMAKE_MODULE_PATH})

set(_curl_libs "")

if("OFF")
  find_dependency(Brotli)
  list(APPEND _curl_libs CURL::brotli)
endif()
if("")
  find_dependency(Cares)
  list(APPEND _curl_libs CURL::cares)
endif()
if("")
  find_dependency(GSS)
  list(APPEND _curl_libs CURL::gss)
endif()
if("")
  find_dependency(Libbacktrace)
  list(APPEND _curl_libs CURL::libbacktrace)
endif()
if("")
  find_dependency(Libgsasl)
  list(APPEND _curl_libs CURL::libgsasl)
endif()
if(NOT "" AND NOT "OFF")
  find_dependency(LDAP)
  list(APPEND _curl_libs CURL::ldap)
endif()
if("OFF")
  find_dependency(Libidn2)
  list(APPEND _curl_libs CURL::libidn2)
endif()
if("OFF")
  find_dependency(Libpsl)
  list(APPEND _curl_libs CURL::libpsl)
endif()
if("OFF")
  find_dependency(Librtmp)
  list(APPEND _curl_libs CURL::librtmp)
endif()
if("")
  find_dependency(Libssh)
  list(APPEND _curl_libs CURL::libssh)
endif()
if("ON")
  find_dependency(Libssh2)
  list(APPEND _curl_libs CURL::libssh2)
endif()
if("")
  find_dependency(Libuv)
  list(APPEND _curl_libs CURL::libuv)
endif()
if("")
  find_dependency(MbedTLS)
  list(APPEND _curl_libs CURL::mbedtls)
endif()
if("ON")
  find_dependency(NGHTTP2)
  list(APPEND _curl_libs CURL::nghttp2)
endif()
if("")
  find_dependency(NGHTTP3)
  list(APPEND _curl_libs CURL::nghttp3)
endif()
if("OFF")
  find_dependency(NGTCP2)
  list(APPEND _curl_libs CURL::ngtcp2)
endif()
if("")
  find_dependency(GnuTLS)
  list(APPEND _curl_libs CURL::gnutls)
  find_dependency(Nettle)
  list(APPEND _curl_libs CURL::nettle)
endif()
if("OFF")
  find_dependency(Quiche)
  list(APPEND _curl_libs CURL::quiche)
endif()
if("")
  find_dependency(Rustls)
  list(APPEND _curl_libs CURL::rustls)
endif()
if("")
  find_dependency(WolfSSL)
  list(APPEND _curl_libs CURL::wolfssl)
endif()
if("OFF")
  find_dependency(Zstd)
  list(APPEND _curl_libs CURL::zstd)
endif()

set(CMAKE_MODULE_PATH ${_curl_cmake_module_path_save})

# Define lib duplicate to fixup lib order for GCC binutils ld in static builds
if(WIN32 AND NOT TARGET CURL::win32_winsock)
  add_library(CURL::win32_winsock INTERFACE IMPORTED)
  set_target_properties(CURL::win32_winsock PROPERTIES INTERFACE_LINK_LIBRARIES "ws2_32")
endif()

include("${CMAKE_CURRENT_LIST_DIR}/CURLTargets.cmake")

# Alias for either shared or static library
if(NOT TARGET CURL::libcurl)
  if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.11 AND CMAKE_VERSION VERSION_LESS 3.18)
    set_target_properties(CURL::libcurl_static PROPERTIES IMPORTED_GLOBAL TRUE)
  endif()
  add_library(CURL::libcurl ALIAS CURL::libcurl_static)
endif()

if(TARGET CURL::libcurl_static)
  # CMake before CMP0099 (CMake 3.17 2020-03-20) did not propagate libdirs to
  # targets. It expected libs to have an absolute filename. As a workaround,
  # manually apply dependency libdirs, for CMake consumers without this policy.
  if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.17)
    cmake_policy(GET CMP0099 _has_CMP0099)  # https://cmake.org/cmake/help/latest/policy/CMP0099.html
  endif()
  if(NOT _has_CMP0099 AND CMAKE_VERSION VERSION_GREATER_EQUAL 3.13 AND _curl_libs)
    set(_curl_libdirs "")
    foreach(_curl_lib IN LISTS _curl_libs)
      if(TARGET "${_curl_lib}")
        get_target_property(_curl_libdir "${_curl_lib}" INTERFACE_LINK_DIRECTORIES)
        if(_curl_libdir)
          list(APPEND _curl_libdirs "${_curl_libdir}")
        endif()
      endif()
    endforeach()
    if(_curl_libdirs)
      target_link_directories(CURL::libcurl_static INTERFACE ${_curl_libdirs})
    endif()
  endif()
endif()

# For compatibility with CMake's FindCURL.cmake
set(CURL_VERSION_STRING "8.19.0-DEV")
set(CURL_LIBRARIES CURL::libcurl)
set(CURL_LIBRARIES_PRIVATE "/Users/val/.mussels/install/host-static/lib/libssh2.a;/Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX26.0.sdk/usr/lib/libldap.tbd;/Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX26.0.sdk/usr/lib/liblber.tbd;-framework SystemConfiguration;-framework CoreFoundation;-framework CoreServices;/Users/val/.mussels/install/host-static/lib/libssl.a;/Users/val/.mussels/install/host-static/lib/libcrypto.a;/Users/val/.mussels/install/host-static/lib/libz.a;/Users/val/.mussels/install/host-static/lib/libnghttp2.a")
set_and_check(CURL_INCLUDE_DIRS "${PACKAGE_PREFIX_DIR}/include")

set(CURL_SUPPORTED_PROTOCOLS "DICT;FILE;FTP;FTPS;GOPHER;GOPHERS;HTTP;HTTPS;IMAP;IMAPS;IPFS;IPNS;LDAP;LDAPS;MQTT;MQTTS;POP3;POP3S;RTSP;SCP;SFTP;SMB;SMBS;SMTP;SMTPS;TELNET;TFTP;WS;WSS")
set(CURL_SUPPORTED_FEATURES "alt-svc;AsynchDNS;HSTS;HTTP2;HTTPS-proxy;IPv6;Largefile;libz;NTLM;SSL;threadsafe;TLS-SRP;UnixSockets")

foreach(_curl_item IN LISTS CURL_SUPPORTED_PROTOCOLS CURL_SUPPORTED_FEATURES)
  set(CURL_SUPPORTS_${_curl_item} TRUE)
endforeach()

set(_curl_missing_req "")
foreach(_curl_item IN LISTS CURL_FIND_COMPONENTS)
  if(CURL_SUPPORTS_${_curl_item})
    set(CURL_${_curl_item}_FOUND TRUE)
  elseif(CURL_FIND_REQUIRED_${_curl_item})
    list(APPEND _curl_missing_req ${_curl_item})
  endif()
endforeach()

if(_curl_missing_req)
  string(REPLACE ";" " " _curl_missing_req "${_curl_missing_req}")
  if(CURL_FIND_REQUIRED)
    message(FATAL_ERROR "CURL: missing required components: ${_curl_missing_req}")
  endif()
  unset(_curl_missing_req)
endif()

check_required_components("CURL")

[vszakats]

@val-ms Thank you for testing and the files/outputs. I'm going to merge the fix
as it's fixing an oversight and IMO improving the output.

Is it correct that you have to set these when building your application?:

            -D OPENSSL_INCLUDE_DIR="{includes}" \
            -D OPENSSL_LIBRARIES="{libs}" \
            -D OPENSSL_CRYPTO_LIBRARY="{libs}/libcrypto.a" \
            -D OPENSSL_SSL_LIBRARY="{libs}/libssl.a" \

or OPENSSL_ROOT_DIR?

Does it work to also set libssh2 and nghttp2 the same way?

The root issue is that at consumption-time libssh2 and nghttp2 is not found by
auto-detection, because the custom values used at curl-build time are missing
by then. With 8.18.0 this behavior applies to all dependencies, while in earlier
versions it only applied to OpenSSL and ZLIB.

[val-ms]

I am not sure that's the issue. Curl should be storing the values I provided via LIBSSH2_INCLUDE_DIR, LIBSSH2_LIBRARY, NGHTTP2_INCLUDE_DIR, and NGHTTP2_LIBRARY within the CURL::libssh2 and CURL::nghttp2 target. Instead, those targets appear to be missing in 8.18.0 when statically linked and so are effectively undefined variables when the CURL::libcurl_static link interface references them.

You're correct that I set OPENSSL_INCLUDE_DIR, OPENSSL_LIBRARIES, OPENSSL_CRYPTO_LIBRARY, and OPENSSL_SSL_LIBRARY when building my application as my application uses libcurl but also directly uses openssl. It does not directly use libssh2 or nghttp2, however, so our CMakeFile.txt wouldn't know what to do with those variables. If I try using them for my application build, I just see:

CMake Warning:
  Manually-specified variables were not used by the project:

    LIBSSH2_INCLUDE_DIR
    LIBSSH2_LIBRARY
    NGHTTP2_INCLUDE_DIR
    NGHTTP2_LIBRARY

[vszakats]

I am not sure that's the issue. Curl should be storing the values I provided via LIBSSH2_INCLUDE_DIR, LIBSSH2_LIBRARY, NGHTTP2_INCLUDE_DIR, and NGHTTP2_LIBRARY within the CURL::libssh2 and CURL::nghttp2 target. Instead, those targets appear to be missing in 8.18.0 when statically linked and so are effectively undefined variables when the CURL::libcurl_static link interface references them.

You're correct that I set OPENSSL_INCLUDE_DIR, OPENSSL_LIBRARIES, OPENSSL_CRYPTO_LIBRARY, and OPENSSL_SSL_LIBRARY when building my application as my application uses libcurl but also directly uses openssl. It does not directly use libssh2 or nghttp2, however, so our CMakeFile.txt wouldn't know what to do with those variables. If I try using them for my application build, I just see:

CMake Warning:
  Manually-specified variables were not used by the project:

    LIBSSH2_INCLUDE_DIR
    LIBSSH2_LIBRARY
    NGHTTP2_INCLUDE_DIR
    NGHTTP2_LIBRARY

Hm, I wonder what the difference may be between built-in OpenSSL/ZLIB
find modules and curl ones, which causes these variables being ignored.

What's supposed to happen is curl-config detecting these dependencies
(if set: by using the above variables) just like it's done at curl-build-time,
creating the CURL::* imported targets as a result, and satisfying their
references present in the list of dependencies.

The actual imported targets aren't exported as part of this config, neither
are the filenames/directories referenced by them.

(They are intentionally exported via the special CURL_LIBRARIES_PRIVATE
variable as an escape hatch, but it's probably not possible to read it without
going through dep detection successfully.)

[val-ms]

@vszakats This seems to fix it for me: #20764

I'm not sure if this breaks things in other build configurations. Maybe it is too heavy handed?

[vszakats]

@val-ms Wow, nice find! Do I understand correctly that MODULE is necessary
to make CMake actually use curl's own, distributed, Find modules? Without this
keyword, CMake may hit a cmake config file first, pick it up, and end up ignoring
the curl detection path, also leaving any custom LIBRARY/INCLUDE variables unused?

If so, I agree this is the solution.

Since this setup has been introduced in 8.18.0, with nothing similar before, this
isn't likely to break anyone's workflow. Also, the logic never intented to detect
and support cmake configs, and can't see how those could work.

[val-ms]

Yes that is my understanding, that without the MODULE keyword, CMake will prefer to use cmake config files installed by the library.

Something I discovered after creating #20764 is that I need the same change to correctly link with zlib. I know you already approved it, but may I add this to the PR?

diff --git a/CMake/curl-config.in.cmake b/CMake/curl-config.in.cmake
index 4e7c29fff6..87363fbd35 100644
--- a/CMake/curl-config.in.cmake
+++ b/CMake/curl-config.in.cmake
@@ -47,7 +47,7 @@ if("@USE_OPENSSL@")
   endif()
 endif()
 if("@HAVE_LIBZ@")
-  find_dependency(ZLIB "@ZLIB_VERSION_MAJOR@")
+  find_dependency(ZLIB "@ZLIB_VERSION_MAJOR@" MODULE)
   # Define lib duplicate to fixup lib order for GCC binutils ld in static builds
   if(TARGET ZLIB::ZLIB AND NOT TARGET CURL::ZLIB)
     add_library(CURL::ZLIB INTERFACE IMPORTED)