# Recap

In the last article, we managed to get a basic version of the Pipes application running – albeit a simple one that only plays a single 5 x 5 puzzle. In this instalment, we will add the code to handle puzzles of different sizes and the ability to select a level and puzzle number.

# Adding Levels

To date, our game play has been limited to two 5 x 5 puzzles. By now you are probably sick of them and can do both with your eyes closed! Let’s fix that immediately by adding a puzzles of different sizes to the *Puzzles.h* file. Due to the different sizes of the puzzles, they must all be declared in their own array. A subset of the puzzles are shown below.

const byte puzzles\_5x5\_count = 2;

const byte PROGMEM puzzles\_5x5[] = {

  0x10, 0x20, 0x40,

  0x00, 0x30, 0x50,

  0x00, 0x00, 0x00,

  0x02, 0x04, 0x00,

  0x01, 0x35, 0x00,

  0x10, 0x00, 0x00,

  0x00, 0x00, 0x00,

  0x00, 0x40, 0x00,

  0x24, 0x30, 0x10,

  0x30, 0x00, 0x20,

}

const byte puzzles\_6x6\_count = 2;

const byte PROGMEM puzzles\_6x6[] = { ... }

const byte puzzles\_7x7\_count = 2;

const byte PROGMEM puzzles\_7x7[] = { ... }

const byte puzzles\_8x8\_count = 2;

const byte PROGMEM puzzles\_8x8[] = { ... }

const byte puzzles\_9x9\_count = 2;

const byte PROGMEM puzzles\_9x9[] = {

0x00, 0x00, 0x00, 0x00, 0x00,

0x01, 0x23, 0x00, 0x00, 0x00,

0x00, 0x02, 0x40, 0x43, 0x00,

0x00, 0x00, 0x00, 0x05, 0x00,

0x06, 0x06, 0x10, 0x00, 0x00,

0x75, 0x00, 0x00, 0x09, 0x80,

0x08, 0x70, 0x00, 0x00, 0x00,

0x09, 0x00, 0x00, 0x00, 0x00,

0x00, 0x00, 0x00, 0x00, 0x00,

...

}

## Loading the Board (Revisited)

The initBoard() function has undergone a few changes to date and the final tweak is to change it to accept a level parameter in addition to the original puzzle number one. The original code in the function remains unchanged however additional functionality has been added to allow the program to read from the different puzzle arrays we declared above.

The puzzleType parameter is a byte which indicates the size of the puzzle from 5 to 9. Using this number, we can work out how many bytes to read per puzzle. In our original code, this value was hardcoded to 15 bytes which equated to 3 bytes per row multiplied by 5 rows. As you may have worked out by now, a 6 x 6 puzzle also uses three bytes per row but has 6 rows.

When determining how many bytes to read, we determine whether the puzzle size is an even number - puzzleType % 2 == 0 - and, if so, we need to read in one half of the width multiplied by the number of row bytes - (puzzleType / 2) \* puzzleType. If the puzzle size is an odd number, we need to round the puzzle size up to the next even number, halve that and multiply in by the number of rows - ((puzzleType + 1) / 2) \* puzzleType.

Callout to “Modulus in C / C++”

When reading the actual puzzle data from the array, a simple switch statement is used to retrieve from the correct array.

#define PUZZLE\_5X5 5

#define PUZZLE\_6X6 6

#define PUZZLE\_7X7 7

#define PUZZLE\_8X8 8

#define PUZZLE\_9X9 9

void initBoard(byte puzzleType, byte puzzleNumber) {

byte x = 0;

byte y = 0;

byte byteRead = 0;

byte bytesToRead = (puzzleType % 2 == 0 ? (puzzleType / 2) \* puzzleType :

((puzzleType / 2) + 1) \* puzzleType);

for (int i = (puzzleNumber \* bytesToRead); i < ((puzzleNumber + 1) \* bytesToRead); i++) {

switch (puzzleType) {

case PUZZLE\_5X5:

byteRead = pgm\_read\_byte(&puzzles\_5x5[i]);

break;

case PUZZLE\_6X6:

byteRead = pgm\_read\_byte(&puzzles\_6x6[i]);

break;

case PUZZLE\_7X7:

byteRead = pgm\_read\_byte(&puzzles\_7x7[i]);

break;

case PUZZLE\_8X8:

byteRead = pgm\_read\_byte(&puzzles\_8x8[i]);

break;

case PUZZLE\_9X9:

byteRead = pgm\_read\_byte(&puzzles\_9x9[i]);

break;

}

...

}

}

