Lockdown optimisation on an SIR model using JuMP.jl

Simon Frost (@sdwfrost) and Sandra Montes (@slmontes)

2025-03-10

Initial version [here](https://github.com/epirecipes/sir-julia/blob/master/markdown/function_map_lockdown_jump/function_map_lockdown_jump.md) by Simon Frost (@sdwfrost)  
Current version Sandra Montes (@slmontes), 2025-03-10

## Introduction

This example explores the optimal control of an SIR (Susceptible-Infected-Recovered) model using a time-varying intervention that reduces the infection rate. The population is divided into three categories: susceptible individuals (S), infected individuals (I), and the total number of cases (C). The intervention is modelled as a time-dependent control variable υ(t) that reduces the transmission rate by a factor of 1 - υ(t). The goal is to determine the optimal timing and application of this intervention to minimise the final number of cases (C) under the following constraints: (a) υ cannot exceed a maximum value, and (b) the total cost, measured as the integral of υ over time, must remain within a specified limit.

The model is described by the following differential equations:

Here, β is the transmission rate, and γ is the recovery rate.

In a study by [Britton and Leskela (2022)](https://epubs.siam.org/doi/10.1137/22M1504433), it was demonstrated that the optimal strategy for controlling the epidemic under the above model involves a single lockdown at a set maximum intervention level for υ, sustained until the cost reaches the specified threshold. To determine whether the optimal policy can be identified numerically, we use a simple Euler discretisation and then use JuMP.jl with IPOPT to optimise.

## Libraries

using OrdinaryDiffEq  
using DiffEqCallbacks  
using JuMP  
using Ipopt  
using Plots  
using DataInterpolations  
using NonlinearSolve;

## Functions

ODE system

function sir\_ode!(du,u,p,t)  
 (S, I, C) = u  
 (β, γ, υ) = p  
 @inbounds begin  
 du[1] = -β\*(1-υ)\*S\*I  
 du[2] = β\*(1-υ)\*S\*I - γ\*I  
 du[3] = β\*(1-υ)\*S\*I  
 end  
 nothing  
end;

SIR simulation

function simulate(p, u0, t₁, dur, ss, alg)  
 t₂ = t₁ + dur  
 lockdown\_times = [t₁, t₂]  
 β, γ, υ = p  
 function affect!(integrator)  
 if integrator.t < lockdown\_times[2]  
 integrator.p[3] = υ  
 else  
 integrator.p[3] = 0.0  
 end  
 end  
 cb = PresetTimeCallback(lockdown\_times, affect!)  
 tspan = (0.0, t₂+ss)  
 # Start with υ=0   
 prob = ODEProblem(sir\_ode!, u0, tspan, [β, γ, 0.0])  
 sol = solve(prob, alg, callback = cb)  
 return sol  
end;

Calculate the total number of infected at the end of simulation

function final\_size(p, u0, t₁, dur, ss, alg)  
 sol = simulate(p, u0, t₁, dur, ss, alg)  
 return sol[end][3]  
end;

## Running the model without intervention

Parameters

u0 = [0.99, 0.01, 0.0]; #S, I, C (cumulative incidence)  
p = [0.5, 0.25, 0]; # β, γ, υ

t0 = 0.0  
tf = 100  
dt = 0.1  
ts = collect(t0:dt:tf)  
alg = Tsit5();

Solve using ODEProblem


prob1 = ODEProblem(sir\_ode!, u0, (t0, tf), p)  
sol1 = solve(prob1, alg, saveat=ts);

Without control the final size of total number of cases is 79%

fianl\_C\_sol1 = sol1[end][3]  
println("Cumulative incidence fraction without control: ", fianl\_C\_sol1)

Cumulative incidence fraction without control: 0.7901973301721557

plot(sol1,  
 xlim=(0, 100),  
 labels=["S" "I" "C"],  
 xlabel="Time (days)",  
 ylabel="Fraction of population",linewidth=1.5)



Now we find the peak value of infected individuals and the time at which it occurs:

peak\_value, peak\_index = findmax(sol1[2, :])   
peak\_time = sol1.t[peak\_index]  
println("The peak of infections occurs at time: ", peak\_time)

The peak of infections occurs at time: 17.5

## Running the model with intervention initiated at the peak of infected cases

Demonstrating the impact of an intervention when initiated at the peak of infected cases.  
Parameters:

p2 = copy(p)  
p2[3] = 0.5; #Set υ to 0.5  
t₁ = peak\_time  
dur = 20.0 #Duration of the intervention  
ss = 100.0;

Simulate with intervention

sol2 = simulate(p2, u0, t₁, dur, ss, alg);


With control starting at the peak of infections and lasting 20 days, the final size of total number of cases is 63%

fianl\_C\_sol2 = sol2[end][3]  
println("Cumulative incidence fraction when control starts at the peak: ", fianl\_C\_sol2)

Cumulative incidence fraction when control starts at the peak: 0.6312297734622068

# create a vector that shows the υ value for each time step  
υ\_test = zeros(length(ts))  
for i in 1:length(ts)  
 if ts[i] >= t₁ && ts[i] <= (t₁ + dur)  
 υ\_test[i] = 0.5 # Set to 0.5 within the time interval  
 end  
end

plot(sol2,  
 xlim=(0, 100),  
 labels=["S" "I" "C"],  
 xlabel="Time (days)",  
 ylabel="Fraction of population",linewidth=1.5)  
plot!(ts, υ\_test, color=:gray, label="υ 20 days from peak",linewidth=1.5)



## Searching for the optimal intervention time

Parameters

β = p2[1]  
γ = p2[2]  
υ\_max = p2[3]  
υ\_total = 10.0; # maximum cost  
  
S0 = u0[1]  
I0 = u0[2]  
C0 = u0[3]  
  
T = Int(tf/dt)  
  
silent = true;

Model setup

model = Model(Ipopt.Optimizer)  
set\_optimizer\_attribute(model, "max\_iter", 1000)  
if !silent  
 set\_optimizer\_attribute(model, "output\_file", "JuMP\_lockdown.txt")  
 set\_optimizer\_attribute(model, "print\_timing\_statistics", "yes")  
end;

Variables:

@variable(model, 0 <= S[1:(T+1)] <= 1)  
@variable(model, 0 <= I[1:(T+1)] <= 1)  
@variable(model, 0 <= C[1:(T+1)] <= 1)  
@variable(model, 0 <= υ[1:(T+1)] <= υ\_max);

We can discretise the SIR model in different ways, but here we use a simple Euler discretisation:

@expressions(model, begin  
 infection[t in 1:T], (1 - υ[t]) \* β \* I[t] \* dt \* S[t] # Linear approximation of infection rate  
 recovery[t in 1:T], γ \* dt \* I[t] # Recoveries at each time step  
 end);

@constraints(model, begin  
 S[1]==S0  
 I[1]==I0  
 C[1]==C0  
 [t=1:T], S[t+1] == S[t] - infection[t]  
 [t=1:T], I[t+1] == I[t] + infection[t] - recovery[t]  
 [t=1:T], C[t+1] == C[t] + infection[t]  
 dt \* sum(υ[t] for t in 1:T+1) <= υ\_total  
end);

@objective(model, Min, C[T+1]);

if silent  
 set\_silent(model)  
end  
optimize!(model)


termination\_status(model)

LOCALLY\_SOLVED::TerminationStatusCode = 4

S\_opt = value.(S)  
I\_opt = value.(I)  
C\_opt = value.(C)  
υ\_opt = value.(υ);

Plotting the results shows that the optimiser has identified a policy similar to the one suggested by [Britton and Leskela (2022)](https://arxiv.org/abs/2202.07780), which is a single lockdown of intensity υ\_max and a duration υ\_total/υ\_max. But the optimiser has also identified a time to start the lockdown that is not the peak of the infection curve.

plot(ts, S\_opt, label="S", xlabel="Time (days)", ylabel="Fraction of population",linewidth=1.5)  
plot!(ts, I\_opt, label="I",linewidth=1.5)  
plot!(ts, C\_opt, label="C",linewidth=1.5)  
plot!(ts, υ\_test, color=:gray, linestyle=:dash, label="υ 20 days from peak",linewidth=1.5)  
plot!(ts, υ\_opt, label="Optimized υ",linewidth=1.5)



tolerance = 1e-3  
max\_indices = findall(x -> abs(x - υ\_max) < tolerance, υ\_opt)  
max\_times = ts[max\_indices]  
intervention\_length = length(max\_indices)\*dt  
  
println("Duration of intervention in days: ", intervention\_length)  
println("The start of intervention is at time: ", max\_times[1])

Duration of intervention in days: 19.900000000000002  
The start of intervention is at time: 14.3


With control starting at the optimased time and lasting 20 days, the final size of total number of cases is 59%

fianl\_C\_sol3 = C\_opt[end]  
println("Cumulative incidence fraction when control is optimised: ", fianl\_C\_sol3)

Cumulative incidence fraction when control is optimised: 0.5945130623911311

Now we use the final sizes function to produce simulations at different start times. In the following plot we can observe how the a 20-day constant-level lockdown of 0.5 the lowest Cumulative incidence is obtained at the optimal time found prevoiusly.

t\_opt = max\_times[1]  
fs(u, p\_) = final\_size(p2, u0, u[1], dur, ss, alg);  
final\_sizes = [fs([x], []) for x in ts]  
plot(ts,  
 final\_sizes,  
 xlabel="Time of intervention",  
 ylabel="Cumulative incidence",  
 ylim=(0,1),  
 xlim=(0,40),  
 legend=false,linewidth=1.5)  
vline!([t\_opt],linewidth=1.5)




We can also calculate the effective reproductive number, Rₜ′ in the presence of the intervention

Rₜ\_opt = β.\* S\_opt ./γ #Not taking into account the intervention  
Rₜ′\_opt = Rₜ\_opt .\* (1 .- υ\_opt); #Taking into account the intervention

And calculate the time at which Rₜ==1 using a root-finding approach:

Rₜ\_interp = CubicSpline(Rₜ\_opt,ts)  
f(u, p) = [Rₜ\_interp(u[1]) - 1.0]  
u0 = [(tf-t0)/3]  
Rtprob = NonlinearProblem(f, u0)  
Rtsol = solve(Rtprob, NewtonRaphson(), abstol = 1e-9).u[1];

plot(ts, Rₜ\_opt, label="Rₜ", xlabel="Time (days)", ylabel="Effective reproductive number", legend=:topright, xlim=(0,60),linewidth=1.5)  
plot!(ts, Rₜ′\_opt, label="Rₜ optimised",linewidth=1.5)  
plot!(ts, υ\_opt, label="Optimized υ",linewidth=1.5)  
vline!([Rtsol], color=:gray, linestyle=:dash, alpha=0.5, label=false,linewidth=1.5)  
hline!([1.0], color=:gray, linestyle=:dash, alpha=0.5, label=false,linewidth=1.5)



## Discussion

We mentioned that different discretisation methods can be used. We also tried discretising the system using exponential approximations to model the transition probabilities. If we model the time between transitions (such as infections or recoveries) as an exponentially distributed random variable with rate λ, the probability of transition between states during the interval dt can be approximated by:

For larger dt, this method may be more accurate than a simple Euler approximation. However, smaller timesteps, although giving results closer to the continuous time system, resulted in the solver struggling to converge. Therefore, at the chosen dt==0.1, the simple Euler discretisation provided better results.

We could also have used other optimisation methods by fixing the intervention length to 20 days and optimising the start of the intervention, which can be observed when we compared the optimal time obtained with the lowest cumulative incidence found simulating different intervention start times using the function final size. However, JuMP optimisation’s advantage is that we could numerically confirm that according to the constraints set to the intervention cost and total cases, the optimal intervention was a single lockdown at the maximum level set and for a period of 20 simulated days.