testcontainers-scala/build.gradle at 948f3ebcf9043ddf07e823d7fd9a831b1dbd080a · dimafeng/testcontainers-scala · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.12.0'
    }
}

plugins {
    id 'nebula.provided-base' version '3.0.3'
    id 'net.researchgate.release' version '2.4.0'
}

group 'com.dimafeng'

apply plugin: 'scala'
apply plugin: 'nebula.provided-base'
apply plugin: 'com.github.ben-manes.versions'
apply plugin: 'maven'
apply plugin: 'signing'


sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    compile("org.testcontainers:testcontainers:$testcontainersVersion")
    provided("org.scala-lang:scala-library:$scalaVersion",
            "org.seleniumhq.selenium:selenium-java:$seleniumVersion",
            "org.testcontainers:selenium:$testcontainersVersion",
            "org.slf4j:slf4j-simple:$slf4jVersion",
            "org.scalatest:scalatest_2.12:$scalaTestVersion",
            "org.testcontainers:mysql:$testcontainersVersion")

    testCompile("junit:junit:4.12",
            "org.scala-lang:scala-library:$scalaVersion",
            "org.testcontainers:selenium:$testcontainersVersion",
            "mysql:mysql-connector-java:$mysqlConnectorVersion",
            "org.mockito:mockito-all:$mockitoVersion")
}

test {
    exclude 'com/dimafeng/testcontainers/integration/**'
}

task integrationTest(type: Test) {
    include 'com/dimafeng/testcontainers/integration/**'
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from scaladoc
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    sign configurations.archives
}

ext.ossrhUsernameValue = project.hasProperty("ossrhUsername") ? project.getProperty("ossrhUsername") : ""
ext.ossrhPasswordValue = project.hasProperty("ossrhPassword") ? project.getProperty("ossrhPassword") : ""

/**
 * Skip signArchives for travis-ci
 */
tasks.each { task ->
    if (!project.hasProperty("ossrhPassword") && "signArchives".equals(task.name)) {
        task.enabled = false
    }
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsernameValue, password: ossrhPasswordValue)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsernameValue, password: ossrhPasswordValue)
            }

            pom.project {
                name 'testcontainers-scala'
                packaging 'jar'
                description 'Scala wrapper for testcontainers-java'
                url 'https://github.com/dimafeng/testcontainers-scala'

                scm {
                    connection 'scm:git:git@github.com:dimafeng/testcontainers-scala.git'
                    developerConnection 'scm:git:git@github.com:dimafeng/testcontainers-scala.git'
                    url 'git@github.com:dimafeng/testcontainers-scala.git'
                }

                licenses {
                    license {
                        name 'The MIT License (MIT)'
                        url 'https://opensource.org/licenses/MIT'
                    }
                }

                developers {
                    developer {
                        name 'Dmitry Fedosov'
                        email 'dimafeng@gmail.com'
                    }
                }
            }
        }
    }
}

uploadArchives.dependsOn integrationTest
afterReleaseBuild.dependsOn uploadArchives