## Rendering the board.

The existing code to render the board will happily render puzzles of any size – however with the larger puzzles portions of the board will not be visible. Later in this article, we will look at how we can make the board scroll as the user moves around.

# Storing the Player’s Progress.

Callout to “Saving User Settings”

My version of the Pipes game will not let a player advance to the next puzzle in each level until they have completed the one before that. I store and retrieve the progress of each level in the EEPROM using two simple functions as shown below. Note that they use the Arduboy2 constant EEPROM\_STORAGE\_SPACE\_START to ensure they do not overwrite any system settings. The offset is used to calculate a memory position that takes into account the fact that the puzzleLevel variable is a value between 5 and 9. Subtracting three from this value ensures that it uses contiguous memory spaces.

#define EEPROM\_START EEPROM\_STORAGE\_SPACE\_START

#define EEPROM\_START\_C1 EEPROM\_START // Game indicator 'L'

#define EEPROM\_START\_C2 EEPROM\_START + 1 // Game indicator 'P'

#define EEPROM\_PUZZLE\_OFFSET EEPROM\_START - 3

void updateEEPROM(byte puzzleLevel, byte index) {

EEPROM.update(EEPROM\_PUZZLE\_OFFSET + puzzleLevel, index);

}

byte readEEPROM(byte puzzleLevel) {

return EEPROM.read(EEPROM\_PUZZLE\_OFFSET + puzzleLevel);

}

But what if the game has been loaded onto an Arduboy that already has data in these locations from other applications – at best the player will be able to play levels they have not actually achieved but at worst, there may be data that causes the program to try to retrieve a non-existent level resulting in errors.

I have included a function that initializes the EEPROM if it hasn’t already done so. The function looks for the letters ‘L’ and ‘P’ (Laying Pipe) in the first two characters of the memory range. If these values are not found then it assumes that you have not played the game before and initializes the memory. This function is called once in the setup() routine.

bool initEEPROM () {

byte c1 = EEPROM.read(EEPROM\_START\_C1);

byte c2 = EEPROM.read(EEPROM\_START\_C2);

if (c1 != 76 || c2 != 80) { // LP

EEPROM.update(EEPROM\_START\_C1, 76);

EEPROM.update(EEPROM\_START\_C2, 80);



...

}

}

# Selecting a Level

Now that we have all of the levels defined and have a way of tracking progress, we need a way for the player to select which of the five levels they would like to play. In a later article, I will add some interest to the menus by circling them with pipes.

The code utilizes two variables for capturing the player’s currently selected menu item and the top item to display as the user scrolls through the options. These are the variables levelSelect\_selectedItem and levelSelect\_topItem respectively. The levelSelect\_selectedItem is incremented or decremented as the user clicks the up or down buttons within the range of the six level options. If the user presses the ‘B’ button, control is returned back to the splash screen.

byte levelSelect\_selectedItem = 0;

byte levelSelect\_topItem = 0;

