Technical evaluation of TURBBO with competency questions.

We designed a set of competency questions to ensure that the ontology covers all the concepts needed to describe a behaviour in the context of how it is measured and how it relates to another behaviour. These questions are designed to represent the sort of questions that behavioural scientists will be interested in when they compare behaviours that were measured in different studies. We present the competency questions in the following table and the sort of responses we expect. We also present the SPARQL queries we designed to represent the competency questions and the results we obtained by running the queries.

As an example dataset for this evaluation, we extracted data from Ha & Kwon (2016) were they studied the relationship between past recycling behaviour and shopping for green apparel. We added the data elements and mapped them to their corresponding classes in TURBBO.

# Competency questions

|  |  |
| --- | --- |
| **Competency question** | **Candidate answer from TURBBO** |
| 1. What is the name of the study that measured/observed this behaviour? | Name of the study |
| 1. What is the sample size of the study that is used to measure this behaviour? | Sample size values |
| 1. If a correlation is measured between this behaviour and another, what is the name of the other behaviour and the correlation coefficient r? | Name of correlated behaviour (eg, recycling, sleeping, walking, etc) and a value of r (0.5, 0.1, etc) |
| 1. Where does ‘this behaviour’ occur (location)? | ‘at home’, ‘at work’, ‘at the park’, ‘in a restaurant’ |
| 1. If this behaviour requires the use of materials, what are the materials? | Car, walking stick, etc. |
| 1. Is this behaviour legal? | Yes, No |

# SPARQL queries and answers

Competency question 1: What is the name of the study that measured/observed this behaviour? With this question, we are trying to find out all the studies that have reported on ‘past recycling behaviour’. We designed the SPARQL query to find the name of the study and if there are associated publications and their DOIs.

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX turbbo: <https://purl.org/turbbo#>

SELECT ?study ?paper ?DOI ?paperTitle

WHERE {

?s ?m ?b;

rdfs:label ?study.

?b rdfs:label "past recycling".

?m rdfs:label "measures".

?s turbbo:produces ?p.

?p rdfs:label ?paper.

?p ?title ?paperTitle.

?title rdfs:label "docTitle".

?p ?hasDOI ?DOI.

?hasDOI rdfs:label "hasDOI".

}

Answer:

<?xml version="1.0"?>

<sparql xmlns="http://www.w3.org/2005/sparql-results#">

<head>

<variable name="study"/>

<variable name="paper"/>

<variable name="DOI"/>

<variable name="paperTitle"/>

</head>

<results>

<result>

<binding name="study">

<literal>Ha and Kwon ﻿Fash Text (2016)</literal>

</binding>

<binding name="paper">

<literal>Ha &amp; Kwon (2016)</literal>

</binding>

<binding name="DOI">

<literal>10.1186/s40691-016-0068-7</literal>

</binding>

<binding name="paperTitle">

<literal>Spillover from past recycling to green apparel shopping behavior: the role of environmental concern and anticipated guilt</literal>

</binding>

</result>

</results>

</sparql>

Competency question 2: What is the sample size of the study that is used to measure this behaviour?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?sampleSize

WHERE {

?r ?correlates ?a.

?a rdfs:label "past recycling".

?correlates rdfs:label "relatesBehaviourA".

?r ?hasSampleSize ?sampleSize.

?hasSampleSize rdfs:label "hasSampleSize".

}

Answer:

<?xml version="1.0"?>

<sparql xmlns="http://www.w3.org/2005/sparql-results#">

<head>

<variable name="sampleSize"/>

</head>

<results>

<result>

<binding name="sampleSize">

<literal datatype="http://www.w3.org/2001/XMLSchema#integer">462</literal>

</binding>

</result>

</results>

</sparql>

Competency question 3: If a correlation is measured between this behaviour and another, what is the name of the other behaviour and the correlation coefficient *r*? (we used ‘past recyling’ as the behaviour of interest).

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT ?relatedBehaviourLabel ?rLabel

WHERE {

  ?r ?relatesA ?behaviour;

?relatesB ?relatedBehaviour.

  ?relatedBehaviour rdfs:label ?relatedBehaviourLabel.

  ?r rdfs:label ?rLabel.

  ?behaviour rdfs:label "past recycling".

  ?relatesA rdfs:label "relatesBehaviourA".

  ?relatesB rdfs:label "relatesBehaviourB".

}

Answer: the answer shows that ‘past recycling’ behaviour has a behaviour called ‘green apparel shopping’ that it was measured against and there was a correlation coefficient r of 0.07.

<?xml version="1.0"?>

<sparql xmlns="http://www.w3.org/2005/sparql-results#">

<head>

<variable name="relatedBehaviourLabel"/>

<variable name="rLabel"/>

</head>

<results>

<result>

<binding name="relatedBehaviourLabel">

<literal>**green apparel shopping**</literal>

</binding>

<binding name="rLabel">

<literal>**0.07**</literal>

</binding>

</result>

</results>

</sparql>

Competency question 4: Where does ‘this behaviour’ occur (location)?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX turbbo: <https://purl.org/turbbo#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?setting

WHERE {

?a rdfs:label "past recycling".

?a ?occursIn ?s.

?occursIn rdfs:label "occursIn".

?s rdfs:label ?setting.

}

Answer:

A null value was returned because the data set did not contain any information about the location (setting).

Competency question 5: If this behaviour requires the use of materials, what are the materials?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX turbbo: <https://purl.org/turbbo#>

SELECT ?material

WHERE {

?a rdfs:label "past recycling".

?a turbbo:requiresMaterial ?m.

?m rdfs:label ?material.

}

Answer:

There is also no response to this query. The dataset does not indicate which materials were used for this behaviour.

Competency question 6: Is this behaviour legal?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX turbbo: <https://purl.org/turbbo#>

SELECT ?isLegal

WHERE {

?a rdfs:label "past recycling".

?a ?legality ?isLegal.

?legality rdfs:label "isLegal".

}

Answer:

This query also did not return any response from the dataset.

**REFERENCE:**

Ha, S., Kwon, S.: Spillover from past recycling to green apparel shopping behavior: the role of environmental concern and anticipated guilt. Fashion and Textiles 3(1), 1-14 (2016)