Stratifying an SIR model by risk group using AlgebraicPetri.jl

Simon Frost (@sdwfrost)

2023-06-13

## Introduction

This example serves as a ‘Hello World’ to stratifying Petri net models, where a coarse model is stratified by another model - in this case, two risk groups, H and L, with high and low contact rates respectively.


## Libraries

using AlgebraicPetri,AlgebraicPetri.TypedPetri  
using Catlab, Catlab.CategoricalAlgebra, Catlab.Programs  
using Catlab.WiringDiagrams, Catlab.Graphics  
using AlgebraicDynamics.UWDDynam  
using OrdinaryDiffEq  
using LabelledArrays  
using Plots

## Transitions

We first define a labelled Petri net that has the different types of transition in our models. The first argument is an array of state names as symbols (here, a generic :Pop), followed by the transitions in the model. Transitions are given as transition\_name=>((input\_states)=>(output\_states)). In this model, we consider the groups as fixed (i.e. no changes between strata), so we just need to have infection and recovery in the model.

epi\_transitions = LabelledPetriNet(  
 [:Pop],  
 :infection=>((:Pop, :Pop)=>(:Pop, :Pop)),  
 :recovery=>(:Pop=>:Pop)  
)  
to\_graphviz(epi\_transitions)




We create a labelled Petri net of the SIR model using the above transitions (or alternatively, we could compose from infection and recovery submodels).

sir\_uwd = @relation () where (S::Pop, I::Pop, R::Pop) begin  
 infection(S, I, I, I)  
 recovery(I, R)  
end  
sir\_acst = oapply\_typed(epi\_transitions, sir\_uwd, [:β , :γ])  
sir\_lpn = dom(sir\_acst)  
to\_graphviz(sir\_lpn)




We then define a second model with two groups with different contact rates. This also has infection and recovery terms defined in terms of within- and between-group interactions.

risk\_uwd = @relation () where (H::Pop, L::Pop) begin  
 infection(H,H,H,H) # Within H infection  
 infection(H,L,H,L) # Infection of S\_H by I\_L  
 infection(L,H,L,H) # Infection of S\_L by I\_H  
 infection(L,L,L,L) # Within L infection  
 recovery(H,H) # H recovery  
 recovery(L,L) # L recovery  
end  
risk\_acst = oapply\_typed(epi\_transitions, risk\_uwd, [:HH, :HL, :LH, :LL, :H, :L])  
risk\_lpn = dom(risk\_acst)  
to\_graphviz(risk\_lpn)



We create a stratified model by using a typed product between the SIR model and the risk model, to generate an ACSetTransformation, from which we subsequently extract a labelled Petri net.

sir\_risk\_acst = typed\_product(sir\_acst, risk\_acst)  
sir\_risk\_lpn = dom(sir\_risk\_acst)  
to\_graphviz(sir\_risk\_lpn)




The state names of the resulting stratified model are tuples of symbols:

snames(sir\_risk\_lpn)

6-element Vector{Tuple{Symbol, Symbol}}:  
 (:S, :H)  
 (:I, :H)  
 (:R, :H)  
 (:S, :L)  
 (:I, :L)  
 (:R, :L)

The solvers in OrdinaryDiffEq.jl do not work with these state names, so we use flatten\_labels to obtain a vector of symbols (of the form :S\_H, :I\_H, etc.).

sir\_risk\_lpn\_flatlabels = flatten\_labels(sir\_risk\_lpn)  
to\_graphviz(sir\_risk\_lpn\_flatlabels)



## Running the model

To run the model, we need to choose specific group sizes and parameter values. We define two groups of equal size and initial composition.

K = 2  
S = [495.0, 495.0]  
I = [5.0, 5.0]  
R = [0.0, 0.0]  
N = [S[i]+I[i]+R[i] for i in 1:K]

2-element Vector{Float64}:  
 500.0  
 500.0

The model above is defined in terms of transmission rates between the two groups, which is a combination of (a) the contact rates between the two groups and (b) the probability of transmission per infectious contact. We assume that the two groups have different overall contact rates, c, and that the fraction of contacts between groups i and j, pij, follows a proportional mixing assumption.

β = 0.05  
c = [20.0, 5.0]  
pij = hcat([[c[j]\*N[j]/sum([c[k]\*N[k] for k in 1:K]) for j in 1:K] for i in 1:K]...)'  
betas = (β .\* (c .\* pij) ./ N)  
γ = 0.25;

We now define the initial conditions and parameter arrays as labelled arrays.

u0 = @LArray vec([S I R]')[:,1] Tuple(snames(sir\_risk\_lpn\_flatlabels))  
p = @LArray [vec(betas); γ; γ] Tuple(tnames(sir\_risk\_lpn\_flatlabels))  
tspan = (0.0, 40.0);

We then compute the vector field from the labelled Petri net (with flatten labels), define the ODEProblem, and solve.

sir\_risk\_vf = vectorfield(sir\_risk\_lpn\_flatlabels)  
sir\_risk\_prob = ODEProblem(sir\_risk\_vf, u0, tspan, p)  
sir\_risk\_sol = solve(sir\_risk\_prob, Rosenbrock32());

## Plotting

plot(sir\_risk\_sol, linecolor=[:blue :red :green], linestyle=[:solid :solid :solid :dash :dash :dash])