void levelSelect() {

arduboy.clear();

if (arduboy.justPressed(UP\_BUTTON) &&

levelSelect\_selectedItem > 0) { levelSelect\_selectedItem--; }

if (arduboy.justPressed(DOWN\_BUTTON) &&

levelSelect\_selectedItem < sizeof(levels) - 1) { levelSelect\_selectedItem++; }

if (arduboy.justPressed(B\_BUTTON)) { gameState = STATE\_INTRO; }

If the player presses the ‘A’ button, the progress of the selected level is retrieved from the EEPROM. If they select a level where they have completed at least one of the puzzles, they are invited to clear the level and start again or continue on from the last completed puzzle. If the player selects a new level, they are first puzzle is automatically selected.

In either scenario the gameplay variable is updated to indicate which routine the main loop() should call on the next pass. I have also included a second variable, prevState, and have set this to STATE\_LEVEL\_SELECT. This variable will be used later to determine how a user got to the puzzle select screen and is described in the section *Selecting a Puzzle* below.

if (arduboy.justPressed(A\_BUTTON)) {

puzzle.level = levels[levelSelect\_selectedItem];

puzzle.index = 0;

if (readEEPROM(puzzle.level) > 0) {

gameState = STATE\_PUZZLE\_SELECT;

prevState = STATE\_LEVEL\_SELECT;

puzzleSelect\_selectedItem = 0;

}

else {

gameState = STATE\_INIT\_GAME;

}

}

Before rendering the menu, the top item to display is calculated based on the currently selected item. This calculation keeps the selected row in the middle of the three rows being displayed except when the player has scrolled to the top or bottom of the list, as shown in the table below.

|  |  |
| --- | --- |
| Selected Item | Top Row |
| 0 (5 x 5, Practice) | 0 |
| 1 (6 x 6, Easy) | 0 |
| 2 (7 x 7, Medium) | 1 |
| 3 (8 x 8, Hard) | 2 |
| 4 (9 x 9, Extreme) | 2 |

The logic seems over the top for five items but the code will work for any number of menu items and visible positions.

if (levelSelect\_selectedItem < levelSelect\_noOfItems - 1) {

levelSelect\_topItem = 0;

}

else {

if (levelSelect\_selectedItem > sizeof(levels) - levelSelect\_noOfItems + 1) {

levelSelect\_topItem = sizeof(levels) - levelSelect\_noOfItems;

}

else {

levelSelect\_topItem = levelSelect\_selectedItem - 1;

}

}

Once the top item is calculated, we can render out the three visible menu items. With a little effort this code could be converted to a loop that would support *n* visible items. For now, the code is hardcoded.

renderLevelDetail(MENU\_ITEM\_3\_X, MENU\_ITEM\_3\_1\_Y, levels[levelSelect\_topItem],

(levelSelect\_topItem == levelSelect\_selectedItem));

renderLevelDetail(MENU\_ITEM\_3\_X, MENU\_ITEM\_3\_2\_Y, levels[levelSelect\_topItem + 1],

(levelSelect\_topItem + 1 == levelSelect\_selectedItem));

renderLevelDetail(MENU\_ITEM\_3\_X, MENU\_ITEM\_3\_3\_Y, levels[levelSelect\_topItem + 2],

(levelSelect\_topItem + 2 == levelSelect\_selectedItem));

}

The renderLevelDetail() function renders a single menu item at positions X and Y. If the variable highlight is true, it first renders a white filled rectangle and sets the text colour to black on a white background. At the end of the routine, it reverts the text back to white text on a black background.

void renderLevelDetail(byte x, byte y, byte level, byte highlight) {

if (highlight) {

arduboy.setTextColor(BLACK);

arduboy.setTextBackground(WHITE);

arduboy.fillRect(x - 1, y - 1, MENU\_ITEM\_3\_WIDTH, MENU\_ITEM\_3\_HEIGHT, WHITE);

}

arduboy.setCursor(x, y);

switch (level) {

case PUZZLE\_5X5:

arduboy.print("Practice ");

arduboy.print(readEEPROM(PUZZLE\_5X5) < 10 ? " " : "");

arduboy.print(readEEPROM(PUZZLE\_5X5));

arduboy.print("/");

arduboy.print(puzzles\_5x5\_count);

break;

case PUZZLE\_6X6: ...

case PUZZLE\_7X7: ...

case PUZZLE\_8X8: ...

case PUZZLE\_9X9: ...

}

arduboy.setTextColor(WHITE);

arduboy.setTextBackground(BLACK);

}

# Selecting a Puzzle

As stated earlier, if the player selects a level where they have completed at least one of the puzzles, they are invited to clear the level and start again or continue on from the last completed puzzle. If the player selects a new level, they are first puzzle is automatically selected. The puzzle selection screen looks like this:



The code below handles the selection of a puzzle. I will not dissect it as it is functionally similar to the level section above but there are a few variations.

The first is when the user selects the option to continue playing the next puzzle from the level they have chosen. If the retrieved EEPROM setting reveals that the user has completed all puzzles in the current level, then they are presented with the last puzzle again.

You will also notice that when rendering the first menu item, the words *Continue Playing* are rendered if the player has progressed from the level selection screen. If they have pressed the ‘B’ button whilst playing an actual puzzle, they will be presented with the option *Restart Puzzle* instead.

