Project 1-1 Grammar Definition

* 각 토큰 사이는 1개 이상의 공백(빈칸, 줄바꿈, 탭 등)으로 구분됨
* [<TOKEN>] 은 <TOKEN>이 있어도 없어도 됨을 의미함
* (<TOKEN>)\* 은 <TOKEN>이 0회 이상 반복됨을 의미함
* (<TOKEN>)+ 은 <TOKEN>이 1회 이상 반복됨을 의미함
* 빨간색 굵은 글씨로 된 키워드들(select, from, create, table 등)은 <LEGAL IDENTIFIER>가 될 수 없음
* 키워드들은 case insensitive함. 즉 select, SELECT, SeLeCt 등이 모두 허용됨
* exit <SEMICOLON>은 프로그램 종료 처리
* 꼭 아래의 문법 대로 구현할 필요는 없지만, 아래의 문법을 지키지 않은 질의들은 Syntax error로 처리되어야 함

**1. QUERY**

<COMMAND> ::= <QUERY LIST>

| **exit** <SEMICOLON>

<QUERY LIST> ::= (<QUERY> <SEMICOLON>)+

<QUERY> ::= <CREATE TABLE QUERY>

| <DROP TABLE QUERY>

| <DESC QUERY>

| <SELECT QUERY>

| <INSERT QUERY>

| <DELETE QUERY>

| <SHOW TABLES QUERY>

<SEMICOLON> ::= ;

**2. CREATE TABLE**

<CREATE TABLE QUERY> ::= **create table** <TABLE NAME> <TABLE ELEMENT LIST>

<TABLE ELEMENT LIST> ::= <LEFT PAREN> <TABLE ELEMENT> (<COMMA> <TABLE ELEMENT>)\* <RIGHT PAREN>

<TABLE ELEMENT> ::= <COLUMN DEFINITION>

| <TABLE CONSTRAINT DEFINITION>

<COLUMN DEFINITION> ::= <COLUMN NAME> <DATA TYPE> [**not null**]

<TABLE CONSTRAINT DEFINITION> ::= <PRIMARY KEY CONSTRAINT>

| <REFERENTIAL CONSTRAINT>

<PRIMARY KEY CONSTRAINT> ::= **primary key** <COLUMN NAME LIST>

<REFERENTIAL CONSTRAINT> ::= **foreign key** <COLUMN NAME LIST> **references** <TABLE NAME> <COLUMN NAME LIST>

<COLUMN NAME LIST> ::= <LEFT PAREN> <COLUMN NAME> (<COMMA> <COLUMN NAME>)\* <RIGHT PAREN>

<DATA TYPE> ::= **int**

| **char** <LEFT PAREN> <INT VALUE> <RIGHT PAREN>

| **date**

<TABLE NAME> ::= <LEGAL IDENTIFIER>

<COLUMN NAME> ::= <LEGAL IDENTIFIER>

<LEGAL IDENTIFIERS> ::= <ALPHABET> (<ALPHABET> | <UNDERSCORE>)\*

<UNDERSCORE> ::= \_

<LEFT PAREN> ::= (

<RIGHT PAREN> ::= )

<COMMA> ::= ,

**3. DROP TABLE / DESC / SHOW TABLES**

<DROP TABLE QUERY> ::= **drop table** <TABLE NAME>

<DESC QUERY> ::= **desc** <TABLE NAME>

<SHOW TABLES QUERY> ::= **show tables**

**4. SELECT**

<SELECT QUERY> ::= **select** <SELECT LIST> <TABLE EXPRESSION>

<SELECT LIST> ::= **\***

| <SELECTED COLUMN> (<COMMA> <SELECTED COLUMN>)\*

<SELECTED COLUMN> ::= [<TABLE NAME> <PERIOD>] <COLUMN NAME> [**as** <COLUMN NAME>]

<PERIOD> ::= .

<TABLE EXPRESSION> ::= <FROM CLAUSE> [<WHERE CLAUSE>]

<FROM CLAUSE> ::= **from** <TABLE REFERENCE LIST>

<TABLE REFERENCE LIST> ::= <REFERED TABLE> (<COMMA> <REFERED TABLE>)\*

<REFERED TABLE> ::= <TABLE NAME> [**as** <TABLE NAME>]

<WHERE CLAUSE> ::= **where** <BOOLEAN VALUE EXPRESSION>

<BOOLEAN VALUE EXPRESSION> ::= <BOOLEAN TERM> ( **or** <BOOLEAN TERM>)\*

<BOOLEAN TERM> ::= <BOOLEAN FACTOR>( and <BOOLEAN FACTOR> )\*

<BOOLEAN FACTOR> ::= [**not**] <BOOLEAN TEST>

<BOOLEAN TEST> ::= <PREDICATE>

| <PARENTHESIZED BOOLEAN EXPRESSION>

<PARENTHESIZED BOOLEAN EXPRESSION> ::= <LEFT PAREN> <BOOLEAN VALUE EXPRESSION> <RIGHT PAREN>

<PREDICATE> ::= <COMPARISON PREDICATE>

| <NULL PREDICTE>

<COMPARISON PREDICATE> ::= <COMP OPERAND> <COMP OP> <COMP OPERAND>

<COMP OPERAND> ::= <COMPARABLE VALUE>

| [<TABLE NAME> <PERIOD>] <COLUMN NAME>

<COMP OP> ::= < | > | = | >= | <= | !=

<COMPARABLE VALUE> ::= <INT VALUE>

| <CHAR STRING>

| <DATE VALUE>

<NULL PREDICATE> ::= [<TABLE NAME> <PERIOD>] <COLUMN NAME> <NULL OPERATION>

<NULL OPERATION> ::= **is** [**not**] **null**

**5. INSERT / DELETE**

<INSERT QUERY> ::= **insert into** <TABLE NAME> <INSERT COLUMNS AND SOURCE>

<INSERT COLUMNS AND SOURCE> ::= [<COLUMN NAME LIST>] <VALUE LIST>

<VALUE LIST> ::= **values** <LEFT PAREN> <VALUE> (<COMMA> <VALUE>)\* <RIGHT PAREN>

<VALUE> ::= **null**

| <COMPARABLE VALUE>

<DELETE QUERY> ::= **delete from** <TABLE NAME> [<WHERE CLAUSE>]

**6. TOKENS**

<CHAR STRING> ::= <QUOTE> (<NON QUOTE CHARACTER>)\* <QUOTE>

<INT VALUE> ::= [<SIGN>] (<DIGIT>)+

<DIGIT> ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9

<SIGN> ::= + | -

<DATE VALUE> ::= <NNNN> - <NN> - <NN>

<NNNN> ::= <DIGIT> <DIGIT> <DIGIT> <DIGIT>

<NN> ::= <DIGIT> <DIGIT>

<NON QUOTE CHARACTER> ::= <DIGIT>

| <ALPHABET>

| <NON QUOTE SPECIAL CHARACTERS>

| <SPACE>

<QUOTE> ::= ‘

<NON QUOTE SPECIAL CHARACTERS> ::= 키보드에서 입력 가능한 특수 문자들 중 따옴표(‘ and ”) 제외한 전부 (!, @, #, $ 등)

<ALPHABET> ::= 영문 알파벳 소문자, 대문자 전부

<SPACE> ::= 스페이스 한 칸 공백