Permalink
Switch branches/tags
ttn-vms-21-2-B4 ttn-vms-21-2-B3 ttn-vms-21-2-B2 mh-e-doc-8.5 mh-e-doc-8.4 mh-e-doc-8.3 mh-e-doc-8.2 mh-e-doc-8.1 mh-e-doc-8.0.3 mh-e-doc-8.0.1 mh-e-doc-8.0 mh-e-8.6 mh-e-8.5 mh-e-8.4 mh-e-8.3.1 mh-e-8.3 mh-e-8.2.93 mh-e-8.2.92 mh-e-8.2.91 mh-e-8.2.90 mh-e-8.2 mh-e-8.1 mh-e-8.0.3 mh-e-8.0.2 mh-e-8.0.1 mh-e-8.0 emacs-pretest-24.0.95 emacs-pretest-24.0.94 emacs-pretest-24.0.93 emacs-pretest-24.0.92 emacs-pretest-24.0.91 emacs-pretest-24.0.90 emacs-pretest-24.0.05 emacs-pretest-23.3.90 emacs-pretest-23.2.94 emacs-pretest-23.2.93.1 emacs-pretest-23.2.93 emacs-pretest-23.2.92 emacs-pretest-23.2.91 emacs-pretest-23.2.90 emacs-pretest-23.1.97 emacs-pretest-23.1.96 emacs-pretest-23.1.95 emacs-pretest-23.1.94 emacs-pretest-23.1.93 emacs-pretest-23.1.92 emacs-pretest-23.1.91 emacs-pretest-23.1.90 emacs-pretest-23.0.96 emacs-pretest-23.0.95 emacs-pretest-23.0.94 emacs-pretest-23.0.93 emacs-pretest-23.0.92 emacs-pretest-23.0.91 emacs-pretest-23.0.90 emacs-pretest-22.2.92 emacs-pretest-22.2.91 emacs-pretest-22.2.90 emacs-pretest-22.1.92 emacs-pretest-22.1.91 emacs-pretest-22.1.90 emacs-pretest-22.0.990 emacs-pretest-22.0.99 emacs-pretest-22.0.98 emacs-pretest-22.0.97 emacs-pretest-22.0.96 emacs-pretest-22.0.95 emacs-pretest-22.0.94 emacs-pretest-22.0.93 emacs-pretest-22.0.92 emacs-pretest-22.0.91 emacs-pretest-22.0.90 emacs-pretest-21.2.95 emacs-pretest-21.2.94 emacs-pretest-21.2.93 emacs-pretest-21.2.92 emacs-pretest-21.2.91 emacs-pretest-21.0.106 emacs-pretest-21.0.105 emacs-pretest-21.0.104 emacs-pretest-21.0.103 emacs-pretest-21.0.102 emacs-pretest-21.0.101 emacs-pretest-21.0.100 emacs-pretest-21.0.99 emacs-pretest-21.0.98 emacs-pretest-21.0.97 emacs-pretest-21.0.96 emacs-pretest-21.0.95 emacs-pretest-21.0.93 emacs-pretest-21.0.92 emacs-pretest-21.0.91 emacs-pretest-21.0.90 emacs-26.1 emacs-26.1-rc1 emacs-26.0.91 emacs-26.0.90 emacs-25.3 emacs-25.2 emacs-25.2-rc2
Nothing to show
Find file Copy path
Fetching contributors…
Cannot retrieve contributors at this time
151 lines (127 sloc) 5.18 KB
;;; let-alist.el --- Easily let-bind values of an assoc-list by their names -*- lexical-binding: t; -*-
;; Copyright (C) 2014-2018 Free Software Foundation, Inc.
;; Author: Artur Malabarba <emacs@endlessparentheses.com>
;; Package-Requires: ((emacs "24.1"))
;; Version: 1.0.5
;; Keywords: extensions lisp
;; Prefix: let-alist
;; Separator: -
;; This is an Elpa :core package. Don't use functionality that is not
;; compatible with Emacs 24.1.
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;; This package offers a single macro, `let-alist'. This macro takes a
;; first argument (whose value must be an alist) and a body.
;;
;; The macro expands to a let form containing body, where each dotted
;; symbol inside body is let-bound to their cdrs in the alist. Dotted
;; symbol is any symbol starting with a `.'. Only those present in
;; the body are let-bound and this search is done at compile time.
;;
;; For instance, the following code
;;
;; (let-alist alist
;; (if (and .title .body)
;; .body
;; .site
;; .site.contents))
;;
;; essentially expands to
;;
;; (let ((.title (cdr (assq 'title alist)))
;; (.body (cdr (assq 'body alist)))
;; (.site (cdr (assq 'site alist)))
;; (.site.contents (cdr (assq 'contents (cdr (assq 'site alist))))))
;; (if (and .title .body)
;; .body
;; .site
;; .site.contents))
;;
;; If you nest `let-alist' invocations, the inner one can't access
;; the variables of the outer one. You can, however, access alists
;; inside the original alist by using dots inside the symbol, as
;; displayed in the example above by the `.site.contents'.
;;
;;; Code:
(defun let-alist--deep-dot-search (data)
"Return alist of symbols inside DATA that start with a `.'.
Perform a deep search and return an alist where each car is the
symbol, and each cdr is the same symbol without the `.'."
(cond
((symbolp data)
(let ((name (symbol-name data)))
(when (string-match "\\`\\." name)
;; Return the cons cell inside a list, so it can be appended
;; with other results in the clause below.
(list (cons data (intern (replace-match "" nil nil name)))))))
((not (consp data)) nil)
((eq (car data) 'let-alist)
;; For nested ‘let-alist’ forms, ignore symbols appearing in the
;; inner body because they don’t refer to the alist currently
;; being processed. See Bug#24641.
(let-alist--deep-dot-search (cadr data)))
(t (append (let-alist--deep-dot-search (car data))
(let-alist--deep-dot-search (cdr data))))))
(defun let-alist--access-sexp (symbol variable)
"Return a sexp used to access SYMBOL inside VARIABLE."
(let* ((clean (let-alist--remove-dot symbol))
(name (symbol-name clean)))
(if (string-match "\\`\\." name)
clean
(let-alist--list-to-sexp
(mapcar #'intern (nreverse (split-string name "\\.")))
variable))))
(defun let-alist--list-to-sexp (list var)
"Turn symbols LIST into recursive calls to `cdr' `assq' on VAR."
`(cdr (assq ',(car list)
,(if (cdr list) (let-alist--list-to-sexp (cdr list) var)
var))))
(defun let-alist--remove-dot (symbol)
"Return SYMBOL, sans an initial dot."
(let ((name (symbol-name symbol)))
(if (string-match "\\`\\." name)
(intern (replace-match "" nil nil name))
symbol)))
;;; The actual macro.
;;;###autoload
(defmacro let-alist (alist &rest body)
"Let-bind dotted symbols to their cdrs in ALIST and execute BODY.
Dotted symbol is any symbol starting with a `.'. Only those present
in BODY are let-bound and this search is done at compile time.
For instance, the following code
(let-alist alist
(if (and .title .body)
.body
.site
.site.contents))
essentially expands to
(let ((.title (cdr (assq \\='title alist)))
(.body (cdr (assq \\='body alist)))
(.site (cdr (assq \\='site alist)))
(.site.contents (cdr (assq \\='contents (cdr (assq \\='site alist))))))
(if (and .title .body)
.body
.site
.site.contents))
If you nest `let-alist' invocations, the inner one can't access
the variables of the outer one. You can, however, access alists
inside the original alist by using dots inside the symbol, as
displayed in the example above."
(declare (indent 1) (debug t))
(let ((var (make-symbol "alist")))
`(let ((,var ,alist))
(let ,(mapcar (lambda (x) `(,(car x) ,(let-alist--access-sexp (car x) var)))
(delete-dups (let-alist--deep-dot-search body)))
,@body))))
(provide 'let-alist)
;;; let-alist.el ends here