void puzzleSelect() {

arduboy.clear();

if (arduboy.justPressed(UP\_BUTTON) &&

puzzleSelect\_selectedItem > 0) { puzzleSelect\_selectedItem--; }

if (arduboy.justPressed(DOWN\_BUTTON) &&

puzzleSelect\_selectedItem < 1) { puzzleSelect\_selectedItem++; }

if (arduboy.justPressed(B\_BUTTON)) { gameState = STATE\_LEVEL\_SELECT; }

if (arduboy.justPressed(A\_BUTTON)) {

if (puzzleSelect\_selectedItem == 1) {

puzzle.index = 0;

updateEEPROM(puzzle.level, puzzle.index);

}

if (puzzleSelect\_selectedItem == 0) {

// If all puzzles in the current level are completed, simply re-show the last puzzle ..

puzzle.index = (readEEPROM(puzzle.level) == getNumberOfPuzzles(puzzle.level) ?

readEEPROM(puzzle.level) -1 : readEEPROM(puzzle.level));

}

gameState = STATE\_INIT\_GAME;

}

renderPuzzleOption(MENU\_ITEM\_2\_X, MENU\_ITEM\_2\_1\_Y, (prevState == STATE\_LEVEL\_SELECT ?

"Continue Playing" : " Restart Puzzle "), (puzzleSelect\_selectedItem == 0));

renderPuzzleOption(MENU\_ITEM\_2\_X, MENU\_ITEM\_2\_2\_Y, " Reset Level",

(puzzleSelect\_selectedItem == 1));

}

# Enabling Scrolling and Centering the Board

To complete the game play, we need to enable scrolling so that the player can reach the lower rows of the bigger puzzles. While modifying the code to support this, we will add some extra functionality to center the board in the screen and to add a ‘scrollbar’ on the right hand side that indicates where the player’s highlighted cell is relative to the rest of the board. When finished, the game play will look like this :

To start with, I have defined another array in the *Puzzles.h* file that stores a row of information per puzzle type. For each puzzle type we define four parameters that include the X and Y position at which to render the board and a ‘unit length’ and ‘bar length’ for the scrollbar. The scrollbar parameters are used simulate the behaviour of a scroll bar where the ‘slider’ length is proportional to the visible screen length compared to the full puzzle size. More about that later.

const byte PROGMEM puzzles\_details[] = {

36, 4, 0, 0, // 5x5

27, 4, 10, 42, // 6x6

21, 4, 8, 36, // 7x7

16, 4, 7, 31, // 8x8

10, 4, 6, 28, // 9x9

};

The puzzle structure that is populated at the start of a game and maintains game play information has been extended to capture this additional information. When populating the puzzle structure via the initBoard() function, these additional parameters are retrieved and stored along with the puzzle definition itself.

struct Slider {

byte unit; // Number of pixels / row for the slider.

byte overall; // Height of the slider portion in pixels.

};

struct Puzzle {

byte level;

byte index;

Node maximum;

Node offset;

Slider slider;

byte board[9][9];

}

puzzle;

In the previous article we looked at the two functions that handle the node selection and pipe laying, play\_NoSelection() and play\_NodeSelected() respectively. If you recall, both of these functions finished with a call to renderBoard() which simply rendered the board in the top left corner of the page. To cater for the offsets, I have added some additional parameters for them as shown below:

void renderBoard(int xOffset, int yOffset, byte topRow) {

arduboy.clear();

...

for (int y = 0; y < puzzle.maximum.y; y++) {

for (int x = 0; x < puzzle.maximum.x; x++) {

if (isPipe(x,y)) {

sprites.drawExternalMask((x \* GRID\_WIDTH) + xOffset, (y \* GRID\_HEIGHT) + yOffset,

pipes[getPipeValue(x, y)], pipe\_mask, frame, frame);

}

}

}

...

}

When rendering the any component of the board, the X and Y offsets are included in position calculations.

To implement the scrolling, I have altered the play\_NoSelection() and play\_NodeSelected() to calculate a ‘Y’ offset that takes into account the current highlighted row. The function to calculate the top row to display is shown below. The code is very similar to that which we utilised when displaying the levels menu and aims to keep the highlighted cell in the middle of the screen where possible.

