**Дополнительное задание**

**Задание:** Написать программу, которая делает операцию a/b. Если возникает одна из исключительных ситуаций вызывается прерывание, исполнение программы останавливается. Необходимо отличать исключения друг от друга.

Исключительные ситуации:  
1. Деление на 0  
2. Выход за ОДЗ [-2010; 2010]

--------------------------------------------------------------------------------------------------------------------

Число, которое мы делим, находится в ячейке A, делитель в ячейке B. После успешного выполнения деления, в ячейке COUNT будет находиться целая часть частного, а ячейке RE – остаток.  
В случае возникновения исключительной ситуации 1, на ВУ-1 будет подана 1, а в случае исключения 2 – будет подано число 2, после чего программа завершит свое выполнение.

**Описание логики работы программы:**

Сначала программа проверяет наличие исключительных ситуаций для обеих переменных, затем определяет знак результата операции (п зависимости от знаков A и B). После чего в ячейки A и B записываются модули чисел. Деление происходит в цикле – вычитаем из A число B, пока это возможно (AC > 0), и считаем кол-во итераций, записываем остаток деления. При корректной работе (без исключений) на ВУ-1 записывается 0.  
При возникновении исключительных ситуаций происходит соответствующая обработка и работа программы завершается.

!!! Если результат частного – отрицательный, то COUNT и RE тоже будут отрицательными.

!!! Если возникают обе исключительные ситуации одновременно – будет обработано прерывание как для исключительной ситуации 1. (на ВУ-1 будет записано 1)

**Код программы:**

ORG 0x2

**V1:** WORD $INT1, 0x180

**A:** WORD 18

**B:** WORD 14

**COUNT:** WORD 0x0 ; целая часть деления

**RE:** WORD 0x0 ; остаток от деления

**ODZpl:** WORD 20

**ODZmi:** WORD 0xFFEC

**ISNEGRES:** WORD 0

**START:** EI

LD B

PUSH

CALL checkODZ ; проверка ОДЗ и исключений для числа В

POP

LD A

BEQ EXIT ; если А равно 0

PUSH

CALL checkODZ ; проверка ОДЗ и исключений для числа А

POP

LD A ; блок проверки знака результата операции

CALL ISNEG

LD B

CALL ISNEG

LD A ; abs(A)

CALL ABS

ST A

LD B ; abs(B)

CALL ABS

ST B

**WHILE:** LD A ; реализация деления A на B

SUB B

ST A

BEQ ENDLN1

BMI ENDLN2

LD COUNT

INC

ST COUNT

JUMP WHILE

**ENDLN2:** ADD B ; окончание в случае наличия остатка

ST RE

JUMP ENDLN

**ENDLN1:** LD COUNT ; окончание в случае, если остаток 0

INC

ST COUNT

ENDLN: LD ISNEGRES

BEQ EXIT

LD COUNT

NEG

ST COUNT

LD RE

NEG

ST RE

**EXIT**: CLA

OUT 0x2

HLT

**I1:** LD #0x1 ; исключительный случай 1

INT 1 ; (деление на 0)

HLT

**I2:** LD #0x2 ; исключительный случай 2

INT 1 ; (выход за границы ОДЗ)

HLT

**checkODZ:** LD &1

BEQ I1 ; подпрограмма, проверяющая ОДЗ и наличие

BPL PLUSB ; исключительных ситуаций

NEGB: CMP ODZmi

BMI I2

RET

PLUSB: CMP ODZpl

BEQ ALL

BPL I2

ALL: RET

**ISNEG:** BMI ISTR ; подпрограмма, выставляющая флаг,

RET ; определяющий знак частного

ISTR: LD ISNEGRES

BEQ FLAGTRUE

CLA

ST ISNEGRES

RET

FLAGTRUE: INC

ST ISNEGRES

RET

**ABS:** BMI ABS1 ; подпрограмма, возвращающая модуль

RET ; числа, записанного в аккумулятор

ABS1: NEG

RET

ORG 0x100

**INT1:** NOP ; обработка прерывания в случае

OUT 0x2 ; возникновения исключительной ситуации

IRET