byte calculateTopRow() {

byte topRow = 0;

if (player.highlightedNode.y <= 2) {

topRow = 0;

}

else {

if (player.highlightedNode.y >= 3 && player.highlightedNode.y <= puzzle.maximum.y - 4) {

topRow = player.highlightedNode.y - 2;

}

else {

topRow = (puzzle.maximum.y - 5 >= 0 ? puzzle.maximum.y - 5 : 0);

}

}

return topRow;

}

The play\_NoSelection() and play\_NodeSelected() utilize the new calculateTopRow() function to determine the top row to display. When the top row evaluates to zero, the rendering of the puzzle starts at the offset position defined in puzzle.offset.x and offset.position.y, as retrieved from the puzzles\_details[] array. As the top row increases the calculated offset gets increasingly larger and negative which forces the board to be rendered from a negative ‘Y’ position.

renderBoard(puzzle.offset.x, puzzle.offset.y - calculateTopRow() \* GRID\_HEIGHT,

calculateTopRow());

The renderBoard() routine will simply render the items regardless of their ‘Y’ values. The Arduboy2 *Sprites* library contains code that detects when an image will be completely rendered outside the dimensions of the screen. However, it needs to calculate this and this adds some overhead to the rendering. This does not pose a problem for a game like Pipes but would be a consideration for a fast moving, action game.

# Rendering a Scroll Bar

Our last little visual trick for his edition of the series is to add a scroll bar that will indicate to the player that the puzzle they are playing is bigger than what the Arduboy can display and where their highlighted cell is relative to the board.

The renderBoard() function is altered once again to include some logic to render the scrollbar. The 5 x 5 puzzle does not need a scroll bar but all other puzzle sizes do. To cater for this, the rendering of the puzzle is conditioned by the puzzle.slider.unit value (one of the values retrieved from the puzzles\_details[] array earlier) being greater than 0. You may have noticed earlier that the 5 x 5 puzzle had this value set to zero.

The ‘slider’ part of the toolbar is positioned on the scrollbar to indicate the relative position of the highlighted cell. This is done by calculating the top position using the topRow parameter multiplied by the puzzle.slider.unit value. The height of the slider is a constant per puzzle type.

void renderBoard(int xOffset, int yOffset, byte topRow) {

…

if (puzzle.slider.unit > 0) {

arduboy.fillRect(SCROLLBAR\_X - 1, SCROLLBAR\_Y, SCROLLBAR\_WIDTH + 1,

SCROLLBAR\_HEIGHT, BLACK);

arduboy.drawRect(SCROLLBAR\_X, SCROLLBAR\_Y, SCROLLBAR\_WIDTH,

SCROLLBAR\_HEIGHT, WHITE);

arduboy.fillRect(SCROLLBAR\_X + 2, SCROLLBAR\_Y + 6 + (topRow \* puzzle.slider.unit),

SCROLLBAR\_WIDTH - 4, puzzle.slider.overall, WHITE);

// Top arrow ..

arduboy.fillTriangle(SCROLLBAR\_X + 4, SCROLLBAR\_Y + 2, SCROLLBAR\_X + 2, SCROLLBAR\_Y + 4,

SCROLLBAR\_X + 6, SCROLLBAR\_Y + 4, WHITE);

// Bottom arrow ..

arduboy.fillTriangle(SCROLLBAR\_X + 2, SCROLLBAR\_Y + SCROLLBAR\_HEIGHT - 5,

SCROLLBAR\_X + 6, SCROLLBAR\_Y + SCROLLBAR\_HEIGHT - 5,

SCROLLBAR\_X + 4, SCROLLBAR\_Y + SCROLLBAR\_HEIGHT - 3, WHITE);

}

## Where’s the code?

The sample code detailed in this article can be found in the repository at [https://github.com/filmote/Pipes\_Article3](https://github.com/filmote/Pipes_Article2). The game is totally playable now but needs more cowbells to make it complete. If you don’t understand that reference, you need to watch the SNL comedy sketch here <https://www.youtube.com/watch?v=DLeNQKk4uuI>

## Next Month

In the next article, we will add some additional features to make the game a little more professional – sound, an animated splash screen and other decorations. If we have space, I will discuss how to create a distributable HEX file and an .arduboy file.